[WEB-API] Bentschi.net (GetIP, GetGeo, GetWeather, ...)

[Bentschi]

Hallo,
Hier mal ein kleines neues Projekt das ich aufgrund eines größeren Projektes gestarted habe.
Dieses Projekt gebe ich kostenlos Öffentlich frei und werde es von Zeit zu Zeit mal erweitern.
Bzw. würde ich auch gerne eure Ideen für Erweiterungen/Verbesserungen hören.

Limitierungen:
- Ein Captcha (CreateCaptcha) ist nur max. 24 Stunden lang gültig

Hier das aktuellste Skript dazu:

Code: Select all

GetIP()
;http://api.bentschi.net/ip
{
  return (RegExMatch(BentschiNetAPI("api.bentschi.net/ip"), "([0-9]{1,3}(\.[0-9]{1,3}){3})", m)) ? m1 : ""
}

GetGeo(q="")
;http://api.bentschi.net/geo?[q=<IP-Address>]
{
  return BentschiNetAPI("api.bentschi.net/geo", {q:q})
}

GetWeather(q="") ;or {lat:y, lon:x}
;http://api.bentschi.net/weather?[q=<IP-Address|City/Country/...>]
;http://api.bentschi.net/weather?lat=<Latitude-Coordinate>&lon=<Longitude-Coordinate>
{
  return BentschiNetAPI("api.bentschi.net/weather", (q.lat && q.lon) ? q : {q:q})
}

CreateCaptcha(filename) ;Filetype: PNG
;http://api.bentschi.net/captcha
;http://api.bentschi.net/captchaImage?s=<Seed returned by captcha>
{
  FileDelete, % filename
  o := BentschiNetAPI("api.bentschi.net/captcha/")
  UrlDownloadToFile, % o.img, % filename
  return o.s
}

VerifyCaptcha(s, text)
;http://api.bentschi.net/captchaVerify?s=<Seed returned by captcha>&text=<Captchatext to verify>
{
  return BentschiNetAPI("api.bentschi.net/captchaVerify", {s:s, text:text})
}

BentschiNetAPI(v, d="")
{
  static hex := {0:0, 1:1, 2:2, 3:3, 4:4, 5:5, 6:6, 7:7, 8:8, 9:9, 10:"A", 11:"B", 12:"C", 13:"D", 14:"E", 15:"F"}
  if (v="postenc")
  {
    VarSetCapacity(s, StrPut(d, "utf-8"), 0), StrPut(d, &s, "cp0")
    while (c := NumGet(s, A_Index-1, "uchar"))
      o .= (RegExMatch(chr(c), "([a-zA-Z0-9])", m)) ? m1 : ("%" hex[(c&0xf0)>>4] hex[c&0x0f])
    return o
  }
  if (v="json")
  {
    if (regexmatch(d, "s)^__chr(A|W):(.*)", m))
    {
      VarSetCapacity(b, 4, 0), NumPut(m2, b, 0, "int")
      return StrGet(&b, 1, (m1="A") ? "cp28591" : "utf-16")
    }
    if (regexmatch(d, "s)^__str:((\\""|[^""])*)", m))
    {
      str := m1
      for p,r in {b:"`b", f:"`f", n:"`n", 0:"", r:"`r", t:"`t", v:"`v", "'":"'", """":"""", "/":"/"}
        str := regexreplace(str, "\\" p, r)
      while (regexmatch(str, "s)^(.*?)\\x([0-9a-fA-F]{2})(.*)", m))
        str := m1 BentschiNetAPI("json", "__chrA:0x" m2) m3
      while (regexmatch(str, "s)^(.*?)\\u([0-9a-fA-F]{4})(.*)", m))
        str := m1 BentschiNetAPI("json", "__chrW:0x" m2) m3
      while (regexmatch(str, "s)^(.*?)\\([0-9]{1,3})(.*)", m))
        str := m1 BentschiNetAPI("json", "__chrA:" m2) m3
      return regexreplace(str, "\\\\", "\")
    }
    str := [], obj := []
    while (RegExMatch(d, "s)^(.*?[^\\])""((\\""|[^""])*?[^\\]|)""(.*)$", m))
      str.insert(BentschiNetAPI("json", "__str:" m2)), d := m1 "__str<" str.maxIndex() ">" m4
    while (RegExMatch(RegExReplace(d, "\s+", ""), "s)^(.*?)(\{|\[)([^\{\[\]\}]*?)(\}|\])(.*)$", m))
    {
      a := (m2="{") ? 0 : 1, c := m3, d := m1 "__obj<" ((obj.maxIndex()+1) ? obj.maxIndex()+1 : 1) ">" m5, tmp := []
      while (RegExMatch(c, "^(.*?),(.*)$", m))
        tmp.insert(m1), c := m2
      tmp.insert(c), tmp2 := {}, obj.insert(cobj := {})
      for k,v in tmp
      {
        if (RegExMatch(v, "^(.*?):(.*)$", m))
          tmp2[m1] := m2
        else
          tmp2.insert(v)
      }
      for k,v in tmp2
      {
        for x,y in str
          k := RegExReplace(k, "__str<" x ">", y), v := RegExReplace(v, "__str<" x ">", y)
        for x,y in obj
          v := RegExMatch(v, "^__obj<" x ">$") ? y : v
        cobj[k] := v
      }
    }
    return obj[obj.maxIndex()]
  }
  o := q := ""
  for k,l in d
    q .= ((q) ? "&" : "") BentschiNetAPI("postenc", k) "=" BentschiNetAPI("postenc", l)
  if (!DllCall("LoadLibrary", "str", "wininet"))
    return
  if (!(hI := DllCall("wininet\InternetOpen", "str", "AutoHotkey/" A_AhkVersion, "uint", 1, "ptr", 0, "ptr", 0, "uint", 0, "ptr")))
    return
  if (hC := DllCall("wininet\InternetConnect", "ptr", hI, "str", regexreplace(v, "(^http:\/\/|\/.+$)"), "ushort", 80, "ptr", 0, "ptr", 0, "uint", 3, "uint", 0, "uint", 0, "ptr"))
  {
    if (hR := DllCall("wininet\HttpOpenRequest", "ptr", hC, "str", "POST", "str", regexreplace(v, "^(http:\/\/)?.+?\/"), "ptr", 0, "ptr", 0, "ptr", 0, "uint", 0x84280100, "ptr", 0, "ptr"))
    {
      hdr := "Content-Type: application/x-www-form-urlencoded"
      if (DllCall("wininet\HttpSendRequest", "ptr", hR, "str", hdr, "uint", StrLen(hdr), (q) ? "astr" : "ptr", (q) ? q : 0, "uint", StrLen(q)))
      {
        if (DllCall("wininet\HttpQueryInfo", "ptr", hR, "uint", 0x20000000|19, "uint*", sc, "uint*", scs := 4, "uint*", sci := 0) && sc=200)
        {
          while (DllCall("wininet\InternetQueryDataAvailable", "ptr", hR, "uint*", s, "uint", 0, "ptr", 0) && s>0)
          {
            DllCall("wininet\InternetReadFile", "ptr", hR, "ptr", (VarSetCapacity(b, s, 0)) ? &b : 0, "uint", s, "uint*", r)
            o .= StrGet(&b, r, "utf-8")
          }
        }
        else if (sc>=300 && sc<400)
        {
          VarSetCapacity(ql, qls := 4096, 0)
          if (DllCall("wininet\HttpQueryInfo", "ptr", hR, "uint", 33, "ptr", &ql, "uint*", qls, "uint*", qli := 0))
            o := BentschiNetAPI(StrGet(&ql), d)
        }
      }
      DllCall("wininet\InternetCloseHandle", "ptr", hR)
    }
    DllCall("wininet\InternetCloseHandle", "ptr", hC)
  }
  DllCall("wininet\InternetCloseHandle", "ptr", hI)
  return (RegExMatch(o, "^[\{\[]")) ? BentschiNetAPI("json", o) : o
}

GetIP

Spoiler

GetIP() gibt einfach nur die aktuelle IP-Adresse (String) aus mit der zum Internet verbunden wird.
Also MsgBox, % GetIP() würde etwas wie zB.: 123.45.678.910 ausgeben

GetGeo

Spoiler

GetGeo() gibt geografische Daten sowie Netzwerkdaten (ISP, etc.) zu einer angegebenen IP-Adresse aus.
Als Backend wird hierfür http://www.telize.com verwendet.
Wird an die Funktion keine IP-Adresse übergeben wird automatisch die IP ähnlich wie bei GetIP() verwendet.
Beispiel-Ausgabe*: GetGeo("173.194.113.33")

Code: Select all

Array
(
	[city] => Mountain View
	[continentCode] => NA
	[country] => United States
	[countryCode] => US
	[countryCode3] => USA
	[hostname] => fra02s20-in-f1.1e100.net
	[ip] => 173.194.113.33
	[isp] => Google Inc.
	[lat] => 37.4192
	[lon] => -122.0574
	[postalCode] => 94043
	[region] => California
	[regionCode] => CA
	[timezone] => America/Los_Angeles
)

GetWeather

Spoiler

GetWeather() gibt aktuelle Wetterdaten für die angegebene IP-Adresse, Längen-/Breitengrad oder Ort/Stadt/Land/... aus.
Längen- und Breitengrade werden per Objekt bsp. {lat:1.0, lon:2.0} übergeben.
Zurückgegeben wird ein Array aus Objekten, da sich zB. eine Abfrage wie GetWeather("London") auf mehrere Positionen beziehen kann.
Möglich ist aber auch eine Suche wie zB. GetWeather("London,UK") die dann nur eine Ausgabe im Array hätte.
Für das Backend wird http://www.telize.com für die bestimmung der Position per IP und http://openweathermap.org für die Wetterdaten verwendet.
Beispiel-Ausgabe*: GetWeather("London,UK")

Code: Select all

Array
(
	[1] => Array
	(
		[clouds] => 20
		[country] => GB
		[description] => shower rain
		[geoName] => London
		[humidity] => 68
		[lat] => 51.50853
		[lon] => -0.12574
		[pressure] => 1011
		[rain] => 0
		[tempC] => 19.83
		[tempF] => 67.694
		[tempMaxC] => 21.67
		[tempMaxF] => 71.006
		[tempMinC] => 18
		[tempMinF] => 64.4
		[weather] => Rain
		[weatherIcon] => 09d
		[weatherId] => 521
		[windDeg] => 240
		[windSpeedKm] => 5.1
		[windSpeedMiles] => 3.1671
	)
)

CreateCaptcha, VerifyCaptcha

Spoiler

CreateCaptcha erzeugt ein CaptchaBild das in filename gespeichert wird und gibt einen Seed zurück.
Der Seed wird für VerifyCaptcha zusammen mit dem text des Captchas verwendet um zu bestimmen ob diese überein stimmen.
Die URL für captchaImage würde auch die parameter r,g und b erlauben die für die Farbe (0-255) stehen.
Wichtig: Nach einem Aufruf von VerifyCaptcha sowie nach 24h wird der Seed ungültig und ein neues Captcha muss geladen werden!
Kleines Beispiel:

Code: Select all

seed := CreateCaptcha("captcha.png")
Gui, margin, 0, 0
Gui, add, pic, x0 y0 w300 h65, captcha.png
Gui, add, edit, vtext xp y+0 w200
Gui, add, button, gCaptcha x+0 yp w100 hp, Submit
Gui, show
return
Captcha:
GuiControlGet, text,, text
MsgBox, % VerifyCaptcha(seed, text)
GuiClose:
ExitApp

Dieser Code erzeugt etwas wie:

29.08.2014 - URI-Encoding für Postdaten im Skript hinzugefügt
29.08.2014 - Das Backend erlaubt jetzt neben den POST-Anfragen auch GET, daher können die Anfragen jetzt auch direkt im Browser getestet werden
29.08.2014 - Funktionen angepasst damit die Parameter-Namen ähnlich der der API sind
01.09.2014 - Die URL http://api.bentschi.net linkt jetzt zu diesem Artikel
01.09.2014 - CreateCaptcha und VerifyCaptcha hinzugefügt

* Die Ausgabe wurde mit print_r von SAPlayer formatiert

[ruespe]

Schick. Aber fehlt da nicht die BentschiNetAPI()?

[Bentschi]

Die ist doch im skript oben dabei