3 replies to this topic

[Ice_Tea]

Hey, there is a command i tend to use to freeze processes, and later resuming them... and to do this with AHK I have to use a another CMDtool to do it, so i were wondering if you could possible add these commands:

; Suspend the process
Process, Suspend, example.exe

; Resume Suspended process
Process, Resume, example.exe

This could be useful if you need more CPU cycles, you could temporary freeze the processes thread to temporarily give other stuff more time and then simply resume the frozen process, this way you don't have to close the program.

(I did try doing a search through the forum, but as I've said before, the search function in all forums is useless... tried googling through the forum too...)

[Lexikos]

tried googling through the forum too...

I used site:autohotkey.com suspend process and got Suspend Process as the first result.
Just for kicks, I also tried the site's own search function and again got Suspend Process as the first result.

[heresy]

Run, Notepad.exe

WinWait, ahk_class Notepad

Process_Suspend("Notepad.exe")

MsgBox, Notepad.exe suspended

Sleep, 5000

Process_Resume("Notepad.exe")

MsgBox, Notepad.exe resumed

Exitapp



;============================== Working on WinXP+

Process_Suspend(PID_or_Name){

    PID := (InStr(PID_or_Name,".")) ? ProcExist(PID_or_Name) : PID_or_Name

    h:=DllCall("OpenProcess", "uInt", 0x1F0FFF, "Int", 0, "Int", pid)

    If !h   

        Return -1

    DllCall("ntdll.dll\NtSuspendProcess", "Int", h)

    DllCall("CloseHandle", "Int", h)

}



Process_Resume(PID_or_Name){

    PID := (InStr(PID_or_Name,".")) ? ProcExist(PID_or_Name) : PID_or_Name

    h:=DllCall("OpenProcess", "uInt", 0x1F0FFF, "Int", 0, "Int", pid)

    If !h   

        Return -1

    DllCall("ntdll.dll\NtResumeProcess", "Int", h)

    DllCall("CloseHandle", "Int", h)

}



ProcExist(PID_or_Name=""){

    Process, Exist, % (PID_or_Name="") ? DllCall("GetCurrentProcessID") : PID_or_Name

    Return Errorlevel

}

[Ice_Tea]

Run, Notepad.exe
WinWait, ahk_class Notepad
Process_Suspend("Notepad.exe")
MsgBox, Notepad.exe suspended
Sleep, 5000
Process_Resume("Notepad.exe")
MsgBox, Notepad.exe resumed
Exitapp

;============================== Working on WinXP+
Process_Suspend(PID_or_Name){
    PID := (InStr(PID_or_Name,".")) ? ProcExist(PID_or_Name) : PID_or_Name
    h:=DllCall("OpenProcess", "uInt", 0x1F0FFF, "Int", 0, "Int", pid)
    If !h   
        Return -1
    DllCall("ntdll.dll\NtSuspendProcess", "Int", h)
    DllCall("CloseHandle", "Int", h)
}

Process_Resume(PID_or_Name){
    PID := (InStr(PID_or_Name,".")) ? ProcExist(PID_or_Name) : PID_or_Name
    h:=DllCall("OpenProcess", "uInt", 0x1F0FFF, "Int", 0, "Int", pid)
    If !h   
        Return -1
    DllCall("ntdll.dll\NtResumeProcess", "Int", h)
    DllCall("CloseHandle", "Int", h)
}

ProcExist(PID_or_Name=""){
    Process, Exist, % (PID_or_Name="") ? DllCall("GetCurrentProcessID") : PID_or_Name
    Return Errorlevel
}

oh snap will you marry me?