5 replies to this topic

[Cattleya]

Hi all Autohotkey Forum member.

I've searched AHK forum many time but only a few result about this topic but no answer at all, so I create this thread, I hope someone help me solve this problem

I'm making a installer using Autohotkey, I add create shortcut to desktop, quick launch feature to my installer and work, but when I try to add pin my app to taskbar feature, I can't find a way to do that. I tried to create my shortcut inside

C:\Users\<MyUsername>\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch\User Pinned\TaskBar

 

And restart my explorer.exe but nothing happen, seem only place my shortcut inside this folder cannot create pin item on taskbar.

I also found this post, but it was wrote in AutoIt, I cannot convert it to Autohotkey because it is out of my knowledge. Hope someone will help me.

http://www.autoitscr...kbar/?p=1050255

 

For Autohotkey I found InvokeVerb, but I don't know how to use.

 

Searched thread:

https://www.google.c...oq=&gs_l=&pbx=1

[nothing]

Best Answer

Hi there,
Nice to see you here.
Here's the solution:

Spoiler

PinToTaskbar("E:\Games\War\Warcraft III.exe")
PinToTaskbar(FilePath)
{
    SplitPath,FilePath,File,Dir
    For i in ComObjCreate("Shell.Application").Namespace(Dir).ParseName(File).Verbs()
        if (i.Name = "Pin to Tas&kbar")
            return i.DoIt()
} 

[Cattleya]

Thank you, nothing.

Your solution work perfectly

 

I also figure how to use  InvokeVerb, here is my example:

#Persistent

InvokeVerb("C:\Windows\System32\calc.exe", "Pin to Taskbar") ; or replace Pin to Taskbar with Pin to Start Menu to create pinned item on Start Menu

InvokeVerb(path, menu, validate=True) {
	;by A_Samurai
	;v 1.0.1 http://sites.google.com/site/ahkref/custom-functions/invokeverb
    objShell := ComObjCreate("Shell.Application")
    if InStr(FileExist(path), "D") || InStr(path, "::{") {
        objFolder := objShell.NameSpace(path)   
        objFolderItem := objFolder.Self
    } else {
        SplitPath, path, name, dir
        objFolder := objShell.NameSpace(dir)
        objFolderItem := objFolder.ParseName(name)
    }
    if validate {
        colVerbs := objFolderItem.Verbs   
        loop % colVerbs.Count {
            verb := colVerbs.Item(A_Index - 1)
            retMenu := verb.name
            StringReplace, retMenu, retMenu, &       
            if (retMenu = menu) {
                verb.DoIt
                Return True
            }
        }
        Return False
    } else
        objFolderItem.InvokeVerbEx(Menu)
}

[jNizM]

I dont like the pin-function in win7
Is there a way to add a toolbar to the taskbar?
A specific folder like "D:\toolbar\"

http://www.tomstrick...r-in-windows-7/

Screenshot
Screenshot2

[nothing]

@Cattleya: you're welcome.

@jNizM: is this? --> http://www.autohotke...-taskbar/page-2

[Cattleya]

@Cattleya: you're welcome.

@jNizM: is this? --> http://www.autohotke...-taskbar/page-2

Sorry for bumping my topic, But can I ask you a question about "Pin to Tas&kbar", is this menu work on Windows XP or only Windows 7 ?