Mayusculas, Minusculas y Titulos Topic is solved

[Wazowski]

Hola a toda la comunidad de habla hispana

Voy al grano mi gente, basado en el siguiente código quisiera agregar 3 funciones mas

Code: Select all

^+i::
  OldClipboard := ClipboardAll
  Clipboard = ;clears the Clipboard
  SendInput, ^c
  ClipWait 0 ;pause for Clipboard data
  If ErrorLevel
   {
    MsgBox, No text selected!
   }
  Clipboard := "_" . Clipboard . "_"
  SendInput, ^v
Return

Quisiera que cuando seleccione el texto se convierta en mayúsculas con la siguiente combinación de teclas

Code: Select all

^+u

En el caso de minúsculas

Code: Select all

^+l

Y en Titulo

Code: Select all

^+t

Desde ya muy agradecido

Un Saludo desde Venezuela.

[Flipeador]

Hola,

Code: Select all

^+i::
^+u::
^+l::
^+t::
gosub rutina
if (!ErrorLevel)
{
    Clipboard := A_ThisHotkey == "^+i" ? "_" . Clipboard . "_"
               : A_ThisHotkey == "^+u" ? "_" . Format("{:U}", Clipboard) . "_"
               : A_ThisHotkey == "^+l" ? "_" . Format("{:L}", Clipboard) . "_"
               : A_ThisHotkey == "^+t" ? "_" . Format("{:T}", Clipboard) . "_" : ""
    SendInput ^v
}
return

rutina:
ClipSaved := ClipboardAll
Clipboard := ""
SendInput ^c
ClipWait 2
if (ErrorLevel)
    Clipboard := ClipSaved
return

[Wazowski]

@Flipeador Gracias bro funciono a la perfección, se me hace a veces muy jodido hacer cosas tan sencillas con este lenguaje de programación, tendrás algún tutorial en español para poder ir aprendiendo que me recomiendas.

Saludos.

[Flipeador]

En español no: https://autohotkey.com/boards/viewtopic ... 06#p229306.
Busca ejemplos en el foro, traduce de a pequeñas partes de texto la documentación oficial, esa es la mejor manera de aprender.

[Wazowski]

Hola @Flipeador

He estado pensando en perfeccionar un poco este código que me facilitaste y digamos simplificarlo un poco más de la siguiente manera.

Code: Select all

^+i::
^+n::
^+u::
^+l::
^+t::
gosub rutina
if (!ErrorLevel)
{
    Clipboard := A_ThisHotkey == "^+i" ? "_" . Clipboard . "_"
               : A_ThisHotkey == "^+n" ? "*" . Clipboard . "*"
               : A_ThisHotkey == "^+u" ? "" . Format("{:U}", Clipboard) . ""
               : A_ThisHotkey == "^+l" ? "" . Format("{:L}", Clipboard) . ""
               : A_ThisHotkey == "^+t" ? "" . Format("{:T}", Clipboard) . "" : ""
    SendInput ^v
}
return

rutina:
ClipSaved := ClipboardAll
Clipboard := ""
SendInput ^c
ClipWait 2
if (ErrorLevel)
    Clipboard := ClipSaved
return

Quisiera que al seleccionar el texto y al combinar ^+i:: intentara las primeras 3 formas explico

El * debe de quedar siempre por fuera, entonces cada vez que yo accione ^+i:: me intente de esa 3 maneras y cuando llegue la opción que más me guste dejo de accionar la combinación de teclas, otra cosa quisiera que cuando seleccionara un texto no me tomara el espacio al final de la palabra que siempre se cuela

Basado en lo que me puedas ayudar lo intentare hacer con la mayúsculas y minúsculas y títulos.

Desde ya muy agradecido.

Un saludo Maquina

[Flipeador]

Esta es una forma:

Code: Select all

n := -1

^+i::
SetTimer event, 100
n := n > 1 ? 0 : n + 1
ToolTip % {0: "_", 1: "*", 2: "*_"}[n]
return

^+u::
^+l::
^+t::
gosub rutina
if (!ErrorLevel)
{
    Clipboard := A_ThisHotkey == "^+u" ? Format("{:U}", Text)
               : A_ThisHotkey == "^+l" ? Format("{:L}", Text)
               :                         Format("{:T}", Text)
    SendInput ^v
}
return

rutina:
ClipSaved := ClipboardAll
Clipboard := ""
SendInput ^c
ClipWait 2
if (ErrorLevel)
    Clipboard := ClipSaved
Text := Trim(Clipboard)
return

event:
if (GetKeyState("CTRL"))
    return
SetTimer event, Off
gosub rutina
if (!ErrorLevel)
{
    Clipboard := n == 0 ?  "_" . Text . "_"
               : n == 1 ? "*" . Text . "*"
               :          "*_" . Text . "_*"
    SendInput ^v
}
ToolTip
n := -1
return

[Wazowski]

@Flipeador WoooW me he quedado funciona realmente súper bien

Excelente hno muchas gracias.