GUI Control inside function Topic is solved

[L40P]

Hi Community,
I once again have a problem. I have a function in which I create a GUI with a text to display a 5sec timer. But it says "A control's variable must be global or static".

Code: Select all

GuiShow() 
{
	Gui, SleepWarning:Add, Text, vCountdown, 5
	Gui, SleepWarning:Show, Center, SleepWarning
	Sleep, 1000
	GuiControl, , Countdown, 4
	Sleep, 1000
	GuiControl, , Countdown, 3
	Sleep, 1000
	GuiControl, , Countdown, 2
	Sleep, 1000
	GuiControl, , Countdown, 1
	Sleep, 1000
	GuiControl, , Countdown, 0
	Sleep, 250
	...
}

How can I edit the control without that error or how can I declare that control's variable as global?

[divanebaba]

Hi.
You can create your GUI outside the function and can use only Gui, SleepWarning: show ... inside your function to display your sleep warning.
I think this will prevent your error message and the need of using definitions for the variables.

[kon]

Code: Select all

GuiShow()
ExitApp

GuiShow() 
{
    static Countdown
    
	Gui, SleepWarning:Add, Text, vCountdown, 5
	Gui, SleepWarning:Show, Center, SleepWarning
	Sleep, 1000
	GuiControl, SleepWarning:, Countdown, 4
	Sleep, 1000
	GuiControl, SleepWarning:, Countdown, 3
	Sleep, 1000
	GuiControl, SleepWarning:, Countdown, 2
	Sleep, 1000
	GuiControl, SleepWarning:, Countdown, 1
	Sleep, 1000
	GuiControl, SleepWarning:, Countdown, 0
	Sleep, 250
}

[L40P]

Code: Select all

Gui, SleepWarning:Add, Text, vCountdown, 5

GuiShow() 
{
	Gui, SleepWarning:Show, Center, SleepWarning
	Sleep, 1000
	GuiControl, , Countdown, 4
	Sleep, 1000
	GuiControl, , Countdown, 3
	Sleep, 1000
	GuiControl, , Countdown, 2
	Sleep, 1000
	GuiControl, , Countdown, 1
	Sleep, 1000
	GuiControl, , Countdown, 0
	Sleep, 250
	...
}

I think you mean like this? The error message doesn't show up anymore that's right, but now the text won't update. The timer and script afterwards runs but the text doesn't change.

[L40P]

Thanks kon. Your code works great

[kon]

There is a problem. The Gui is not destroyed, so when you call the function a second time it will give you a warning about not being able to use the same variable for more than 1 control.
You can try this. Then try it without the line that destroys the Gui.

Code: Select all

GuiShowSleepWarning()
GuiShowSleepWarning()
ExitApp

GuiShowSleepWarning() 
{
    static Countdown
    
    Countdown := 5
	Gui, SleepWarning:Add, Text, vCountdown, % Countdown
	Gui, SleepWarning:Show, Center, SleepWarning
    Loop {
        Sleep, 1000
        GuiControl, SleepWarning:, Countdown, % --Countdown
        if (Countdown < 1) {
            Sleep, 250
            Gui, SleepWarning:Destroy
            return
        }
    }
}