141 replies to this topic

[Laszlo]

You missed my correction.

No, I did not. By funny result I meant 0x6016026030a00, while the correct output is 6162630a00.

[polyethene]

I meant 0x6016026030a00, while the correct output is 6162630a00.

Hmm, RegExReplace(RegExReplace(h, "0x(.)(?=$|0x)", "0$1"), "0x") seems to work. I don't know what the impact of two calls would be but it shouldn't be much.

[Laszlo]

Yes, this works. With the AutoHotkey\license.txt the second RegExReplace takes about 20ms, not a noticeable time. So, we have a nice example, when regular expressions speed up the code.

This is only 15ms faster, but two lines longer:

h := RegExReplace(h, "0x(.)(?=0x|$)", "0$1")
   StringReplace h, h, 0x,,All
   Return h

[SKAN]

Hmm, RegExReplace(RegExReplace(h, "0x(.)(?=$|0x)", "0$1"), "0x") seems to work.

Ah! Then it can be applied to your RgbToHex() !

Thanks!

[polyethene]

This is only 15ms faster, but two lines longer

Cool, looks like I underestimated StringReplace.

Ah! Then it can be applied to your RgbToHex()

Done

[SKAN]

Thanks Titan, I will be using it!

BTW, change the "ownage (req. 1.0.46.x+)" !

[polyethene]

1.0.46.x+

v1.0.46 released: SubStr() and more expression operators

[SKAN]

Uh Oh! :oops: Thanks! I missed it! ..

[Laszlo]

...and this is how your Rotate function looks like in AHK v1.0.46.x+:

Rotate( pointer, dataSz=0, factor=47 ) { ; Defaults to ROT47

   L0 := 32+factor, L1 := 127+factor, pointer--

   Loop %dataSz% {

      Asc := *(++pointer) + factor

      If ( Asc > L0 and Asc < L1 )

         DllCall("RtlFillMemory", Int,pointer, Int,1, UChar,Asc<127 ? Asc : Asc-94)

   }

}

[SKAN]

Sir, Many thanks for giving that nice example! The function looks so beautiful! Will try it shortly..

[SKAN]

I can see a 50ms savings in AHK's license.txt, but I like it more for being a demonstration for AHK's new capabilities.

I will allow a few days and then update the original post with the function.

Many Thanks & Regards,

[Laszlo]

You might want to mention that decryption is done with the key 94-factor. For example

Rotate(&x,StrLen(x),80) ; replace x with encrypted text

Rotate(&x,StrLen(x),14) ; replace x with decrypted original

ROT47 happens to be its own inverse. factor = 13 is NOT ROT13!

[SKAN]

ROT47 happens to be its own inverse. factor = 13 is NOT ROT13!

Thanks for informing it. I had not tried a number other than 47!

Regards,

[Laszlo]

we have a nice example, when regular expressions speed up the code

Not any more. The old style hex converter script is 15% faster with today's AHK release (version 1.0.46.01) than the RegEx version, thanks to the speedup of expressions. The lesson: because AHK is constantly improving, don't trust old speed comparisons.

#NoEnv

SetBatchLines -1



file = C:\Program Files\AutoHotkey\license.txt

FileRead b, %file%

b := b b b b b b b b b b



t2 := A_TickCount

h := tHex(b)

t2 := A_TickCount - t2

t1 := A_TickCount

h := toHex(b)

t1 := A_TickCount - t1



MsgBox Old style = %t2%`nRegEx = %t1%



tHex(ByRef b, s = 0) {

   f := A_FormatInteger

   SetFormat Integer, H

   VarSetCapacity(h, 5*(VarSetCapacity(b) * !s + s))

   Loop % VarSetCapacity(b) * !s + s

      h := h . *(&b+A_Index-1)+256

   StringReplace h, h, 0x1,,All

   SetFormat Integer, %f%

   Return h

}



toHex(ByRef b, s = 0) {

   f = %A_FormatInteger%

   SetFormat, Integer, H

   Loop, % VarSetCapacity(b) * !s + s

      h := h . *(&b + A_Index - 1)

   SetFormat, Integer, %f%

   h := RegExReplace(h, "0x(.)(?=0x|$)", "0$1")

   StringReplace h, h, 0x,,All

   Return h

}

[SKAN]

The lesson: because AHK is constantly improving, don't trust old speed comparisons.

Thanks,