Class Object Method Overloading

[RFM]

Hello,

Have been working on making a class and came across another very important thing I use very often in classes, but apparently cannot be done in AutoHotKey. That is method overloading. This is where you have two or more methods with the same name, just different parameters. For example, here are two methods with the same name, but different parameters, rather, one has an additional parameter (I omitted the entire class definition, as only method overloading is of concern):

Code: Select all

	GetDesc(Item, default := "")
	{
		; <some code>	
	}
	
	GetDesc(Item, default := "", ByRef found)
	{
		; <some code>	
	}

I use method overloading quite a bit, not to have it available here is very disappointing.

[Helgef]

Maybe you can work with variadic functions.
Also, note,

all parameters that lie to the right of the first optional parameter must also be marked optional. [v1.0.90+]:
source

Good luck.

[wolf_II]

Code: Select all

MyFunction(Param1, Param2, Param3 := "") {
    If (Param3 = "")
        MsgBox, MyFunction() with 2 parameters
    Else
        MsgBox, MyFunction() with 3 parameters
}

[HotKeyIt]

Code: Select all

m:=new MyClass
m.GetDesc("a")
m.GetDesc("a","b")
m.GetDesc("c","d","e")
Class MyClass {
   GetDesc(v*){
      fun:=this["GetDesc" v.MaxIndex()]
      return %fun%(this,v*)
   }
   GetDesc1(Item){
      return this.GetDesc2(Item)
   }
   GetDesc2(Item, default := "")
   {
     MsgBox % A_ThisFunc "`n" Item "`n" default
   }

   GetDesc3(Item, default := "", ByRef found := "")
   {
     MsgBox % A_ThisFunc "`n" Item "`n" default "`n" found	
   }
}

[4GForce]

Code: Select all

m:=new MyClass
m.GetDesc("a")
m.GetDesc("a","b")
m.GetDesc("c","d","e")
Class MyClass {
   GetDesc(v*){
      fun:=this["GetDesc" v.MaxIndex()]
      return %fun%(this,v*)
   }
   GetDesc1(Item){
      return this.GetDesc2(Item)
   }
   GetDesc2(Item, default := "")
   {
     MsgBox % A_ThisFunc "`n" Item "`n" default
   }

   GetDesc3(Item, default := "", ByRef found := "")
   {
     MsgBox % A_ThisFunc "`n" Item "`n" default "`n" found	
   }
}

That's nice to know, isn't there another way with __Call ???

[HotKeyIt]

Code: Select all

m:=new MyClass
m.GetDesc("a")
m.GetDesc("b","c")
m.GetDesc("d","e","f")
Class MyClass {
   __Call(func,v*){
      If !IsFunc(fun:=this[Func])
         fun:=this[Func v.MaxIndex()]
      return %fun%(this,v*)
   }
   GetDesc1(Item){
      return this.GetDesc2(Item)
   }
   GetDesc2(Item, default := "")
   {
     MsgBox % A_ThisFunc "`n" Item "`n" default
   }

   GetDesc3(Item, default := "", ByRef found := "")
   {
     MsgBox % A_ThisFunc "`n" Item "`n" default "`n" found	
   }
}