1.1.29.00 Display Issue

[TLM]

Latest version does not display inline values correctly

Code: Select all

MsgBox % ">>" ["A", "B", "C"].Count() "<<"
MsgBox % ">>" ["A", "B", "C"].Length() "<<"

Both display << only..
Isolated works

Code: Select all

MsgBox % ">>" ( ["A", "B", "C"].Count() ) "<<"

[swagfag]

i dont think this has much to do with the update in and of itself.
here's something on 1.1.28.02:

Code: Select all

; MsgBox % ">>" ["A", "B", "C"].Count() "<<" ; not available in 1.1.28.02

MsgBox % ">>" ["A", "B", "C"].Length() "<<" ; doesnt work, returns: <<

arr := ["A", "B", "C"]
MsgBox % ">>" arr.Length() "<<" ; works, returns: >>3<<

MsgBox % ["A", "B", "C"].Length() ; expression, works, returns: 3

MsgBox % ">>" . ["A", "B", "C"].Length() . "<<" ; explicit concat, works, returns: >>3<<
MsgBox % ">>" (["A", "B", "C"].Length()) "<<" ; forced expression/implicit concat, works, returns: >>3<<

[Helgef]

This is documented behaviour.

[v1.0.97+]: Array literal. If the open-bracket is not preceded by a value (or a sub-expression which yields a value), it is interpreted as the beginning of an array literal. For example, [a, b, c] is equivalent to Array(a, b, c)

Hence, if it is, it isn't. (That is ["A","B","C"] tries to do member access on ">>" which isn't valid)

Spoiler

In v2, you'll get the appropriate error message

Cheers.

[swagfag]

.. tries to do member access on ">>" which isn't valid..

how so?

Code: Select all

; https://autohotkey.com/docs/Variables.htm#operators
; https://autohotkey.com/boards/viewtopic.php?f=14&t=49605
; 1.1.28.02 btw if that makes any difference

Arr := {"A": {"B": {"C": "kek"}}}
MsgBox, % "Arr" ["A", "B", "C"] ; supposed member access, returns: blank
MsgBox, % Arr["A", "B", "C"] ; actual member access, returns: kek

; >> := {"A": {"B": {"C": "kek"}}} ; moot, cant declare var '>>'
; MsgBox, % ">>" ["A", "B", "C"] ; moot, cant declare var '>>'
; MsgBox, % >>["A", "B", "C"] ; moot, cant declare var '>>'

[Helgef]

As I said, it is invalid, because you cannot member access a string.

Spoiler

Code: Select all

"".base.__get := "f"
Arr := {"A": {"B": {"C": "kek"}}}
MsgBox, % "Arr" ["A", "B", "C"] ; supposed member access, returns: blank

f(this, p*){
	global
	return %this%[p*]
}

Cheers.

[swagfag]

i see

Spoiler

now onto figuring out why this uhhh, nifty, i guess?, snippet reminded me of a contortionist is saw not too long ago trying to jam himself in a box, clearly not intended for that purpose. i do wonder...

[jeeswg]

- Here's the issue, you can put a space between the object name and the first square bracket.
- If you use a literal string for the object name, it refers to the base object for strings.

Code: Select all

q:: ;get value from object/string
"".base.__get := "f"
Arr := {"A": {"B": {"C": "hey"}}}
MsgBox, % "Arr" ["A", "B", "C"] ;HEY ;surprising
MsgBox, % Arr ["A", "B", "C"] ;hey ;surprising
MsgBox, % "Arr"["A", "B", "C"] ;HEY ;surprising
MsgBox, % Arr["A", "B", "C"] ;hey
return

f()
{
	return "HEY"
}

- I had this issue before, but I've only now fully understood it. (Thanks Helgef.)
possible issue with GetCapacity? - AutoHotkey Community
https://autohotkey.com/boards/viewtopic ... 10#p153010

[lexikos]

As I said, it is invalid, because you cannot member access a string.

It is invalid because strings have no members by default. As you showed, it can be valid.