MS Outlook by COM

[scriptors]

This are how to utilize Outlook by COM, but I need to kow how to "complete" sometinghs

Code: Select all

String_To := ""
String_CC := ""
String_Subject = ""
String_HTMLBody := 
	(
	"Hello,<br>
	in <b>this</b> mail.<br><br>
	<i>bye bye<br>Luigi</i>"
	)
Attachment_1 := "C:\...\...\...\....ahk"

IfWinNotExist, ahk_class rctrl_renwnd32
{
MsgBox ,4 , ATTENTION, OUTLOOK must to be open.`nYou want to open Outlook now? 
IfMsgBox Yes
	Run C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Microsoft Office\Microsoft Outlook 2010 ;your Outlook program

else
	return
Return
}
IfWinExist, ahk_class rctrl_renwnd32
{
olMailItem := 0
MailItem := ComObjActive("Outlook.Application").CreateItem(olMailItem)
MailItem.SendUsingAccount := ;must investigate
MailItem.TO := String_To
MailItem.CC := String_CC
MailItem.Subject := String_Subject
MailItem.htmlbody := String_HTMLBody ; &.htmlbody

MailItem.Attachments.Add(Attachment_1) ; Attachment_1 must be set
MailItem.Display
Sleep 200
olMailItem :=
Return

I need to understand how to select different Send Accounts (I have 3 sender account at work) and if its possible to add personal signature, normally visible in any new mail but discard after set MailItem.htmlbody :=

[scriptors]

Signature are solved

insert this and delete MailItem.htmlbody := String_HTMLBody
(from: https://autohotkey.com/board/topic/7133 ... for-ahk-l/)

Code: Select all

myInspector :=	MailItem.GetInspector, myInspector.Activate
wdDoc :=	myInspector.WordEditor
wdRange :=	wdDoc.Range(0, wdDoc.Characters.Count)
wdRange.InsertBefore(String_HTMLBody)

ps. you NOT use HTML tag for the BODY string

[scriptors]

MailItem.SentOnBehalfOfName := "Insert from: other name"

But if you have more Account ...

[scriptors]

Found:

Code: Select all

MailItem.SendUsingAccount := MailItem.Application.Session.Accounts.Item(3) ; (1) or (2) or (3) ... depend by number of Account

[scriptors]

Finish work :

Code: Select all

mbutton::
String_From := ""
String_To := "Test_TO"
String_CC := "Text_CC"
String_Subject = "Test_Subject"
String_HTMLBody := ("Test_body")
Attachment_1 := 0

IfWinNotExist, ahk_class rctrl_renwnd32
{
MsgBox ,4 , ATTENTION, OUTLOOK must to be open.`nYou want to open Outlook now? 
IfMsgBox Yes
	Run C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Microsoft Office\Microsoft Outlook 2010 ;your Outlook program

else
	return
Return
}
IfWinExist, ahk_class rctrl_renwnd32
{
olMailItem := 0
MailItem := ComObjActive("Outlook.Application").CreateItem(olMailItem) ;create outlook mail
MailItem.SendUsingAccount := MailItem.Application.Session.Accounts.Item(2) ;(1) are the standard account
MailItem.SentOnBehalfOfName := String_From ; if you have also more sender to chose
MailItem.TO := String_To
MailItem.CC := String_CC
MailItem.Subject := String_Subject
if Attachment_1 is alpha
{
	MailItem.Attachments.Add(Attachment_1) ; Attachment_1 must be set
}	
MailItem.Display
Sleep 200
myInspector :=	MailItem.GetInspector, myInspector.Activate
wdDoc :=	myInspector.WordEditor
wdRange :=	wdDoc.Range(0, wdDoc.Characters.Count)
wdRange.InsertBefore(String_HTMLBody)
olMailItem :=
Return
}
; remember to set SHOW Signature, for New message, also for other Account (if you have) 

[Joe Glines]

BTW instead of using the Item number you can put in the email address. For instance

Code: Select all

MailItem.SendUsingAccount := MailItem.Application.Session.Accounts.Item["[email protected]"] ;specifies which account

[scriptors]

Thank you, now I not remember if try this solution (and have some problem) or not.

I'm searching how to forward message (comprehensive of attachment if present)

[RonJeanJr]

While trying to create a script that uses a variable instead of a specific email send-from address via Outlook, I was able to discover that this line does NOT actually work:
MailItem.SendUsingAccount := MailItem.Application.Session.Accounts.Item["[email protected]"]
I discovered this during error testing when manually setting the send-from address, in quotes, just as listed, and it completely failed to use anything other than Outlook's default sender.
This line DOES however work perfectly:
MailItem.SendUsingAccount := MailItem.Application.Session.Accounts.Item(3)
Whereas (3) = the 3rd Outlook sender account

( This is the case, at least, with Outlook 2007 & AHK 1.1.28.00 )

[FanaticGuru]

if its possible to add personal signature, normally visible in any new mail but discard after set MailItem.htmlbody :=

Simple string logic will allow you to keep the current body of an email and add to it. This is very important when creating a reply and have the whole chain of emails already in the body.

Code: Select all

NewHTML:= "<p> blal blal blal </p>"
olEmail.HTMLBody := NewHTML olEmail.HTMLBody

This will make the email body equal to the NewHTML string followed by the olEmail.HTMLBody string. Effectively adding your new stuff to the top of the email.

Hooking into the wdDoc is still cool and useful but maybe simpler to just manipulate the string in most cases.

Here is an example combining both to put a table into an email:

Code: Select all

^F12::
	olApp := ComObjActive("Outlook.Application")
	olMailItem := olApp.CreateItem(0) ;  olMailItem := 0
	olMailItem.display

	olMailItem.HTMLBody := "<b>Stuff Before</b>"

	olInspector := olApp.ActiveInspector.WordEditor.Application.ActiveDocument
	olTable := olInspector.Tables.Add(olInspector.Range(olInspector.Range.End - 1), 6, 7, 1, 0) ; Range, NumRows, NumColumns, DefaultTableBehavior, AutoFitBehavior
	olTable.Cell(1,1).Range.Text := "First Cell"
	olTable.Cell(3,2).Range.Text := "Three Down, Two Over"

	olMailItem.HTMLBody := olMailItem.HTMLBody "<i>More Stuff</i>"
return

FG

[Joe Glines]

While trying to create a script that uses a variable instead of a specific email send-from address via Outlook, I was able to discover that this line does NOT actually work:
MailItem.SendUsingAccount := MailItem.Application.Session.Accounts.Item["[email protected]"]

It works fine for me. I switch between multiple accounts all the time. You do need to be sure the case of your text matches exactly to your account as it is case sensitive.

[RonJeanJr]

Excellent and thank you very much - working perfectly now.

[FanaticGuru]

OP already has a solution but just for generally knowledge, code like this seems strange to me:

Code: Select all

MailItem.SendUsingAccount := MailItem.Application.Session.Accounts.Item["[email protected]"]

This is taking the MailItem and working backwards to get the application object which generally the code would already have.

So you could do this:

Code: Select all

	olApp := ComObjActive("Outlook.Application")
	olEmail := olApp.ActiveWindow.CurrentItem
	olEmail.SendUsingAccount := olApp.Session.Accounts.Item("[email protected]")

Also olApp.Session is a way of getting a Namespace so I prefer using GetNamespace for that:

Code: Select all

	olApp := ComObjActive("Outlook.Application")
	olNameSpace := olApp.GetNamespace("MAPI")
	olEmail := olApp.ActiveWindow.CurrentItem
	olEmail.SendUsingAccount := olNameSpace.Accounts.Item("[email protected]")

The Namespace object is the term that Outlook uses and this is an object that can be used for accessing other things, like folders.

Most of this is just a combination of personal preference and common conventions but these type common conventions do make using the MSDN database somewhat easier.

FG