19 replies to this topic

[lasmori]

I was not entirely happy with the existing scripts for doing this, so I ended up writing my own.

The script itself is a bit simpler then the others for a couple reasons:
1) I did not write or include any other functionality besides window dragging
2) The logic for moving the window is a bit simpler over the other scripts I've seen
3) IMHO, the script is commented and formatted a bit better.


Anyhow, nothing great.

EDIT: Updated to be even simpler thanks to a couple tips posted by Lexikos

;-------------------------------------------------
; Window dragging via alt+lbutton                -
; Author: Lasmori (email AT lasmori D0T com)     -
;-------------------------------------------------
!LButton::

CoordMode, Mouse, Relative
MouseGetPos, cur_win_x, cur_win_y, window_id
WinGet, window_minmax, MinMax, ahk_id %window_id%

; Return if the window is maximized or minimized
if window_minmax <> 0
{
  return
}

CoordMode, Mouse, Screen
SetWinDelay, 0

loop
{
  ; exit the loop if the left mouse button was released
  if !GetKeyState("LButton", "P")
  {
    break
  }

  ; move the window based on cursor position
  MouseGetPos, cur_x, cur_y
  WinMove, ahk_id %window_id%,, (cur_x - cur_win_x), (cur_y - cur_win_y)
}

return
;-------------------------------------------------

[AHKisNice]

Hello, thanks for the script. I alt+left clicked on a window's titlebar and nothing happened. What is the script supposed to do? How do i use it?

[lasmori]

it lets you move windows. I am using it because my taskbar is on the top and windows tend to get stuck with their titlebars hidden.

It wont work on maximized windows, though it should work great on normal windows.

Its also meant for using on the inside or body or the application, not the title bar... as that already works

[ManaUser]

Hello, thanks for the script. I alt+left clicked on a window's titlebar and nothing happened. What is the script supposed to do? How do i use it?

The idea is you can "grab" a window by any part (not just the title bar) if you hold down alt.

[AHKisNice]

lol oh thanks, nice script lasmori.

I am using it because my taskbar is on the top and windows tend to get stuck with their titlebars hidden.

Why did you move the taskbar to the top? I am going to try that to see if I like it.

[Lexikos]

I like how explicitly your variables are named. I'm usually much too lazy. :lol:

I have a few suggestions:
[*:33lb0q1b]A_WinDelay (not A_Win_Delay!) and similar settings need not be reset manually if the thread is going to end.

SetWinDelay:
Every newly launched thread (such as a hotkey, custom menu item, or timed subroutine) starts off fresh with the default setting for this command. That default may be changed by using this command in the auto-execute section (top part of the script).

Threads:
When resumed, a thread's settings for things such as ErrorLevel and SendMode are automatically restored to what they were just prior to its interruption;

[*:33lb0q1b]GetKeyState is available as a function, in case you want to avoid an unnecessary variable.

if ! GetKeyState("LButton", "P")
; or
if GetKeyState("LButton", "P") = 0
; instead of
GetKeyState, lbutton_state, LButton, P
if  lbutton_state = U

[*:33lb0q1b]All purely numeric args (excluding MsgBox) also accept expressions.

WinMove, ahk_id %window_id%,, cur_x - cur_win_x, cur_y - cur_win_y
; instead of
window_x := cur_x - cur_win_x
window_y := cur_y - cur_win_y
WinMove, ahk_id %window_id%,, %window_x%, %window_y%

[superdsp]

I was not entirely happy with the existing scripts for doing this, so I ended up writing my own.

The script itself is a bit simpler then the others for a couple reasons:
1) I did not write or include any other functionality besides window dragging
2) The logic for moving the window is a bit simpler over the other scripts I've seen
3) IMHO, the script is commented and formatted a bit better.


Anyhow, nothing great.

;-------------------------------------------------
; Window dragging via alt+lbutton                -
; Author: Lasmori (email AT lasmori D0T com)     -
;-------------------------------------------------
!LButton::
original_win_delay := A_Win_Delay

CoordMode, Mouse, Relative
MouseGetPos, cur_win_x, cur_win_y, window_id
WinGet, window_minmax, MinMax, ahk_id %window_id%

; Return if the window is maximized or minimized
if window_minmax <> 0 
{
  return
}

CoordMode, Mouse, Screen
SetWinDelay, 0

loop
{
  ; exit the loop if the left mouse button was released
  GetKeyState, lbutton_state, LButton, P
  if lbutton_state = U
  {
    break
  }

  MouseGetPos, cur_x, cur_y
  window_x := cur_x - cur_win_x
  window_y := cur_y - cur_win_y
  WinMove, ahk_id %window_id%,, %window_x%, %window_y%
}

SetWinDelay, %original_win_delay%

return
;-------------------------------------------------

Very nice!

[Razlin]

Didnt test the script but many people dont know that if you

ALT+Space ona window

then press M = move

You can use the arrrow keys to move a window then press enter to "execute" the move

this is part of windows not ahk.

Anyhow.. my 2 copper

[Da Rossa]

Nice script brother! i'm using it! Are you planning to write a clean code for the Window resize function too?

[lasmori]

Nice script brother! i'm using it! Are you planning to write a clean code for the Window resize function too?

Sister, not brother

Hmm... I had no plans to do so but could if someone wants it bad enough. I obviously haven't been paying attention to the forum for a while. (Actually just had surgery...)


I also wanted to thank the above poster on the tips.

[lasmori]

lol oh thanks, nice script lasmori.

I am using it because my taskbar is on the top and windows tend to get stuck with their titlebars hidden.

Why did you move the taskbar to the top? I am going to try that to see if I like it.

I dunno... I am a mac user so its just more familiar

[Da Rossa]

Nice script brother! i'm using it! Are you planning to write a clean code for the Window resize function too?

Sister, not brother

Hmm... I had no plans to do so but could if someone wants it bad enough. I obviously haven't been paying attention to the forum for a while. (Actually just had surgery...)


I also wanted to thank the above poster on the tips.

[liquidos]

Thanks, this script really works nicely! I had one problem with it though. When I dragged a window it stayed beneath other windows. I added this line to make it be the top window:

SetWinDelay, 0 ; After this
WinSet, Top,, ahk_id %window_id%

The problem might be because some third party program or the TweakUI xmouse feature, I don't know, but it probably doesn't add much overhead..