Strings as arrays

[RFM]

One of my favorite languages treated strings as an array and could do the following (the "=" in that language is ":=" in AHK and "!" is the rest of line comment initiator):

myString = "This is my test string."
Char3 = myString[3] ! Char3 = "i"
Char7 = myString[7] ! Char7 = "s"
Chars3to7 = myString[3 : 7] ! Chars3to7 = "is is"
It did not do the following, which I would have liked:
CharsStartingAt3size5 := myString[3 # 5] ! CharsStartingAt3size5 = "is is"
Of course, you usually used variables in place of the numbers.

You could also do this:
myString[3] = "a" ! myString = "Thas is my test string."
myString[4] = "t" ! myString = "That is my test string."
myString[6 : 10] = "was a" ! myString = "That was a test string."
It did not do the following, which I would have liked:
myString[3 # 8] = "ere's my" ! myString = "There's my test string."

The above was a tremendous time saving syntax. It has the SubStr function as well to access characters within the string, and, of course, you could concatenate strings together to change the string, but the above syntax was so much simpler and quicker.

Sorry, though I have time to make a suggestion, I don't have time for an ongoing conversation about my suggestion!
This is my one and only post to this thread.
This is the "Wish List", this is my wish.

[jNizM]

You can use commands/StringSplit.htm and commands/SubStr.htm for this.

[Guest]

Just for reference:

Sinkfaze comes pretty close to this wish https://autohotkey.com/board/topic/5456 ... ipulation/

and you have TF & stringthings https://github.com/ahkscript/awesome-Au ... nipulation

[guest3456]

Just for reference:

Sinkfaze comes pretty close to this wish https://autohotkey.com/board/topic/5456 ... ipulation/

nice, I didn't know about that PythonStr library that sinkfaze created

[Guest]

Don't forget to checkout the link in the post beneath sinkfaze by jethrow https://autohotkey.com/board/topic/4670 ... ies-ahk-l/

[just me]

StrSplit() can be used to convert a string into an array of characters. But it won't permit myString[3 : 7].

[lexikos]

It's a minor convenience (syntax sugar) over simply using SubStr, but SubStr is less obscure for the uninitiated.

Code: Select all

myString := "This is my test string."
Char3 := myString[3] ; Char3 := "i"
Char7 := myString[7] ; Char7 := "s"
Chars3to7 := myString[3,,7] ; Chars3to7 := "is is"

CharsStartingAt3size5 := myString[3, 5] ; CharsStartingAt3size5 = "is is"

ListVars
Pause

StrIndex(s, i, n:="", j:="") {
    static _ := ("".base.__Get := Func("StrIndex"))
    return n="" ? j="" ? SubStr(s,i,1) : SubStr(s,i,j-i+1) : SubStr(s,i,n)
}

[TAC109]

Wow!

What just happened?!

[lexikos]

https://autohotkey.com/docs/Objects.htm ... ase_Object

[Flipeador]

https://autohotkey.com/docs/Objects.htm ... ase_Object

Interesting ... I never really played around this.
Edit*

Code: Select all

; ##############################################################################################################################################################
; EXAMPLE
; ##############################################################################################################################################################
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
; NEW
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
Str := "This is my test string."


; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
; GET
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
MsgBox % Str																				; This is my test string.
MsgBox % Str[]																			; This is my test string.
MsgBox % Str[7]																			; s
MsgBox % Str[17, 7]																	; string.
MsgBox % Str[0]																			; 23 (length)
MsgBox % Str.Length																	; 23 (length)


; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
; CALL
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
MsgBox % Str.Compare("This is my test string.")						; 1 (TRUE, CaseSensitive = 0)
MsgBox % Str.Compare("This is my test strinG.")						; 1 (TRUE, CaseSensitive = 0)
MsgBox % Str.Compare("This is my test strinG.", 1)					; 0 (FALSE, CaseSensitive = 1)

MsgBox % Str.InStr("my")															; 9


; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
; SET
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
Str[] := "This is my new test string."
MsgBox % Str 																			; This is my new test string.
Str[3] := 1
MsgBox % Str																				; Th1s is my new test string.
Str[12, 3] := "NEW"
MsgBox % Str																				; Th1s is my NEW test string.




















; ##############################################################################################################################################################
; DEFAULT BASE OBJECT
; ##############################################################################################################################################################
__DefaultBaseObject() {
	static _ := ("".base.base := {__Get: Func("__DefaultBaseObject__Get"), __Set: Func("__DefaultBaseObject__Set"), __Call: Func("__DefaultBaseObject__Call")})
}


; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
; GET
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
__DefaultBaseObject__Get(Var, Param*) {
	;X := Var[]
	if (!Param.MaxIndex())
		return (Var)
	
	;X := Var[0]	|	X := Var.Length
	else if (Param[1] = 0 || Param[1] = "Length")
		return (StrLen(Var))
	
	;X := Var[X], / X != 0
	return (Param[2] = "" ? (Param[3] = "" ? SubStr(Var, Param[1], 1) : SubStr(Var, Param[1], Param[3] - Param[1] + 1)) : SubStr(Var, Param[1], Param[2]))
}


; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
; SET
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
__DefaultBaseObject__Set(ByRef Var, Param*) {
	;Var[] := X
	if (Param.MaxIndex() = 1)
		Var := Param[1]
	
	;Var[X1] := X2
	else if (Param.MaxIndex() = 2)
		Var := SubStr(Var, 1, Param[1] - 1) . Param[2] . SubStr(Var, Param[1] + 1)
	
	;Var[X1, X2] := X3
	else if (Param.MaxIndex() = 3)
		Var := SubStr(Var, 1, Param[1] - 1) . Param[3] . SubStr(Var, Param[1] + Param[2])
	
	return (0)
}


; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
; CALL
; ///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
__DefaultBaseObject__Call(Var, FuncName, Param*) {
	;bool Compare(Var, CaseSensitive?)
	if (FuncName = "Compare")
		return (Param[2] ? (Var == Param[1]) : (Var = Param[1]))
	
	;int InStr(Needle, CaseSensitive?, StartingPos=1, Occurrence=1)
	else if (FuncName = "InStr")
		return InStr(Var, Param[1], !!Param[2], Param[3] = "" ? 1 : Param[3], Param[4] = "" ? 1 : Param[4])
}

https://github.com/flipeador/AutoHotkey ... Object.ahk

---

I could replace a character doing this:

Code: Select all

Str := "This is my test string."

Pos			:= 3
Replace	:= "1"
NumPut(Ord(Replace), Str, (Pos - 1) * 2, "Uchar")

MsgBox % Str

But not work for all (someone could explain?):

Code: Select all

Str := "This is my test string."

Pos			:= 3
Replace	:= "•"
NumPut(Ord(Replace), Str, (Pos - 1) * 2, "Uchar")

MsgBox % Str

[HotKeyIt]

Code: Select all

Str := "This is my test string."

Pos			:= 3
Replace	:= "•"
NumPut(Ord(Replace), Str, (Pos - 1) * 2, A_IsUnicode?"USHORT":"UCHAR")

MsgBox % Str

[nnnik]

I normally don't like youtube videos but noone explains it better than this guy does:

[Flipeador]

Code: Select all

Str := "This is my test string."

Pos			:= 3
Replace	:= "•"
NumPut(Ord(Replace), Str, (Pos - 1) * 2, A_IsUnicode?"USHORT":"UCHAR")

MsgBox % Str

I must pay more attention .
Thanks HotKeyIt.

[nnnik]

Please don't ignore me

[Flipeador]

Please don't ignore me

Haha, I have not ignored you, it seems that the video you have posted does not appear to me, but I have already extracted the URL. I had to activate the subtitles to understand what he is saying (my English is medium).
I've seen other vídeos too. Thanks nnnik .

[niczoom]

Great video! I didn't know much about UTF8, now I do.