How to make a 4-digit number by adding leading zeros

[helpme]

I would like to add leading zeros to a number such that it always becomes a 4-digit number. For example, if the number is 12, then the converted number is 0012. If it is 122, the the converted number is 0122. If it is 1, the the converted number is 0001.

How can this be done in Autohotkey? Thank you.

I am using Autohotkey ver1.1.15

[just me]

One option:

Code: Select all

#NoEnv
MyNumber := 1
MsgBox, 0, 4-digit Number, % SubStr("000" . MyNumber, -3)
ExitApp

[Ronins]

Another way

Code: Select all

Num := 12
Pack := "0000"
MsgBox, % (SubStr(Pack, 1, StrLen(Pack) - StrLen(Num)) . Num)

[joedf]

@just me ha ha pretty close... that's what I pretty much had
http://stackoverflow.com/a/24100686

[tank]

http://msdn.microsoft.com/en-us/library ... p/ms647550
or you can get this directly from the documentation
DllCall

DllCall

Code: Select all

; Example: Calls the API's wsprintf() to pad the number 432 with leading zeros to make it 10 characters wide (0000000432).

VarSetCapacity(ZeroPaddedNumber, 20)  ; Ensure the variable is large enough to accept the new string.
DllCall("wsprintf", "Str", ZeroPaddedNumber, "Str", "%010d", "Int", 432, "Cdecl")  ; Requires the Cdecl calling convention.
MsgBox %ZeroPaddedNumber%

[Gangula]

@just me ha ha pretty close... that's what I pretty much had
http://stackoverflow.com/a/24100686

How do i add a padding code into this? I'd like to "SetFormat, float, 03.0". But I don't know how and where to add this line of code to.

[joedf]

You want padding for a float number?
I’m not sure what you mean here.
Do you have code to share?

[Gangula]

https://autohotkey.com/board/topic/2530 ... ng-string/

` & w::
clip := Clipboard
if RegExMatch(clip, "s)(.*?)(\d+)(.*)", m)
Clipboard := m1 . m2+1 . m3
return

I found a code in one of the forums for pasting incrementing string(above code)

But if I have a string "000abc" it returns a value of "1abc". But my desired output is "001abc". How do I achieve that?

[Odlanir]

Code: Select all

Clipboard := m1 . Format("{:03}", m2+1) . m3

[jeeswg]

Here's a way:

Code: Select all

q::
vText := "1abc"
MsgBox, % Format("{:06}", vText)
return

For more Format function examples see FORMAT FUNCTION EXAMPLES here:
jeeswg's characters tutorial - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=7&t=26486

[Gangula]

Worked like a charm. Thanks a lot.

[Gangula]

Code: Select all

Clipboard := m1 . Format("{:03}", m2+1) . m3

Just one more thing. Do you know how to let the code detect the format and then apply it.

In the code you specified, it's fixed to 3 leading 0's. I'm wondering if it's possible to write a script that detects the number of leading zero's in the parent string and apply that as the format.

[Odlanir]

Sure:

Code: Select all

clip := Clipboard
if RegExMatch(clip, "s)(.*?)(\d+)(.*)", m) {
   lm2 := strlen(m2)
   Clipboard := m1 . Format("{:0" lm2 "}", m2+1) . m3
}

[Gangula]

awesome, thanks

[Gangula]

The more I use this code, the more features I find to add to this script.
Can someone help me with adding few other lines of code to this?

This code works like a charm, but I'd like to add "F2" and "CTRL+A" into this script.
So what I want is to, click on a file and enter the shortcut key, so that it'll rename it without me having to manually press "F2" and "CTRL+A".

Code: Select all

` & w::
    clip := Clipboard
if RegExMatch(clip, "s)(.*?)(\d+)(.*)", m) {
   lm2 := strlen(m2)
   Clipboard := m1 . Format("{:0" lm2 "}", m2+1) . m3
}
    sendinput ^v
return

[Odlanir]

Select a file ( only one ) in explorer window and press window-key+3

Code: Select all

#SingleInstance, force
#Persistent
#NoEnv

#3::
OldName := Explorer_GetSelection()
if (RegExMatch(OldName,"`n") > 0 ) {
   MsgBox % "You must select only one file."
   ExitApp
}
if RegExMatch(OldName, "Os)(.*?)(\d+)(.*)", m) {
   lm2 := strlen(m[2])
   NewName := m[1] . Format("{:0" lm2 "}", m[2]+1) . m[3]
   FileMove, % OldName, % NewName
} else {
   MsgBox % "The selected file does not contains any digit."
}   
return


Explorer_GetSelection(hwnd="") {
	hwnd := hwnd ? hwnd : WinExist("A")
	WinGetClass class, ahk_id %hwnd%
	if (class="CabinetWClass" or class="ExploreWClass" or class="Progman" or class="#32770")
		for window in ComObjCreate("Shell.Application").Windows
			if (window.hwnd==hwnd)
    sel := window.Document.SelectedItems
	for item in sel
	ToReturn .= item.path "`n"
	return Trim(ToReturn,"`n")
}


esc::
   ExitApp

[Gangula]

The script works perfectly. But I'd like it to work with normal string, not just on files. I've given renaming files as an example.

So, here are the steps I'd like the script to folllow:

1. I'll copy a text from anywhere
2. then I'll click somewhere else(notepad/files or any other software)
3. then I'll press the hotkey which executes F2 > CTRL+A > then pastes the incremented text

[Odlanir]

Is this what you want?

Code: Select all

#SingleInstance, force
#Persistent
#NoEnv

#3::
if RegExMatch(Clipboard, "O)(.*?)(\d+)(.*)", m) {
   lm2 := strlen(m[2])
   Clipboard := m[1] . Format("{:0" lm2 "}", m[2]+1) . m[3]
   send  {F2}
   Send ^a
   send ^v
}
return
esc::
   ExitApp

[Gangula]

Wow, yeah. I didn't realize it was this simple. Thank you

[Gangula]

Is this what you want?

Code: Select all

#SingleInstance, force
#Persistent
#NoEnv

#3::
if RegExMatch(Clipboard, "O)(.*?)(\d+)(.*)", m) {
   lm2 := strlen(m[2])
   Clipboard := m[1] . Format("{:0" lm2 "}", m[2]+1) . m[3]
   send  {F2}
   Send ^a
   send ^v
}
return
esc::
   ExitApp

Hey Odlanir, I've created a separate thread for this for another query. Can you please look into that?