Problema con script de login
Moderator: Flipeador
Problema con script de login
Hola tengo un script con un apartado de login y tiene un error que no se solucionar (Pass1 es el ejemplo de la contraseña), al poner la contraseña Pass1 me gustaria que no se vea la palabra Pass1 y que se vea ***** pero no se como, referencias porfavor.
Last edited by nipton on 02 Aug 2017, 05:05, edited 1 time in total.
Re: Problema con script
Cuando creas el control Edit debes especificar la opción 'Password'. Mira aquí.
Code: Select all
Gui, Add, Edit, Password w500
Gui, Show
Re: Problema con script
En mi caso el script de login que uso es este, y no soy capaz de lograrlo con la informacion que usted me paso, gracias por la ayuda .
Code: Select all
Usuario := "test"
Contraseña := "test"
InputBox U, Usuario
InputBox C, Contraseña
If (U != Usuario || C != Contraseña )
Re: Problema con script
Prueba este código, y si puedes cambia el título del tema y pon algo más descriptivo:
Code: Select all
Usuario := "Admin"
Contraseña := "123"
; ################################################################################################################
; Pedir al usuario que ingrese usuario y contraseña.
; ################################################################################################################
Gui Font, q5 s9, Segoe UI
Gui Add, GroupBox, x5 y5 w305 h130, Ingresar
Gui Add, Text, x17 y25 w280 h21, Ingrese el nombre de usuario:
Gui Add, Edit, x17 y48 w280 h21 HWNDhUser gUser
DllCall("User32.dll\SendMessageW", "Ptr", hUser, "UInt", 0x1501, "Int", TRUE, "Str", "Nombre de usuario")
Gui Add, Text, x17 y80 w280 h21 +0x200, Ingrese la contraseña:
Gui Add, Edit, x17 y103 w280 h21 HWNDhPassword gPassword Password
DllCall("User32.dll\SendMessageW", "Ptr", hPassword, "UInt", 0x1501, "Int", TRUE, "Str", "Contraseña")
Gui Add, Button, x105 y144 w120 h23 gAceptar Disabled HWNDhAceptar Default, Aceptar
Gui Add, Button, x231 y144 w80 h23 gCancelar, Cancelar
Gui Show, w315 h175, Ingresar || %A_UserName%
Return
Aceptar:
If (!(UserName == Usuario))
BalloonTip(hUser, "Usuario", "El nombre de usuario es incorrecto!", 3)
Else If (!(Password == Contraseña))
BalloonTip(hPassword, "Contraseña", "La contraseña es incorrecta!", 3)
Else
Main()
Return
GuiClose:
GuiEscape:
Cancelar:
ExitApp
Return
User:
ControlGetText, UserName,, ahk_id %hUser%
DllCall("User32.dll\EnableWindow", "Ptr", hAceptar, "Int", UserName != "" && Password != "")
Return
Password:
ControlGetText, Password,, ahk_id %hPassword%
DllCall("User32.dll\EnableWindow", "Ptr", hAceptar, "Int", Password != "" && UserName != "")
Return
; ################################################################################################################
; Dentro de la función 'Main' pon tu código. Esta función solo será llamada si el usuario ingreso nombre de usuario y contraseña correctos.
; ################################################################################################################
Main()
{
MsgBox El usuario o contraseña ingresados son correctos.
ExitApp
}
; ################################################################################################################
; Funciones necesarias
; ################################################################################################################
BalloonTip(hEdit, Title := "", Text := "", Icon := 4)
{
If (Title == "" && Text == "")
Return (DllCall("User32.dll\SendMessageW", "Ptr", hEdit, "UInt", 0x1504, "Ptr", 0, "Ptr", 0))
NumPut(VarSetCapacity(EDITBALLOONTIP, 4* A_PtrSize, 0), EDITBALLOONTIP, 0, "UInt")
NumPut(&Title, EDITBALLOONTIP, A_PtrSize, "Ptr")
NumPut(&Text, EDITBALLOONTIP, 2 * A_PtrSize, "Ptr")
NumPut(Icon, EDITBALLOONTIP, 3 * A_PtrSize, "Int")
DllCall("User32.dll\SendMessageW", "Ptr", hEdit, "UInt", 0x1503, "Ptr", 0, "Ptr", &EDITBALLOONTIP)
}
Re: Problema con script de login
Gracias por tu ayuda me funciono
Re: Problema con script de login
Revivo el tema ya que me surgio un error, pongo mi script en main pero no se puede abrir ya que supuestamente hay un error en mi script pero cuando abro el script sin el sistema de logeo funciona correctamente, ¿Porque podria ser eso?
Re: Problema con script de login
Probablemente estes intentando definir una etiqueta que ya está siendo usada en el sistema de ingreso (por ej. User:).
Si no es por eso, es dificil decirte si no pones por lo menos el error que te muestra.
Pon el mensaje de error o tu Script.
Si no es por eso, es dificil decirte si no pones por lo menos el error que te muestra.
Pon el mensaje de error o tu Script.
Who is online
Users browsing this forum: No registered users and 29 guests