Basic Warframe Auto Login

Post gaming related scripts
TygerByte
Posts: 96
Joined: 12 Aug 2016, 05:22

Basic Warframe Auto Login

14 Dec 2017, 10:12

I made an auto login for Warframe. It's not a good a idea to run because your password is saved in plain text and if you don't know what that means then you should not use this script. If you would still like to use it you'll find my example below and you may need to change the the password used if it's not the same as your password Also potentially change the color of the login button color as I do run a Reshade for Warframe which changes my colors, but I have checked a few times on a regular setup and verified it worked. Another note is that the script is set to start Warframe in 64bit mode, dx11, and not fullscreen. The PixelSeach will work on Borderless Fullscreen and Windowed mode, but Windowed would require some changes to the pixel coordinates.

Updated the script to include Nextron's until loop on the Play button because my original setup still failed to hit Play on occasions. Thanks Nextron!

Code: Select all

#NoEnv
SetWorkingDir %A_ScriptDir%
DetectHiddenWindows, On
SetKeyDelay, 40, 40
SetMouseDelay, 40
SetTitleMatchMode, 2
SetFormat, FloatFast, 0 ;; Round the math up.

;; Configuration
Bypass := 0                    ;; Start Warframe w/o Steam or the checking for updates with the launcher. Not a good idea if there's updates.
LoginButtonColor := 0xD7D7D7   ;; A Gray Color I use to determine the Login Button is Visable
LoginBtnVariation := 25        ;; PixelSearch color variation set to 25 works for my setup.
MyPassword = WaitingRoomGame

;; The Script
If ( Bypass = 0 )
{
	Run, steam://rungameid/230410   ;; Steam Browser Link to Warframe
	SetTimer, CheckPlayBtn, 200     ;; Check for the PLAY button
}
Else
{
	;; Steamless Startup
	RegRead, TheLauncherEXE, HKEY_CURRENT_USER\Software\Digital Extremes\Warframe\Launcher, LauncherExe
	SplitPath, TheLauncherEXE, l_name, l_dir
	
	;Run, %TheLauncherEXE%  -cluster:public -registry:Steam, %l_dir%   ;; Uncomment this line to Run the Launcher and check for updates, but no Steam.
	;SetTimer, CtrlWait, 200                                           ;; Uncomment this one too if you want to run the launcher without Steam. Remember to comment the line below after!
	
	Run, %l_dir%\..\Warframe.x64.exe -fullscreen:0 -dx10:0 -dx11:1 -threadedworker:1 -cluster:public -language:en   ;; Start Warframe in 64bit Directx11 non-fullscreen mode.
}

;; After Launcher runs or not wait for WF to start and grab some stats we need for pixel searching.
WinWaitActive, WARFRAME ahk_exe Warframe.x64.exe
WinGetActiveStats, wTitle, wWidth, wHeight, wX, wY
h_wWidth := ( wWidth / 2 )            ; Half window width
l_wHeight := ( wHeight * 0.766666 )   ; Login Button yPosition
p_wHeight := ( wHeight * 0.726851 )   ; Password Box yPosition
h_wHeight := ( wHeight / 2 )          ; Half window height

Loop,
{
	If !WinActive( "WARFRAME ahk_exe Warframe.x64.exe" )
	{
		WinWaitActive, WARFRAME ahk_exe Warframe.x64.exe
	}
	
	;; Get the Login Color
	; PixelGetColor, MyLoginClr, %h_wWidth%, %l_wHeight% 
	; Tooltip, Login Color is %MyLoginClr%, 10, 10
	
	;; Look for the Gray Login Button. Color could be wrong on some setups if you use something like Reshade/SweetFX
	PixelSearch, , , %h_wWidth%, %l_wHeight%, %h_wWidth%, %l_wHeight%, %LoginButtonColor%, %LoginBtnVariation%
	If ( Errorlevel = 0 ) && WinActive( "WARFRAME ahk_exe Warframe.x64.exe" )
	{
		Break
	}
	Sleep, 100 ; Stop spamming
}

BlockInput, On
Send, {Click, %h_wWidth%, %p_wHeight%, 3}   ; Have to click the password box because the cursor poofs sometimes. Thanks DE.
Sleep, 30
ControlSendRaw, , %MyPassword%, WARFRAME ahk_exe Warframe.x64.exe   ; ControlSend so our password isn't sent to the wrong window on accident.
Sleep, 30
SendInput, {Enter}
BlockInput, Off
ExitApp

CheckPlayBtn:
	ControlGet, PlayButton, HWND, , Warframe is up to date!, Warframe ahk_exe Launcher.exe   ; Look for these words so we know WF is up to date.
	If !PlayButton
	{
		Return
	}
	Else
	{
		Loop 
		{
			While WinExist("Warframe ahk_class Launcher ahk_exe Launcher.exe")
			{
				ControlClick, PLAY, Warframe ahk_class Launcher ahk_exe Launcher.exe
				Sleep, 200
			}
			Sleep, 1500
		} Until !WinExist("Warframe ahk_class Launcher ahk_exe Launcher.exe")   ;Second loop in case the launcher updates and restarts		
		SetTimer, CheckPlayBtn, Off
	}
Return
On a side note you could easily turn this into a daily login script if you really want to accumulate those logins while on vacation.

UPDATE: Pixel location and color has changed on the new login screen and I haven't bothered to update it. You'll have to change that and it should work again.
Last edited by TygerByte on 19 Jul 2018, 17:56, edited 7 times in total.
User avatar
Nextron
Posts: 1391
Joined: 01 Oct 2013, 08:23
Location: Netherlands OS: Win10 AHK: Unicode x32

Re: Basic Warframe Auto Login

14 Dec 2017, 11:13

You know starting a game is too cumbersome if people are motivated enough the script it. :lol:

As did i... :silent: Since I run the game in regular fullscreen, I can't do a pixelsearch for the login button, so I made it trigger the password input by manually pressing enter when the login screen loads.
I was surprised the line ControlClick, PLAY, Warframe ahk_exe Launcher.exe works. Since the launcher is a Chrome app with no discernible controls.

My quick-and-dirty:

Code: Select all

Run "C:\Program Files (x86)\Steam\steamapps\common\Warframe\Tools\Launcher.exe" -cluster:public -registry:Steam
WinWaitActive,Warframe ahk_class Launcher ahk_exe Launcher.exe
Loop {
	While WinExist("Warframe ahk_class Launcher ahk_exe Launcher.exe"){
		ControlClick,x760 y600,Warframe ahk_class Launcher ahk_exe Launcher.exe
		Sleep,200
	}
	Sleep 1500
}Until !WinExist("Warframe ahk_class Launcher ahk_exe Launcher.exe") ;Second loop in case the launcher updates and restarts
KeyWait,Enter,DT90
If ErrorLevel
	ExitApp
Send,PASSWORDHERE{Enter}
ExitApp
TygerByte
Posts: 96
Joined: 12 Aug 2016, 05:22

Re: Basic Warframe Auto Login

14 Dec 2017, 15:19

Ahh I only discovered it using toralf's "AHK Window Info 1.7", but the Play is always present so I made a cheap workaround waiting for "Warframe is up to date!". Thanks for showing me your setup. :D
FlaccidPotato
Posts: 5
Joined: 17 Jul 2018, 17:13

Re: Basic Warframe Auto Login

17 Jul 2018, 17:21

Can anyone help me as it isn't typing my password in after launching the game to the login screen? My code is below -

Code: Select all

Run "G:\Game Installs\SteamApps\common\Warframe\Tools\Launcher.exe" -cluster:public -registry:Steam
WinWaitActive,Warframe ahk_class Launcher ahk_exe Launcher.exe
Loop {
	While WinExist("Warframe ahk_class Launcher ahk_exe Launcher.exe"){
		ControlClick,x760 y600,Warframe ahk_class Launcher ahk_exe Launcher.exe
		Sleep,200
	}
	Sleep 1500
}Until !WinExist("Warframe ahk_class Launcher ahk_exe Launcher.exe") ;Second loop in case the launcher updates and restarts
KeyWait,Enter,DT90
If ErrorLevel
	ExitApp
Send,*****{Enter}
ExitApp
TygerByte
Posts: 96
Joined: 12 Aug 2016, 05:22

Re: Basic Warframe Auto Login

19 Jul 2018, 17:53

FlaccidPotato wrote:Can anyone help me as it isn't typing my password in after launching the game to the login screen? My code is below -
Should check to make sure the Cursor is blinking in the Password input box and then you can push Enter. If it's not blinking you need to click in the input box to move the cursor there.
FlaccidPotato
Posts: 5
Joined: 17 Jul 2018, 17:13

Re: Basic Warframe Auto Login

24 Jul 2018, 15:12

TygerByte wrote:
FlaccidPotato wrote:Can anyone help me as it isn't typing my password in after launching the game to the login screen? My code is below -
Should check to make sure the Cursor is blinking in the Password input box and then you can push Enter. If it's not blinking you need to click in the input box to move the cursor there.
Yeah it is ready for input, but the password just doesn't get typed in.
Senx

Re: Basic Warframe Auto Login

01 Aug 2018, 18:23

Someone found a solution for the problem above?
User avatar
Nextron
Posts: 1391
Joined: 01 Oct 2013, 08:23
Location: Netherlands OS: Win10 AHK: Unicode x32

Re: Basic Warframe Auto Login

02 Aug 2018, 09:46

I just updated the game for the first time in years and tried the login script, but for me it still worked, so the problem isn't due to game changes.

you could try placing a Soundbeep line, before the Send,PASSWORD, so you can hear if and when the pass is typed as a debug measure.
FlaccidPotato
Posts: 5
Joined: 17 Jul 2018, 17:13

Re: Basic Warframe Auto Login

06 Aug 2018, 06:57

Nextron wrote:I just updated the game for the first time in years and tried the login script, but for me it still worked, so the problem isn't due to game changes.

you could try placing a Soundbeep line, before the Send,PASSWORD, so you can hear if and when the pass is typed as a debug measure.
I literally have no idea how to do that lol.

Also which script did you use? The first post's or the seconds post?
User avatar
Nextron
Posts: 1391
Joined: 01 Oct 2013, 08:23
Location: Netherlands OS: Win10 AHK: Unicode x32

Re: Basic Warframe Auto Login

06 Aug 2018, 07:11

The second script.

Before the second to last line (the one with your password), add a line with the command Soundbeep. Save your script and retry launching/logging in to Warframe with it. When at the login prompt and you hit enter, listen if you hear a single beep or not.
FlaccidPotato
Posts: 5
Joined: 17 Jul 2018, 17:13

Re: Basic Warframe Auto Login

07 Aug 2018, 15:27

Nextron wrote:The second script.

Before the second to last line (the one with your password), add a line with the command Soundbeep. Save your script and retry launching/logging in to Warframe with it. When at the login prompt and you hit enter, listen if you hear a single beep or not.
Working! :D

Is there a way to just let it do the typing without having to press enter? Maybe by adding a delay or something?
User avatar
Nextron
Posts: 1391
Joined: 01 Oct 2013, 08:23
Location: Netherlands OS: Win10 AHK: Unicode x32

Re: Basic Warframe Auto Login

07 Aug 2018, 15:56

Sure: Replace the line KeyWait,Enter,DT90 with Sleep,40000.
Here 40000 is the amount of millisecond to wait after the play button is automatically pressed, before typing the password. In this case 40 seconds. You can time how long the loading takes for you and add a couple of seconds to account for some variation and replace that number.
FlaccidPotato
Posts: 5
Joined: 17 Jul 2018, 17:13

Re: Basic Warframe Auto Login

08 Aug 2018, 10:34

Nextron wrote:Sure: Replace the line KeyWait,Enter,DT90 with Sleep,40000.
Here 40000 is the amount of millisecond to wait after the play button is automatically pressed, before typing the password. In this case 40 seconds. You can time how long the loading takes for you and add a couple of seconds to account for some variation and replace that number.
Thank you so much! Really appreciate all the help
HCR Mad Bull

Re: Basic Warframe Auto Login

15 Aug 2018, 06:00

Hello, Im also very interested in this as well but it isn't working for me unfortunately and help would be greatly appreciated.

It runs the program but doesn't type it in like the other guy. When I press enter nothing happens not even a beep from the game so I'm unsure how to move forwards.

Thanks Ben
User avatar
Nextron
Posts: 1391
Joined: 01 Oct 2013, 08:23
Location: Netherlands OS: Win10 AHK: Unicode x32

Re: Basic Warframe Auto Login

16 Aug 2018, 03:47

Does it take more than 90 seconds to load your game? Did you add the SoundBeep line (just to check) before the last line?
Otto_Damus
Posts: 1
Joined: 11 Dec 2018, 07:05

Re: Basic Warframe Auto Login

11 Dec 2018, 07:27

Hi All,

I'm just wondering if anyone has had problems with DE over a script like this? I would love to be able to script this annoying process. However, I don't think it is worth losing an account to a lengthy ban on my account.

Return to “Gaming Scripts (v1)”

Who is online

Users browsing this forum: No registered users and 43 guests