like Logitech spotlight

[Gurkentoepfer]

I would like to have a semi-transparent window where a hole appears at the current mouse position.
The mouse function should be still work (clickable buttons of windows which can bee seen throught the "hole").

https://www.youtube.com/watch?v=ojcoSzjiG3o

I've started with a code like that ... (but it it's not a spotlight its a dark spot).
Any idea to improve?

Code: Select all

SetTitleMatchMode, 2
#Persistent
#SingleInstance Force
if !(A_iscompiled)
	Hotkey, ESC, Beenden

Spot:=0

#o::
	if (Spot=0)
	{
		Gui, dark: Color, black, black
		Gui, dark: +ToolWindow +Lastfound -Caption
		WinSet, Region, 0-0 W%A_ScreenWidth% H%A_ScreenHeight%
		WinSet, Transparent, 150
		Gui, dark: Show, W%A_ScreenWidth% H%A_ScreenHeight%, darkwin
		WinMaximize, A
		WinGetPos, WinPosX, WinPosY, WinWidth, WinHeight		
		SetTimer, Spotlight, 10
		Spot:=1
	}
	else
	{
		SetTimer, Spotlight, off
		Gui, dark: Destroy
		Spot:=0
	}
	
return

Spotlight:
	Diameter := 200
	MouseGetPos, xPos, yPos
	xPos -= Diameter/2
	yPos -= Diameter/2	
	WinSet, Region, %xPos%-%yPos% w%Diameter% h%Diameter% E, darkwin	
return

Beenden:
	ExitApp
return

[Nightwolf85]

I found this which I think does what you want, but it isn't a good circle.

Maybe you can alter it's region to be more circular, like your dark one?
https://autohotkey.com/board/topic/3303 ... et-region/

[Gurkentoepfer]

Thank you.
Based on your hint ... a shape which looks more like a circle ...

Code: Select all

;
; AutoHotkey Version: 1.x
; Language:       English
; Platform:       WinXP
; Author:         LiquidGravity <[email protected]>
;
; Script Function:
;	Mouse Spotlight Example Using WinSet Region
;
#SingleInstance force
#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%

Hotkey, ESC, Beenden

Gui, Margin , 0, 0
Gui, -Caption +AlwaysOnTop
Gui, Color, 000000
Gui, Show, Maximize, Mouse Spotlight
WinSet, Transparent, 180, Mouse Spotlight
WinSet, Region, 0-85 0-%A_ScreenHeight% %A_ScreenWidth%-%A_ScreenHeight% %A_ScreenWidth%-0 0-0 0-85, Mouse Spotlight
SetTimer, Alert2, 50
Return


Alert2:
    Radius := 200
    CoordMode,Mouse, Screen
    MouseGetPos, X3, Y3, OutputVarWin, OutputVarControl
    region:=""
    loop, 37
    {
        x := x3 + Round(Radius*sin(ATan(1)*A_index*2/9),0)
        y := y3 + Round(Radius*cos(ATan(1)*A_index*2/9),0)
        Region .= " " . x . "-" . y
    }    
    WinSet, Region, 0-85 0-%A_ScreenHeight% %A_ScreenWidth%-%A_ScreenHeight% %A_ScreenWidth%-0 0-0 0-85 %Region%, Mouse Spotlight
Return


GuiClose:
2GuiClose:
Beenden:
ExitApp

[iPhilip]

I simplified/optimized the code a little in the version below:

Code: Select all

#NoEnv

Transparency := 150

Radius := 200
Vertices := 40
Angle := 8*ATan(1)/Vertices

Gui, -Caption +Hwndhwnd
Gui, Color, Black
Gui, Show, Maximize
WinSet, Transparent, %Transparency%, ahk_id %hwnd%
SetTimer, DrawHole, 10
Return

DrawHole:
   MouseGetPos, X, Y
   Loop, %Vertices%
      Hole .= Floor(X + Radius * Cos(A_Index * Angle)) "-" Floor(Y + Radius * Sin(A_Index * Angle)) " "
   Hole .= Floor(X + Radius * Cos(Angle)) "-" Floor(Y + Radius * Sin(Angle))
   WinSet, Region, 0-0 0-%A_ScreenHeight% %A_ScreenWidth%-%A_ScreenHeight% %A_ScreenWidth%-0 0-0 %Hole%, ahk_id %hwnd%
   Hole =
Return

^=::Radius += 10
^-::Radius -= 10
^0::Radius := 200

!=::
Transparency -= 10
WinSet, Transparent, %Transparency%, ahk_id %hwnd%
Return
!-::
Transparency += 10
WinSet, Transparent, %Transparency%, ahk_id %hwnd%
Return
!0::
Transparency := 150
WinSet, Transparent, %Transparency%, ahk_id %hwnd%
Return

Esc::ExitApp

Cheers!

[Nextron]

Really cool! If changed it to support multiple monitors and added some hotkeys (F1 in config part) to enable/disable the spotlight and using that hotkey in combination with the arrow keys to change the spotlight size and contrast.

Code: Select all

#NoEnv
#SingleInstance,Force

Hotkey=F1
Radius := 200
Vertices := 40
Angle := 8*ATan(1)/Vertices
TransparencyTarget:=150
FadeAmount:=10
SysGet, XVirtualScreen, 76
SysGet, YVirtualScreen, 77
SysGet, CXVirtualScreen, 78
SysGet, CYVirtualScreen, 79
CoordMode,Mouse, Screen
Transparency:=0


Fade:
   If (Transparency=0){
      Gui, -Caption +Hwndhwnd +AlwaysOnTop +ToolWindow
      Gui, Color, Black
      Gui, Show, x%XVirtualScreen% y%YVirtualScreen% w%CXVirtualScreen% h%CYVirtualScreen% NA,
      WinSet, Transparent, 0, ahk_id %hwnd%
      Hotkey,%Hotkey%,Hotkey
      Hotkey,%Hotkey% & Up,HotkeyUp,On
      Hotkey,%Hotkey% & Down,HotkeyDown,On
      Hotkey,%Hotkey% & Left,HotkeyLeft,On
      Hotkey,%Hotkey% & Right,HotkeyRight,On
      SetTimer, DrawHole, 10, On
      SetTimer, Fade, 10, On
   }
   
   Transparency+=FadeAmount
   
   If (Transparency<=0){
      Transparency:=0
      SetTimer,Fade,Off
      SetTimer,DrawHole,Off
      Hotkey,%Hotkey% & Up,Off
      Hotkey,%Hotkey% & Down,Off
      Hotkey,%Hotkey% & Left,Off
      Hotkey,%Hotkey% & Right,Off
      Gui,Destroy
   }Else If (Transparency>=TransparencyTarget){
      Transparency:=TransparencyTarget
      SetTimer,Fade,Off
   }
   
   WinSet, Transparent, %Transparency%, ahk_id %hwnd%
Return

DrawHole:
   MouseGetPos, X, Y
   X-=XVirtualScreen
   Y-=YVirtualScreen
   Loop, %Vertices%
      Hole .= Floor(X + Radius * Cos(A_Index * Angle)) "-" Floor(Y + Radius * Sin(A_Index * Angle)) " "
   Hole .= Floor(X + Radius * Cos(Angle)) "-" Floor(Y + Radius * Sin(Angle))
   WinSet, Region, %XVirtualScreen%-%YVirtualScreen% %XVirtualScreen%-%CXVirtualScreen% %CXVirtualScreen%-%CYVirtualScreen% %CXVirtualScreen%-%YVirtualScreen% %XVirtualScreen%-%YVirtualScreen% %Hole%, ahk_id %hwnd%
   Hole =
Return



Hotkey:
   FadeAmount*=-1
   SetTimer,Fade,10
Return

HotkeyUp:
HotkeyDown:
   Direction:=InStr(A_ThisLabel,"Up") ? 1 : -1
   TransparencyTarget+=10*Direction
   If (TransparencyTarget<20)
      TransparencyTarget:=20
   Else If (TransparencyTarget>255)
      TransparencyTarget:=255
   Transparency:=TransparencyTarget
   ;FadeAmount:=TransparencyTarget//10
   WinSet, Transparent, %Transparency%, ahk_id %hwnd%
Return
HotkeyLeft:
HotkeyRight:
   Direction:=InStr(A_ThisLabel,"Right") ? 1 : -1
   Radius+=20*Direction
   If (Radius < 20)
      Radius:=20
Return

Esc::ExitApp

[iPhilip]

Great job Nextron! I appreciate you making this even cooler.

[LAPIII]

This is a fantastic tool! I want to be able to zoom in and out with the scroll wheel in increments of 25%. I also think that a toggle for this tool would be great.

[boiler]

I also think that a toggle for this tool would be great.

There is a toggle if you use Nextron's version. Press F1 to toggle. Hold F1 and use arrow keys to resize and change contrast.

[amateur+]

Cursor Highlighter

Spoiler

focus.gif (527.28 KiB) Viewed 563 times