Show Icon on compiled Script as a picture in Gui

[Delta Pythagorean]

I'm assuming there's a way to do it using DllCall or maybe PostMessage.
But the point is, I want to take the compiled script's icon and use it in a gui inside of said script.
If there is a way, please to tell or point me in the right direction, thank you!

[divanebaba]

Hi.
A few years ago I used autohotkey basic and I was able to input bmp file into ahk files and even into compiled versions.

Unfortunately this method does not works now. Maybe the new autohotkey version, I'm using 1.1.26.01, does not support.
I used a tool called Get Hex of Bmp .ahk

Spoiler

Code: Select all

gui, add, edit, w400 vFile,
gui, add, button, w100 gOpen x+10,Open File
gui, add, edit, r40 w510 vOutput xm
gui, show

Open:
gui, submit, nohide
BinRead(file,data)
Bin2Hex(h,data,res)
guicontrol,,output,%h%
return

Bin2Hex(ByRef h, ByRef b, n=0)      ; n bytes binary data -> stream of 2-digit hex
{                                   ; n = 0: all (SetCapacity can be larger than used!)
   format = %A_FormatInteger%       ; save original integer format
   SetFormat Integer, Hex           ; for converting bytes to hex

   m := VarSetCapacity(b)
   If (n < 1 or n > m)
       n := m
   Address := &b
   h =
   Loop %n%
   {
      x := *Address                 ; get byte in hex
      StringTrimLeft x, x, 2        ; remove 0x
      x = 0%x%                      ; pad left
      StringRight x, x, 2           ; 2 hex digits
      h = %h%%x%
      Address++
   }
   SetFormat Integer, %format%      ; restore original format
}

BinRead(file, ByRef data, n=0, offset=0)
{
   h := DllCall("CreateFile","Str",file,"Uint",0x80000000,"Uint",3,"UInt",0,"UInt",3,"Uint",0,"UInt",0)
   IfEqual h,-1, SetEnv, ErrorLevel, -1
   IfNotEqual ErrorLevel,0,Return,0 ; couldn't open the file

   m = 0                            ; seek to offset
   IfLess offset,0, SetEnv,m,2
   r := DllCall("SetFilePointerEx","Uint",h,"Int64",offset,"UInt *",p,"Int",m)
   IfEqual r,0, SetEnv, ErrorLevel, -3
   IfNotEqual ErrorLevel,0, {
      t = %ErrorLevel%              ; save ErrorLevel to be returned
      DllCall("CloseHandle", "Uint", h)
      ErrorLevel = %t%              ; return seek error
      Return 0
   }

   m := DllCall("GetFileSize","UInt",h,"Int64 *",r)
   If (n < 1 or n > m)
       n := m
   Granted := VarSetCapacity(data, n, 0)
   IfLess Granted,%n%, {
      ErrorLevel = Mem=%Granted%
      Return 0
   }

   result := DllCall("ReadFile","UInt",h,"Str",data,"UInt",n,"UInt *",Read,"UInt",0)

   if (!result or Read < n)
       t = -3
   IfNotEqual ErrorLevel,0, SetEnv,t,%ErrorLevel%

   h := DllCall("CloseHandle", "Uint", h)
   IfEqual h,-1, SetEnv, ErrorLevel, -2
   IfNotEqual t,,SetEnv, ErrorLevel, %t%-%ErrorLevel%

   Return Read
}

and after conversion I put this hex chars into my script like below

Code: Select all

...
GoSub, LoadBitmap1
hBMP := DllCall( "CreateDIBitmap", UInt,hDC, UInt,(bmiHAddr:=&BMP+14)
       ,UInt,(CBM_INIT:=4), UInt,&BMP+NumGet(BMP,10), UInt,&BMP+14, UInt,(DIB_PAL_COLORS:=1) )       
SendMessage, (STM_SETIMAGE:=0x172), (IMAGE_BITMAP:=0x0), hBMP,, ahk_id %hPic%
...
Gui, Show, ,%MainWnd%
return

LoadBitmap1:
BMPH = 
(	Join
... (the hex chars)
)
nSize := StrLen(BMPH)//2
VarSetCapacity( BMP,nSize )
Loop % nSize
NumPut( "0x" . SubStr(BMPH,2*A_Index-1,2), BMP, A_Index-1, "Char" )
return

The old compiled versions does show the image. The ahk versions does not.
I don't know why, maybe you know how to fix. I would be glad too, knowing a functionally method.

[Delta Pythagorean]

Hopefully I find a way, it may be something as simple as a DllCall but I'd rather just take my time with it.

[jeeswg]

Here are some ideas re. icons and Guis. Cheers.

Code: Select all

q:: ;show icons (note: have Notepad/IE icons, to see their icons)
;see also:
;Crazy Scripting : Include an Icon in your script - Scripts and Functions - AutoHotkey Community
;https://autohotkey.com/board/topic/31044-crazy-scripting-include-an-icon-in-your-script/

;method 1
Gui, Add, Picture,, % A_AhkPath

;method 2
hIcon := LoadPicture(A_AhkPath, "", vType)
Gui, Add, Picture,, % "HICON:" hIcon

;method 3
WinGet, hWnd, ID, ahk_class IEFrame
;ICON_SMALL := 0 ;ICON_BIG := 1 ;ICON_SMALL2 := 2
SendMessage, 0x7F, 1,,, % "ahk_id " hWnd ;WM_GETICON := 0x7F
hIcon := ErrorLevel
Gui, Add, Picture,, % "HICON:" hIcon

;method 4
WinGet, hWnd, ID, ahk_class Notepad
;GCL_HICON := -14 ;GCL_HICONSM := -34
vSfx := (A_PtrSize=8) ? "Ptr" : ""
if hIcon := DllCall("GetClassLong" vSfx, Ptr,hWnd, Int,-14, UInt)
Gui, Add, Picture,, % "HICON:" hIcon

;method 5
hIcon := DllCall("LoadIcon", Ptr,0, Ptr,32512, Ptr) ;IDI_APPLICATION (standard exe icon)
Gui, Add, Picture,, % "HICON:" hIcon

;method 6
vPath := A_AhkPath
hModule := DllCall("LoadLibrary", Str,vPath)
hIcon00 := DllCall("LoadIcon", Ptr,hModule, Ptr,159, Ptr) ;[green H]
hIcon01 := DllCall("LoadIcon", Ptr,hModule, Ptr,206, Ptr) ;S on [green S]
hIcon10 := DllCall("LoadIcon", Ptr,hModule, Ptr,207, Ptr) ;P on [red H]
hIcon11 := DllCall("LoadIcon", Ptr,hModule, Ptr,208, Ptr) ;PS on [red S]
vList := "00,01,10,11"
Loop, Parse, vList, % ","
	Gui, Add, Picture,, % "HICON:" hIcon%A_LoopField%

Gui, Show, w300 h400
return