Switching Between Loops

[Fat]

trying to get a loop to start on one key stroke, then another key stroke stop that loop and start another loop and be able to switch between them at will.
ive gotten them to go from one to the other once and then no further. the one below allows to go from one to the other but must double tap. if tapped too quickly, it gets stuck. this leads me to believe its getting stuck in the loop/delay. i dont know. ive tried a few different menial methods.. no avail.
basically looking to switch between loops. any helps or examples welcome.
thank you all.

Code: Select all

$a::
b = 1
Loop
{
if a = 1
break
Send {1}
Sleep 1000
}
a = 0
return

$b::
a = 1
Loop
{
if b = 1
break
Send {2}
Sleep 1000
}
b = 0
return

[divanebaba]

Hi.
Solving your issue with a loop is for me, as a person cheated for his education, unknown.
But a workaround is possible. Look below for a solution with a timer:

Code: Select all

Settimer, check, 1000

$a::
a = 1 
b = 0
return

$b::
a = 0
b = 1
return

check:
if (a = 1)
send 1
if (b = 1)
send 2
return

$Esc::
settimer, check, off
return

Works it as you have desired?
BTW: You don't need to "thank you all". It is enough, when you thank to me.

[Rohwedder]

Hallo,
try:

Code: Select all

$a::
	b := 0, a := 1
	SetTimer a,-1
Return
a:
	While, a
	{
		Send 1
		Sleep 1000
	}
Return
$b::
	a := 0, b := 1
	SetTimer b,-1
Return
b:
	While, b
	{
		Send 2
		Sleep 1000
	}
Return

or:

Code: Select all

SetTimer, Loops, -1
$a::Loop = a
$b::Loop = b
$c::Loop =
Loops:
Loop
{
	While, Loop = "a"
	{
		Send 1
		Sleep 1000
	}
	While, Loop = "b"
	{
		Send 2
		Sleep 1000
	}
}
Return

[Fat]

Hi.
Solving your issue with a loop is for me, as a person cheated for his education, unknown.
But a workaround is possible. Look below for a solution with a timer:

Code: Select all

Settimer, check, 1000

$a::
a = 1 
b = 0
return

$b::
a = 0
b = 1
return

check:
if (a = 1)
send 1
if (b = 1)
send 2
return

$Esc::
settimer, check, off
return

Works it as you have desired?
BTW: You don't need to "thank you all". It is enough, when you thank to me.

your rendition of self has me more puzzled than i was with my little loop task now that you seem to have shown a much better angle on it. ill try this and it looks promising. we'll see once i get all the sub functions involved.
i havent taken a computer class since the 80s.. my programming logic is very rusty to say the least.
thank YOU.

[Fat]

Hallo,
try:

Code: Select all

$a::
	b := 0, a := 1
	SetTimer a,-1
Return
a:
	While, a
	{
		Send 1
		Sleep 1000
	}
Return
$b::
	a := 0, b := 1
	SetTimer b,-1
Return
b:
	While, b
	{
		Send 2
		Sleep 1000
	}
Return

or:

Code: Select all

SetTimer, Loops, -1
$a::Loop = a
$b::Loop = b
$c::Loop =
Loops:
Loop
{
	While, Loop = "a"
	{
		Send 1
		Sleep 1000
	}
	While, Loop = "b"
	{
		Send 2
		Sleep 1000
	}
}
Return

i will try both. if not used in task at hand, im sure they will be very useful in the future. i save all info and ideas i get here. problem being.... data retrieval
thank YOU too
xo

edit 1:
one question now is what is timer "-1" purpose?
and
is there a command to exit the loop search? like "$c::Exit"? having loop c say break or return seems to work
and
i tried the loops with one of the "sleep 1000" commands removed, and it got stuck on that loop. probably not enough time to read input

[Rohwedder]

Hallo,
timer "-1" purpose?:
If Period is negative, the timer will run only once. For example, specifying -100 would run the timer 100 ms from now then disable the timer as though SetTimer, Label, Off had been used.
is there a command to exit the loop search?
Wihout sleep?
I do not know why, but at least "Sleep, 0" is needed:

Code: Select all

SetTimer, Loops, -1
$a::Loop = a
$b::Loop = b
$c::Loop = Exit
Loops:
Loop
{
	While, Loop = "a"
	{
		SendInput 1
		Sleep, 0
	}
	While, Loop = "b"
	{
		SendInput 2
		Sleep, 0
	}
	If Loop = Exit
		Exit
}
Return