Konfigurierbares AHK-Menu für Schnellzugriff

[divanebaba]

Konfigurierbares AHK-Menu.
Für blitzschnellen Zugriff auf vordefinierte Programme, Labels etc..

Leistung ist auch eine Frage der Organisation.
Wenn jemand für ein spezielles Programm häufig separate Zusatzprogramme oder Makros benutzt, wird ein schneller Zugriff auf diese vorteilhaft sein.
Ein AHK-Menu, in dem solche Zusatzprogramme und Makros aufgelistet sind, bietet schnellen Zugriff.
Wenn dieses AHK-Menu auch noch, mit z. B. ifwinactive, gezielt bestimmte Menüs aufrufen kann, spart es nochmal zusätzlich Zeit.

Dieses Skript erstellt, überflüssigerweise, auch noch ein Traymenu.

Es ist nix Besonderes.
Die hervorzuhebende Funktion ist, mit ifwinactive, viel benutzten Programmen eine vorausgewählte Palette Zusatztools bereitzustellen.
Der zeilenweise Aufbau hilft bei der Übersichtlichkeit.

Die Ursprünge liegen bei der Arbeit, wo ich eines von etwa einem Dutzend Makros sehr oft, zusätzlich zu einem aktiven Programm, ausführen musste.
Dort und auch Zuhause erspart es mir viel Zeit, ohne daß ich mir ständig irgendwelche HotKeys oder Hotstrings merken muss.

Langweiliges Testskript.
Voreingestellte Tastenkombination RAlt & ä. Nach Drücken der Tastenkombination RAlt & ä öffnet sich ein Standard-AHK-Menü.

Dieses Skript kann:
1. Programme ausführen (Pfadangabe in Eintrag_5)
2. Labels ausführen (Labelangabe in Eintrag_2)
3. Ordner öffnen (Benutzerdefiniertes Icon notwendig)
Bitte beachtet, daß, für die Nutzung von benutzerdefinierten Icons, das Skript einen Ordner mit Icons in %A_ScriptDir% benötigt.

Code: Select all

iconpath = % a_ScriptDir . "\" . "icons" ; Hier müssen die genutzten Icons abgelegt sein

Das Beispielskript ist folgendermaßen auszuprobieren:
- Code kopieren und als beliebig zu benennende ahk-Datei abspeichern und ausführen.
- Tastenkombination RAlt + ä drücken.
- Im angezeigten Menu auf Notepad (Windows-Editor) klicken.
- Sollte der Editor nicht aktiv sein, auf dessen Fenster klicken und aktivieren.
- Jetzt erneut die Tastenkombination RAlt + ä drücken.
- Es sollte nun ein anderes Menu zu sehen sein.
- Irgendwohin klicken, um das Menü zu schließen.
- Dieselbe Prozedur mit deaktiviertem Editor-Fenster ausführen.

Man sollte sehen, daß, je nachdem, ob der Editor aktiv oder inaktiv ist, ein anderes Menu geöffnet wird.
Selbiges gilt auch für Microsoft-Paint.
Code:

Code: Select all

; Created by RP alias divanebaba
; Version: Prinzip-Demo 05.06.2017
; 
; Funktion:
; Nach Betätigen der Tastenkombination AltGr & ä, öffnet sich an der Mausposition ein Menu.
; Mit "[color=#0000FF]ifwinactive[/color]" kann das Menu bestimmten Programmen
; ausgewählte Makros, Zusatzprogramme, Pfade etc. zur Verfügung stellen
; Hier, als Beispiel, Notepad und Paint, denen verschiedene Menueintäge zur Verfügung gestellt werden.
; Die Menüs können folgendermaßen zusammengestell werden
;
; Alle Einträge werden mit einem Komma getrennt. Siehe Beispiel:
; Eintrag_1,Eintrag_2,Eintrag_3,Eintrag_4,Eintrag_5
;
; Eintrag_1 = Menueintrag
; Eintrag_2 = Label [muss entfallen, wenn Eintrag_5 Pfad zur exe]
; Eintrag_3 = Iconname ohne Endung [muss entfallen, wenn Eintrag_5 Pfad zur exe]
; Eintrag_4 = Icongröße [kann entfallen, wenn Eintrag_5 Pfad zur exe]
; Eintrag_5 = Pfadname zur ausführbaren Datei

; Trennstriche werden mit einem einzigen Komma erzeugt
; +++++++++++++++++++++++++++++++++++++++++++++++++++
; Anmerkung zu Eintrag_2, und Eintrag_3.
; Sollten eigene Icons benutzt werden, wird ein Unterordner namens icons benötigt
; iconpath = % a_ScriptDir . "\" . "icons"
; dort können benutzerdefinierte Icons abgelegt und über Eintrag_3 eingelesen werden
; +++++++++++++++++++++++++++++++++++++++++++++++++++

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance force

; Benötigt einen Ordner mit Icons
iconpath = % a_ScriptDir . "\" . "icons"

mEditor =		; SUBMENUE Solid Edge
(
WordPad,,,,C:\Windows\write.exe
MSCONFIG,,,,C:\Windows\System32\msconfig.exe
WordPad,,,,C:\Windows\write.exe
)

mPaint =
(
Rechner,,,,C:\Windows\System32\calc.exe
Notepad,,,64,C:\Windows\notepad.exe
RegEdit,,,48,C:\Windows\regedit.exe
WordPad,,,32,C:\Windows\write.exe
)

mMenu1 =
(
MSPaint,,,,C:\Windows\System32\mspaint.exe
Notepad,,,48,C:\Windows\notepad.exe
RegEdit,,,32,C:\Windows\regedit.exe
Rechner,,,,C:\Windows\System32\calc.exe
MSCONFIG,,,,C:\Windows\System32\msconfig.exe
SnippingTool,,,,C:\Windows\System32\SnippingTool.exe
DirektX-Diagnose,,,,C:\Windows\System32\dxdiag.exe
)

mMenu2 =
(
Notepad,,,48,C:\Windows\notepad.exe
RegEdit,,,32,C:\Windows\regedit.exe
WordPad,,,,C:\Windows\write.exe
)

; Blöcke mit Untermenüs
; Da die Menues erst erstellt werden müssen, bevor sie als Untermenue eingebunden werden können, werden Blöcke mit verweisenden Untermenues separat erstellt

Menu1 =
(
,
Untermenu Editor,:mEditor
Untermenu Paint,:mPaint
Untermenu Menu2,:mMenu2
)

Menu2 =
(
,
Untermenu Editor,:mEditor
Untermenu Paint,:mPaint
Untermenu Menu1,:mMenu1
)

Menu_Editor =
(
,
Untermenu Paint,:mPaint
Untermenu Menu1,:mMenu1
Untermenu Menu2,:mMenu2
)

Menu_Paint =
(
,
Untermenu Editor,:mEditor
Untermenu Menu1,:mMenu1
Untermenu Menu2,:mMenu2
)

Menu1=%mMenu1%`n%Menu1%
Menu2=%mMenu2%`n%Menu2%
Menu_Editor=%mEditor%`n%Menu_Editor%
Menu_Paint=%mPaint%`n%Menu_Paint%

All_Menu = mMenu1|mMenu2|mEditor|mPaint|Menu1|Menu2|Menu_Editor|Menu_Paint

loop, parse, All_Menu, |
{	menu_name:=A_Loopfield
	Loop, parse, %A_Loopfield%, `n, `r
	{
		If (!A_Loopfield or SubStr(A_Loopfield,1,1)=";")
		Continue
		Stringsplit, Eintrag_, A_Loopfield, `,
		ifequal, Eintrag_1
		Menu, %menu_name%, add
		if Eintrag_1 <>
		{
			If (SubStr(Eintrag_2,1,1)=":")
			{
				Menu, %menu_name%, Add, %Eintrag_1%, %Eintrag_2%
				ifnotequal Eintrag_3
				Menu, %menu_name%, Icon, %Eintrag_1%, %iconpath%\%Eintrag_3%.ico, , %Eintrag_4%
			}
			else
			{
				Menu, %menu_name%, Add, %Eintrag_1%, MenuHandler
				ifnotequal Eintrag_3
				Menu, %menu_name%, Icon, %Eintrag_1%, %iconpath%\%Eintrag_3%.ico, , %Eintrag_4%
				else
				{
					if !Eintrag_4
					Eintrag_4=32
					Menu, %menu_name%, Icon, %Eintrag_1%, %Eintrag_5%, 1, %Eintrag_4%
				}
			}
		}
	}
}	
	
; ############ MENULISTEN
Tray=
(
,
SnippingTool,,,,C:\Windows\System32\SnippingTool.exe
DirektX-Diagnose,,,,C:\Windows\System32\dxdiag.exe
,
Notepad,,,48,C:\Windows\notepad.exe
)

Tray=%Tray%`n%Menu1%

Loop, parse, Tray, `n, `r
{
	If (!A_Loopfield or SubStr(A_Loopfield,1,1)=";")
	Continue
	Stringsplit, Eintrag_, A_Loopfield, `,
	if (!Eintrag_1 && !Eintrag_2)
	Menu, Tray, add
	if Eintrag_1 <>
	{
		ifequal, Eintrag_2
		{
			Menu, Tray, Add, %Eintrag_1%, MenuHandler
			ifnotequal Eintrag_3
			Menu, Tray, Icon, %Eintrag_1%, %iconpath%\%Eintrag_3%.ico,, %Eintrag_4%
			continue
		}
		
			If (SubStr(Eintrag_2,1,1)=":")
			{
				Menu, Tray, Add, %Eintrag_1%, %Eintrag_2%
				ifnotequal Eintrag_3
				Menu, Tray, icon, %Eintrag_1%, %iconpath%\%Eintrag_3%.ico,, %Eintrag_4%
			}
			else
			{
			Menu, Tray, Add, %Eintrag_1%, MenuHandler
			ifnotequal Eintrag_3
			Menu, Tray, Icon, %Eintrag_1%, %iconpath%\%Eintrag_3%.ico, , %Eintrag_4%
			else
			{
				if !Eintrag_4
				Eintrag_4=32
				Menu, Tray, Icon, %Eintrag_1%, %Eintrag_5%, 1, %Eintrag_4%
			}
			}
	}
}	
Menu, Tray, Icon, %A_AhkPath%, 2
Return

MenuHandler:
Loop, parse, %A_ThisMenu%, `n, `r
{
	IfInString, A_LoopField, %A_ThisMenuItem%
	{
		Stringsplit, EintragIn_, A_Loopfield, `,
		{
			ifnotequal, EintragIn_2
			gosub %EintragIn_2%
			else
			{
				ifexist, %EintragIn_5%
				run %EintragIn_5%
				else
				msgbox %EintragIn_5%`n`nnot exist.
			}
			return
		}
	}
}
return

RAlt & ä::
settitlematchmode, 2
ifwinactive, - Editor
{
	Menu, Menu_Editor, show
	return
}
ifwinactive, - Paint
{
	Menu, Menu_Paint, show
	return
}
Menu, Menu1, show
return

Das wirklich Besondere an dem Skript ist, die mit "ifwinactive" automatisierte Möglichkeit, ausgewählten Programmen weiterführende Tools zur Verfügung zu stellen, ohne sich den Ablageort merken oder suchen zu müssen. Workflow nennt man das auf Neudeutsch.

Ich habe seinerzeit dem CAD-Programm Solid Edge häufig benutzte Makros zur Verfügung gestellt.
Das Skript nutze ich noch immer. Ich führe es mit xButton2, der Daumentaste der Maus aus.

Dieses Skript ist nur sinnvoll, wenn man es für die eigenen Zwecke anpasst.
Das Beispielskript ist, ohne Anpassung, vollkommen nutzlos.

[jstklw]

hallo @divanebaba,

ich suche gerade für meine Kollegen aus der Konstruktion ein paar Macros oder AHK-Funktionen.
Was hattest Du für Macros oder AHK-Skripte umgesetzt?

Vielen DANK!

[BoBo]

@jstklw - SolidEdge macros/functions?

[jstklw]

Hallo BoBo,

ja - divanebaba erwähnt ja, dass er:

"Ich habe seinerzeit dem CAD-Programm Solid Edge häufig benutzte Makros zur Verfügung gestellt.
Das Skript nutze ich noch immer. Ich führe es mit xButton2, der Daumentaste der Maus aus."

da wollte ich halt mal wissen was er so umgesetzt hat.

[erwe]

Pardon, ein kleines funktionsfähiges Beispiel wäre toll ( Notepad und Calc?)
Danke, Freundliche Grüße. Erwe

[garry]

ein kurzes Beispiel MenuTray

Code: Select all

;- MENU_TRAY / open with rightclick
#warn
#Persistent
setworkingdir,%a_scriptdir%
;----------
Data=
(join`r`n
Calc;calc
Notepad;notepad
Desktop;%a_desktop%
Charmap;charmap
Autohotkey;https://autohotkey.com/
Fonts;C:\WINDOWS\Fonts
Exit;Exit
)
;----------
Menu, Tray, NoStandard
Loop, parse, data, `n, `r
  {
  stringsplit,c,A_LoopField,`;
  Menu, tray, add, %c1%, a1
  bt%a_index%:=c2
  }
Return
;-----------------------------------------------
a1:
x:=A_ThisMenuItem,y:=A_ThisMenuItemPos,e:=bt%y%
If (e="Exit")
   ExitApp
try   
run,%e%
return
;===============================

[jstklw]

Hallo erwe, Hallo garry,

vielen Dank für Eure Antworten und das Beispiel.

Mir ging es weniger um das Menu, mehr um die Macros hinsichtlich Solid Edge.
Sorry wenn ich das noch nicht so klar kommuniziert habe.

Trotzdem - vielen Dank!

[divanebaba]

Das geschwindigkeitserhöhende Prinzip, bei meiner Skriptvorstellung, ist, daß je nach dem, welches Fenster aktiv ist, ein gänzlich anderes Menü angezeigt werden kann.
Wenn der Explorer, der Desktop oder der MP3-Player aktiv ist, brauche ich nunmal ganz andere Tools, als wenn mein CAD-Programm geöffnet ist.

Zur Frage von @jstklw
Erfreulicherweise haben die neuesten Versionen, von Solid Edge, viele Funktionen der früher erhältlichen Makros übernommen.

Meine Makros waren nur klickintensive Aufgaben automatisieren, also Kleinigkeiten, wie Fensteransichten manipulieren, zugehörige Draft eines aktiven Teils oder einer Zusammenstellung blitzschnell öffnen, Stapelverarbeitung beim Drucken von Zeichnungssätzen, Manipulationen von Variablenwerten für Animationen etc.
Der Vorteil des o.g. Skriptes ist, daß jedes gewünschte Makro oder Skript immer nur zwei Klicks entfernt und nicht an unterschiedlichen Stellen im Windows-Band versteckt gewesen sind.

Fensteransichten manipulieren hört sich banal an, doch SE greift angeblich, beim Rendern von Fensteransichten, auf Windows-Funktionen zurück.
Da gibt es ein paar Methoden, unglaublich viel Zeit beim nahezu permanentem Rendern zu sparen. Natürlich bei unveränderten Rendereigenschaften, denn sonst wäre es ja witzlos.
Das sind zwar nur Einsparungen im Millisekundenbereich, doch da diese mehrere Tausend Male täglich erfolgen, sollte man theoretisch täglich einige Sekunden oder gar Minuten gespart haben.
Meine Info ist über zwanzig Jahre alt. Vielleicht hat sich in dem Punkt ja etwas getan.

All das Tempo und das KnowHow sind aber allzuoft nutzlos.
Für eine Karriere, in der Industrie, könnte das Googeln nach Gleitcreme, statt SE-Makros, zielführender sein.