waterctrl.dll

[tmplinshi]

Class_WaterCtrl.ahk

Code: Select all

; ===============================================================
; Functions:
; 	EnableWater(ParentHwnd, BMP, x = 0, y = 0, WaterRadius = 3, WaterHeight = 20)
; 	WaterBlob(x = 0, y = 0, WaterRadius = 30, WaterHeight = 30)
; 	SetWaterParent(ParentHwnd)
; 	FlattenWater()
; 	DisableWater()
; 	Free()
; ===============================================================
Class WaterCtrl
{
	static hModule := DllCall("LoadLibrary", "Str", "waterctrl.dll")

	EnableWater(ParentHwnd, BMP, x = 0, y = 0, WaterRadius = 3, WaterHeight = 20) {
		hBITMAP := FileExist(BMP) ? This.Image2hBITMAP(BMP) : BMP
		Return, DllCall("waterctrl\enablewater"
		                , "Int", ParentHwnd
		                , "Int", x
		                , "Int", y
		                , "Int", hBITMAP
		                , "Int", WaterRadius
		                , "Int", WaterHeight)
	}

	WaterBlob(x = 0, y = 0, WaterRadius = 30, WaterHeight = 30) {
		Return, DllCall("waterctrl\waterblob"
		                , "Int", x
		                , "Int", y
		                , "Int", WaterRadius
		                , "Int", WaterHeight)
	}

	SetWaterParent(ParentHwnd) {
		Return, DllCall("waterctrl\setwaterparent", "Int", ParentHwnd)
	}

	FlattenWater() {
		Return, DllCall("waterctrl\flattenwater")
	}

	DisableWater() {
		Return, DllCall("waterctrl\disablewater")
	}

	Free() {
		This.DisableWater()
		DllCall("FreeLibrary", "Ptr", This.hModule)
	}

	Image2hBITMAP(ImageFile) {
		Return, DllCall("LoadImage", "Int", 0, "Str", ImageFile, "UInt", 0, "Int", 0, "Int", 0, "UInt", 0x2010)
	}
}

Demo:

Code: Select all

#NoEnv
#SingleInstance Force
SetWorkingDir %A_ScriptDir%
SetBatchLines -1

#Include Class_WaterCtrl.ahk

Gui, Color, FAFAFA
Gui, Margin, 0, 10
Gui, +hwndhGui
	WaterCtrl.EnableWater(hGui, "ahk_logo.bmp")

Gui, Add, Text, x0 y111 w542 h111 hwndhText

Gui, Add, Button, x50 gSetWaterParent, SetWaterParent
Gui, Add, Button, x+50 gWaterBlob, WaterBlob
Gui, Add, Button, x+50 gFlattenWater, FlattenWater

Gui, Show,, WaterCtrl Demo
Return

SetWaterParent:
	WaterCtrl.SetWaterParent(hText)
Return

WaterBlob:
	WaterCtrl.WaterBlob(50, 50)
Return

FlattenWater:
	WaterCtrl.FlattenWater()
Return

GuiClose:
	WaterCtrl.Free()
ExitApp

Download (Containing waterctrl.dll and demo files)

[Guest10]

good stuff! any demos?

[tmplinshi]

Added.

[joedf]

DLL Sourcecode?

[tmplinshi]

@joedf
The author didn't provide the source code.

Author's homepage

[joedf]

Oh well thanks for the homepage