Make CapsLock double click? Topic is solved

[firestar9114]

So, I constantly hit CapsLock by accident. So I thought it would be nice to make it only work on a double tap. After looking around I thought this solution would work:

Code: Select all

CapsLock:: 
If (A_TimeSincePriorHotkey<200) and (A_PriorHotkey="CapsLock")
{
	if GetKeyState("CapsLock", "T") = 1
 	{
   		SetCapsLockState, off
 	}
	else if GetKeyState("CapsLock", "F") = 0
 	{
   		SetCapsLockState, on
 	}
}
Return

Unfortunately while this mostly implements the intended behaviour I usually activate capslock when I am trying to hit Shift or Tab and I hit capslock by mistake. Fortunately this doesn't enable it, BUT if I hit Shift and mistakenly roll my finger over capslock as well before releasing shift, for some reason CapsLock toggles despite only being pressed once. Why does my code do this, and how can I fix it? (note that holding control and alt instead of shift also cause this behaviour, but not tab, if that helps)

[dmg]

I would guess it is because the script interprets most keys + capslock as an entirely different thing than just capslock, for the purpose of your hotkey. You might try adding * to your hotkey, so it will trigger even if other keys are involved.

Code: Select all

*CapsLock:: 
If (A_TimeSincePriorHotkey<200) and (A_PriorHotkey="CapsLock")
{
	if GetKeyState("CapsLock", "T") = 1
 	{
   		SetCapsLockState, off
 	}
	else if GetKeyState("CapsLock", "F") = 0
 	{
   		SetCapsLockState, on
 	}
}
Return

[GEV]

Try

Code: Select all

SetCapslockState OFF

			RETURN	 ; === end of auto-execute section ===

*CapsLock:: ; Fire the hotkey even if extra modifiers are being held down. 
If (A_ThisHotkey == A_PriorHotkey && A_TimeSincePriorHotkey < 300)
{
	KeyWait CapsLock
	If GetKeyState("CapsLock", "T") 
   		SetCapsLockState, off
	else
   		SetCapsLockState, on
}
else
   		SetCapsLockState, off
Return

[dmg]

A hotkey label is also considered the end of the auto-execute section, so the return is not necessary.

[firestar9114]

Thanks for the help, I think that wildcard was the key, after fiddling with it some this solution worked:

Code: Select all

*CapsLock:: ; Fire the hotkey even if extra modifiers are being held down. 
If (A_ThisHotkey == A_PriorHotkey && A_TimeSincePriorHotkey < 300)
{
	If GetKeyState("CapsLock", "T") 
   		SetCapsLockState, off
	else
   		SetCapsLockState, on
}
Return

I removed some extra else statements and things that were making it only require a single click to toggle off. For the sake of consistency I want to have to double click for both activating and deactivating the CapsLock. Thanks for the help.

p.s. Also, it appears as though KeyWait isn't needed. I guess that CapsLock doesn't repeat?