Jump to content

Sky Slate Blueberry Blackcurrant Watermelon Strawberry Orange Banana Apple Emerald Chocolate
Photo

How to defeat limits on Master Volume level in Windows XP SP3?


  • Please log in to reply
1 reply to this topic
Ron1
  • Members
  • 42 posts
  • Last active: Apr 01 2014 06:58 PM
  • Joined: 20 Dec 2007

After the latest update from Microsoft Windows Update for my Windows XP SP3, the master volume level in VOLUME CONTROL is limited to a range of 22 to 71, rather than the usual 0 to 100.  Does anyone know why, and how this can be reset to 0 to 100?

 

Thank you for your help.



Psychofergo
  • Members
  • 23 posts
  • Last active: Jan 10 2015 04:41 PM
  • Joined: 09 Dec 2013

you can always use something like this:

 

#noenv

;_________________________________________________ 
;_______User Settings_____________________________ 

; Make customisation only in this area or hotkey area only!! 

; The percentage by which to raise or lower the volume each time:
vol_Step = 4

; How long to display the volume level bar graphs:
vol_DisplayTime = 2000

; Master Volume Bar colour (see the help file to use more
; precise shades):
vol_CBM = Red

; Wave Volume Bar colour
vol_CBW = Blue

; Background colour
vol_CW = Silver

; Bar's screen position.  Use -1 to centre the bar in that dimension:
vol_PosX = -1
vol_PosY = -1
vol_Width = 150  ; width of bar
vol_Thick = 12   ; thickness of bar

; If your keyboard has multimedia buttons for Volume, you can
; try changing the below hotkeys to use them by specifying
; Volume_Up, ^Volume_Up, Volume_Down, and ^Volume_Down:
HotKey, #Up, vol_MasterUp      ; Win+UpArrow
HotKey, #Down, vol_MasterDown
HotKey, #Right, vol_WaveUp       ; Win+RightArrow
HotKey, #Left, vol_WaveDown

;========================================================
;		AutoExecute Section - do not modify
;========================================================

vol_BarOptionsMaster = 1:B ZH%vol_Thick% ZX0 ZY0 W%vol_Width% CB%vol_CBM% CW%vol_CW%
vol_BarOptionsWave   = 2:B ZH%vol_Thick% ZX0 ZY0 W%vol_Width% CB%vol_CBW% CW%vol_CW%

; If the X position has been specified, add it to the options.
; Otherwise, omit it to centre the bar horizontally:
if vol_PosX >= 0
	{
		vol_BarOptionsMaster = %vol_BarOptionsMaster% X%vol_PosX%
		vol_BarOptionsWave   = %vol_BarOptionsWave% X%vol_PosX%
	}

; If the Y position has been specified, add it to the options.
; Otherwise, omit it to have it calculated later:
if vol_PosY >= 0
	{
		vol_BarOptionsMaster = %vol_BarOptionsMaster% Y%vol_PosY%
		vol_PosY_wave = %vol_PosY%
		vol_PosY_wave += %vol_Thick%
		vol_BarOptionsWave = %vol_BarOptionsWave% Y%vol_PosY_wave%
	}
;___________________________________________ 
SetBatchLines, 10ms

vol_WaveUp:
	SoundSet, +%vol_Step%, Wave
	Gosub, vol_ShowBars
Return

vol_WaveDown:
	SoundSet, -%vol_Step%, Wave
	Gosub, vol_ShowBars
Return

vol_MasterUp:
	SoundSet, +%vol_Step%
	Gosub, vol_ShowBars
Return

vol_MasterDown:
	SoundSet, -%vol_Step%
	Gosub, vol_ShowBars
Return

vol_ShowBars:
	; To prevent the "flashing" effect, only create the bar window if it
	; doesn't already exist:
	IfWinNotExist, vol_Wave
		Progress, %vol_BarOptionsWave%, , , vol_Wave
	IfWinNotExist, vol_Master
	{
		; Calculate position here in case screen resolution changes while
		; the script is running:
		if vol_PosY < 0
		{
			; Create the Wave bar just above the Master bar:
			WinGetPos, , vol_Wave_Posy, , , vol_Wave
			vol_Wave_Posy -= %vol_Thick%
			Progress, %vol_BarOptionsMaster% Y%vol_Wave_Posy%, , , vol_Master
		}
		else
			Progress, %vol_BarOptionsMaster%, , , vol_Master
	}
	; Get both volumes in case the user or an external program changed them:
	SoundGet, vol_Master, Master
	SoundGet, vol_Wave, Wave
	Progress, 1:%vol_Master%
	Progress, 2:%vol_Wave%
	SetTimer, vol_BarOff, %vol_DisplayTime%
Return

vol_BarOff:
	SetTimer, vol_BarOff, off
	Progress, 1:Off
	Progress, 2:Off
Return

Notice that it just increases or decreased, not set the volume.

Hope that helps