9 replies to this topic

[Learning one]

WARNING: This is old thread. It is continued here.

[function] CreateTreeView
 
Creates TreeView from a string in which each item is placed in new line and hierarchy is defined by Tab character on the left. Item options can be added after one or more Tab characters after item name. This function is public domain.

Function

CreateTreeView(TreeViewDefinitionString) {	; by Learning one
	IDs := {} 
	Loop, parse, TreeViewDefinitionString, `n, `r
	{
		if A_LoopField is space
			continue
		Item := RTrim(A_LoopField, A_Space A_Tab), Item := LTrim(Item, A_Space), Level := 0
		While (SubStr(Item,1,1) = A_Tab)
			Level += 1,	Item := SubStr(Item, 2)
		RegExMatch(Item, "([^`t]*)([`t]*)([^`t]*)", match)	; match1 = ItemName, match3 = Options
		if (Level=0)
			IDs["Level0"] := TV_Add(match1, 0, match3)
		else
			IDs["Level" Level] := TV_Add(match1, IDs["Level" Level-1], match3)
	}
}	; http://www.autohotkey.com/board/topic/92863-function-createtreeview/

Example 1 - basic

TvDefinition=
(
File
	New
	Open
	Save
	Save as...
	Exit
Edit
	Undo
	Cut
	Copy
	Paste
	Delete
View
	Full screen
	Zoom
		100
		200
Help
)

Gui, Add, TreeView, h300
CreateTreeView(TvDefinition)
Gui, Show
return

GuiClose:
ExitApp

Example 2 - items with options

TvDefinition=
(
File				bold
	New
	Open			bold
	Save
	Save as...
	Exit
Edit
	Undo
	Cut
	Copy
	Paste
	Delete
View				Expand
	Full screen		Select
	Zoom
		100
		200
Help
)

Gui, Add, TreeView, h300
CreateTreeView(TvDefinition)
Gui, Show
return

GuiClose:
ExitApp

See also: [function] CreateMenu

[Learning one]

[function] CreateTreeView updated

- now it supports adding TV item options

[tidbit]

This is awesome. Treeviews have always been a pain, I have a template made just for them (though, I think I lost it when I got my new computer). This makes it so much more human-readable, thanks!

[Coco]

Cool! This makes it easier, thanks! I have a collection of functions that uses XML to create TreeView(s) with support for moving, indenting, etc. , still unfinished though..

[rbrtryn]

+100

 

Adding it to my standard library

 

[nitpick]

You could replace your RegExReplace with:

RegExMatch(Item,  "([^`t]*)([`t]*)([^`t]*)", match)

Has the same effect and is more compact.

[/nitpick]

[Pulover]

Great work! Thanks!

[Joy2DWorld]

        While (SubStr(Item,1,1) = A_Tab)
            Level += 1,    Item := SubStr(Item, 2)

 

 

 

Looping is one way of counting characters in a string,

 

but other ways more direct,

 

ex., regexmatch(item,"$(\t+)",_),  item := substr(item, level := strlen(_1))

 

could also just regexreplace away the tabs in second var & compare length to set level, etc.

 

hope sugestive.

[Learning one]

Thanks for suggestions and compliments!
@rbrtryn: RegExMatch is made more compact now. Thanks!
@Joy2DWorld: Hey, nice to see you again on AHK forum. I appreciate your suggestion, but I'll leave While loop.
 
* * *
 
Related: I totally rewrote and upgraded CreateMenu function, which uses the same logic to create menus. Will be released soon.

[tps242]

Does gLabels not work with this?

 

TvDefinition=
(
Game Client bold Expand
Client
Launch/Relaunch gLaunch
Log Off 
Quit
)
 

Gui, Add, TreeView, h300
CreateTreeView(TvDefinition)
 
Gui, Show
return
 
GuiClose:
ExitApp
 

CreateTreeView(TreeViewDefinitionString) { ; by Learning one
IDs := {} 
Loop, parse, TreeViewDefinitionString, `n, `r
{
if A_LoopField is space
continue
Item := RTrim(A_LoopField, A_Space A_Tab), Item := LTrim(Item, A_Space), Level := 0
While (SubStr(Item,1,1) = A_Tab)
Level += 1, Item := SubStr(Item, 2)
RegExMatch(Item, "([^`t]*)([`t]*)([^`t]*)", match) ; match1 = ItemName, match3 = Options
if (Level=0)
IDs["Level0"] := TV_Add(match1, 0, match3)
else
IDs["Level" Level] := TV_Add(match1, IDs["Level" Level-1], match3)
}
} ; http://www.autohotkey.com/board/topic/92863-function-createtreeview/
 
Shift::Reload
 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; GAME CLIENT - CLIENT ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
Launch:
IfWinNotActive, MapleStory, , WinActivate, MapleStory,
IfWinExist,MapleStory
{
WinClose
} else {
SplashImage,,M,,Maplestory is being relaunched/launched, Notice, 
Run C:\Nexon\MapleStory\HawtMaple.exe
Sleep, 5000
ControlSetText,Static1,If this window persists after Maplestory has launched; press {~}, Notice
SetTimer, MapleExist, 65
}
Return
 
MapleExist:
IfWinExist, MapleStory
{
SplashImage, Off
SetTimer, MapleExist, Off
}
return
 
splashreturn:
WinMove, Screenshot, , 0,  A_ScreenHeight-120
return
 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 

[tps242]

Okay I added it to the beginning and it works but adding AltSubmit next to the row and putting (A_GuiEvent == "Normal") under Launcher: label is not doing anything to stop it from launching, and only when the user left clicks it

 

 

Labels are completely ignored if i put it before showgui and it just continues line after line..until it hits a return

 

If I put it after showgui, nothing after the code applies the return, wth.