Trigger a script when the mouse stops moving

[WeThotUWasAToad]

Hello,

Rather than using a hotkey, is it possible to launch a script by moving then stopping the mouse?

Thanks

[Garbidge_1]

Code: Select all

#NoEnv
Do_ToolTip:=1
mWait:=200
gosub Mouse_Check
return  ; end auto execute

MOUSE_STOPPED:
	;
	; put your code here
	;
	return

!Esc::       ; Alt + Esc to quit
	ExitApp

Mouse_Check:
	mStill:=0
	MouseGetPos, Ox, Oy
	Sleep %mWait%
	loop {
		MouseGetPos, Mx, My
		if( Mx = Ox && My = Oy ) {
			mStill++
			if( mStill >= 5 ) {   ; 5 = 1000/mWait 
				mStill:=0
				if( !IS_MSTOPPED && Do_ToolTip )
					ToolTip, Mouse has stopped moving.
				IS_MSTOPPED:=1
				SetTimer, MOUSE_STOPPED, -1
			}
		} else  {
			IS_MSTOPPED:=0
			ToolTip
		}
		Ox:=Mx, Oy:=My
		Sleep %mWait%
	}
	return

[Shadowpheonix]

You may also like Mouse Gestures.

[evilC]

The technique posted by Garbidge_1 will not detect when the mouse stops moving, it will detect when the mouse cursor stops moving. You could be moving the mouse against the edge of the monitor, and the cursor would not move, but the mouse would still be moving.
Also, in many games, the windows cursor will not move when you move the mouse, so this code will not do anything.

Detecting when the mouse itself stops moving is non-trivial, because you simply stop getting mouse move messages when it stops moving, so you need to set a timer running after every move, and when the timer fires, you consider the mouse stopped.

If you want to detect the mouse stopping moving, see the sample script in my MouseDelta library - it shows how to do this with the RAWINPUT API. All the code you need is there.