ayuda Win7 y UAC Topic is solved

[silvana]

Hola
Por favor, alguien me podria ayudar a poder presionar "yes" en UAC (user account control) de win7 mediante hotkey
parece ser, que en esta ventana autohotkey no es operativo.

no tengo mucho conociento sobre el programa, de hecho solo lo uso para logarme en algun programa mediante macros, pero ahora uno de ellos me la sale la dichosa ventana.

es decir simplemente poder hacer un run de un programa y cuando salga la ventana poder darle a yes

https://upload.wikimedia.org/wikipedia/ ... edcode.png

Muchas gracias

[Flipeador]

Hola,

parece ser, que en esta ventana autohotkey no es operativo.

Justamente esa ventana de seguridad es para impedir que las aplicaciones maliciosas hagan cambios no autorizados en el ordenador. ¿Que sentido tendría si el mismo programa podría "Confirmar" el diálogo?.
Para evitar esa ventana, puedes intentar ejecutar el script como Administrador o buscar el archivo "AutoHotkey.exe", ve a propiedades y en compatibilidad marcas la opción para que se ejecute siempre como administrador. Otra forma sería desactivando UAC por completo.

[silvana]

Hola

puede que no me haya explicado bien , lo que quiero es poder pulsar yes en el UAC con una macro, para así poder abrir el programa en cuestion ( que en la ultima version tiene un alert UAC)

buscando por los foros , he visto un script ya generado, para poder tratar la pantalla del UAC con autohotkey . Intentaré usarlo

en todo caso, gracias por la ayuda.

Code: Select all

; ===============================================================================================================================
; Title .........: NoUAC
; AHK Version ...: 1.1.25.01 x64 Unicode
; Win Version ...: Windows 10 Professional x64 / 1607 Build 14393.693
; Description ...: erstellt eine Verknüpfung auf dem Desktop ohne lästige Abfrage der Benutzerkontensteuerung beim Ausführen
; Version .......: v1.10
; Modified ......: 2017-03-13 16:33
; Author(s) .....: moefr01
; ===============================================================================================================================
#NoTrayIcon
#SingleInstance force
if not A_IsAdmin
{
   Run *RunAs "%A_ScriptFullPath%"
   ExitApp
}

Gui, Add, Text, x10 y10 w320 h40 vText, NoUAC - Erstellen Sie im Handumdrehen eine Verknüpfung zu Anwendungen ohne lästige Abfrage der Benutzerkontensteuerung beim Ausführen.
Gui, Add, Text, x10 y80, Bei Nutzung mit Akkustrom (Notebook):
Gui, Add, Radio, x210 y80 vRadio0 gRadio Checked, aktiv
Gui, Add, Radio, x258 y80 vRadio1 gRadio, inaktiv
Gui, Add, Text, x100 y116 vText0, Aufgabenordner:
Gui, Add, Edit, x190 y112 w150 h20 vEingOrdner
Gui, Add, Text, x10 y144 vText1, Aufgabenname:
Gui, Add, Edit, x90 y140 w250 h20 vEingTaskname
Gui, Add, Text, x10 y172 vText2, Anwendung:
Gui, Add, Edit, x90 y168 w220 h20 vEingProgrammpfad
Gui, Add, GroupBox, x10 y200 w330 h160 vGroup1 BackgroundTrans,
Gui, Add, Picture, x20 y220 w48 h48 vIcon,
Gui, Add, Text, x20 y270 w310 h80 vAusgabe,
Gui, Add, Button, x310 y167 h22 w30 vfsButton gfsButton, ...
Gui, Add, Button, x200 y368 w140 vErstellenButton gErstellenButton, Verknüpfung erstellen...
Gui, Show, w350 h200, NoUAC
batterystop:="false"
Return

Radio:
GuiControlGet, aktiv, , Radio0
If (aktiv)
  batterystop:="false"
Else
  batterystop:="true"
Return

; Dateiauswahldialog starten
fsButton:
FileSelectFile, programmpfad, 1, , Bitte ausführbare Datei auswählen:, Ausführbare Datei (*.exe)
GuiControl, , EingProgrammpfad, %programmpfad%
GuiControl, , Icon, %programmpfad%
GuiControlGet, taskname, , EingTaskname
GuiControlGet, ordnername, , EingOrdner
taskname0 = %taskname%
taskname = "%ordnername%\%taskname%"
GuiControlGet, programmpfad, , EingProgrammpfad
programmpfad0 = %programmpfad%
programmpfad = "%programmpfad%"

; Formatierungen
Ausgabetext = Verknüpfung:`n%A_Desktop%\%taskname0%`n`nPfad:`n%Windir%\System32\schtasks.exe /RUN /TN %taskname%
GuiControl, , Ausgabe, %Ausgabetext%
Gui, Show, w350 h400, NoUAC
Return

ErstellenButton:
If (taskname0 = "") or (programmpfad0 = "") {
  MsgBox, , ACHTUNG!, Es wurden keine Eingaben gemacht oder eine Verknüpfung bereits erstellt.
  Return
  }
; erstellt Verknüpfung auf dem Desktop: minimiert, erstes Icon von exe, mit Tasknamen
FileCreateShortcut, "%Windir%\System32\schtasks.exe", %A_Desktop%\%taskname0%.lnk, , /RUN /TN %taskname%, ...erstellt am %A_DD%.%A_MM%.%A_YYYY%, %programmpfad0%, , , 7
; erstellt Aufgabe in der Aufgabenplanung
Run, %Windir%\system32\schtasks.exe /create /sc beimstart /tn %taskname% /tr %programmpfad% /rl höchste, , hide

Sleep, 500
userid:=A_ComputerName "\" A_UserName
FileDelete, %taskname0%.xml
FileAppend,
(
<?xml version="1.0" encoding="UTF-16"?>
<Task version="1.2" xmlns="http://schemas.microsoft.com/windows/2004/02/mit/task">
  <RegistrationInfo>
    <URI>\fmwSystemImager</URI>
  </RegistrationInfo>
  <Principals>
    <Principal id="Author">
      <UserId>%userid%</UserId>
      <LogonType>InteractiveToken</LogonType>
      <RunLevel>HighestAvailable</RunLevel>
    </Principal>
  </Principals>
  <Settings>
    <MultipleInstancesPolicy>IgnoreNew</MultipleInstancesPolicy>
    <DisallowStartIfOnBatteries>%batterystop%</DisallowStartIfOnBatteries>
    <StopIfGoingOnBatteries>%batterystop%</StopIfGoingOnBatteries>
  </Settings>
  <Actions Context="Author">
    <Exec>
      <Command>%programmpfad%</Command>
    </Exec>
  </Actions>
</Task>
), %taskname0%.xml

RunWait, %Windir%\system32\schtasks.exe /create /xml %taskname0%.xml /tn %taskname% /f, , hide
MsgBox, 0x40, , Die %taskname0%-Verknüpfung zu %programmpfad% wurde erfolgreich auf dem Desktop angelegt.
GuiControl, , EingOrdner
GuiControl, , EingTaskname
GuiControl, , EingProgrammpfad
FileDelete, %taskname0%.xml
taskname0 =
programmpfad0 =
Return

GuiClose:
ExitApp

[Guest]

este codigo tambien parece interesente .. el otro veo que es solo para win10 y yo estoy con el 7

https://autohotkey.com/boards/viewtopic.php?t=4334

[Silvana]

Ya lo he podido solucionar. Gracias por a ayuda!

Un saludo