AHK 进程管理

Post by **hitman** » 13 Apr 2017, 22:05

thx,good!

Post by **pk23** » 26 Feb 2017, 21:36

感谢，小巧好用

Post by **et2010** » 26 Jan 2017, 08:12

@tmplinshi 感谢你的快速回复，另存为UTF-8（with BOM）后问题已解决。

Post by **tmplinshi** » 26 Jan 2017, 03:04

@Guest 文件要保存为 UTF-8 (含BOM)

Post by **Guest** » 25 Jan 2017, 22:49

感谢分享！但是我运行时报错：

AhkScriptManager.ahk (32) : ==> Functions cannot contain functions.
Specifically: RefreshList()

Post by **huyaowen** » 27 Oct 2016, 00:22

试过好几个都太啰嗦，这个好。简单干练。

Post by **tmplinshi** » 26 Oct 2016, 23:29

: AhkScriptManager.png (7.49 KiB) Viewed 4861 times


#NoEnv
#NoTrayIcon
#SingleInstance Force
SetBatchLines -1
DetectHiddenWindows On

global HLV

CreateGUI()
CreateMenu()
RefreshList()
return

GuiClose:
GuiEscape:
ExitApp

CreateGUI() {
	Gui, Font, s10, 微软雅黑
	Gui, Add, ListView, w700 r10 Grid HwndHLV gLvEvent, 文件名|文件路径|PID
	Gui, Add, Button, xm gRefreshList, 刷新列表
	Gui, Show,, AHK 进程管理 v1.03
}

CreateMenu() {
	Loop, Parse, % "退出|重启|暂停|暂停热键||结束进程", |
		Menu, lvMenu, Add, % A_LoopField, MenuHandler

	Menu, lvMenu, Default, 退出
}

RefreshList() {
	LV_Delete()

	WinGet, id, List, ahk_class AutoHotkey
	Loop, %id% {
		this_id := id%A_Index%
		WinGet, this_pid, PID, ahk_id %this_id%

		WinGetTitle, this_title, ahk_id %this_id%
		fPath := RegExReplace(this_title, " - AutoHotkey v[\d.]+$")
		SplitPath, fPath, fName
		
		LV_Add("", fName, fPath, this_pid)
	}

	LV_ModifyCol()
}

GuiContextMenu(GuiHwnd, CtrlHwnd) {
	if (CtrlHwnd = HLV) && LV_GetNext() {
		Menu, lvMenu, Show
	}
}

MenuHandler(ItemName) {
	static cmd := {重启: 65303, 暂停热键: 65305, 暂停: 65306, 退出: 65307}
	static WM_COMMAND := 0x111

	if (ItemName = "结束进程") {
		for i, obj in GetSelectedInfo()
			Process, Close, % obj.pid
	} else {
		for i, obj in GetSelectedInfo()
			PostMessage, WM_COMMAND, % cmd[ItemName],,, % obj.path " ahk_pid " obj.pid
	}

	if (ItemName ~= "退出|结束|重启")
		SetTimer, RefreshList, -300
}

GetSelectedInfo() {
	RowNum := 0, arr := []
	while, RowNum := LV_GetNext(RowNum) {
		LV_GetText(path, RowNum, 2)
		LV_GetText(pid, RowNum, 3)
		arr.push( {pid: pid, path: path} )
	}
	return arr
}

LvEvent() {
	if (A_GuiEvent = "DoubleClick" && A_EventInfo)
		MenuHandler("退出")
}

类似工具: 脚本调试辅助器

AHK 进程管理

Post a reply

Expand view Topic review: AHK 进程管理

Re: AHK 进程管理

Re: AHK 进程管理

Re: AHK 进程管理

Re: AHK 进程管理

Re: AHK 进程管理

Re: AHK 进程管理

AHK 进程管理