Counting files inside folder with different name + counting numbers inside filename

[Johana]

I have inside a folder textfiles that shows me how many times a script (name) has been run (0000) by a user (user).

Name_User_0000.txt

Basically I want to be able to make statistical use of this. I need to:

• Count how many times a user has run a script
• Count what scripts a user has run
• Count how many scripts a script has been run by all users

This should all be insterted into an Excelfile.

I don't know where to start or adress this. Specially since I don't know how to make a loop nor combine two variables and present them. Any and all help appreciated. Thanks in Advanced,
J

[divanebaba]

You can start with the Example #3 in Loop (files & folders).
When you are able to list and display all files, you can make second step, which could be creating a Gui for displaying desired data.
Good luck.

[Johana]

You can start with the Example #3 in Loop (files & folders).
When you are able to list and display all files, you can make second step, which could be creating a Gui for displaying desired data.
Good luck.

Not getting it to work, it's not displaying the files :S

Code: Select all

#SingleInstance, force
#Persistent
#NoEnv
SetBatchLines, -1
SetWinDelay, -1
SetTitleMatchMode 2

NetworkFolder := "XX"  ; replace with your network folder name
loop, % NetworkFolder "\*.txt" {
   scrName := RegExReplace(A_LoopFileName, "^(.*)_.*_.*", "$1")
   scrList .= scrName "`n"
}
sort, scrList, U
scrList := "Visa||" RegExReplace(scrList, "`n", "|")
Gui, Font, s10 Normal
Gui, Add, Text, x10 w50,Scripts
Gui, Add, DropDownList, yp-5 x70 gScr,%scrList%
gui, font,s15
Gui, Add,text, x10 w600 h600 vTx
gui,Show
return

Scr:
	cnt := 0
	if ( A_GuiControl = "Visa") 
		return
	loop, % NetworkFolder "\*.txt" {
		if ( RegExMatch(A_LoopFileName, A_GuiControl)) {
			cnt += RegExReplace(A_LoopFileName, ".*_(.*)\.txt", "$1")
		}
	}
	GuiControl,,Tx, % "The script: """ trim(A_GuiControl) . """ has been run " cnt " times!"
return


Esc::
GuiClose:
GuiEscape:
ExitApp
return

[BoBo]

I'd parse for the filename ...
a) extracting the username
b) creating an array named after the extracted username
c) push all upcoming details that are assigned to that specific user into its array
d) once the file filtering has been finished create a CSV file based on the array data (or trigger Excel directly using COM)

[Johana]

I'd parse for the filename ...
a) extracting the username
b) creating an array named after the extracted username
c) push all upcoming details that are assigned to that specific user into its array
d) once the file filtering has been finished create a CSV file based on the array data (or trigger Excel directly using COM)

Ah yeah that sounds clever! Since we're chatting about and having fun here, how would YOU do it?

[BoBo]

Code: Select all

Loop 9
   FileAppend, test,% A_ScriptName "_BoBo_000" A_Index ".txt"   ; create 9 files named "testscript_username_0009.txt" for testing


F10::
Loop, Files,% A_ScriptDir "\*_*_*.txt"
    {
    fArray := StrSplit(SubStr(A_LoopFileName,1,-4),"_")   ; push the different elements of the filename into the "filename"array and get rid of file extension.
    MsgBox % fArray[1]   ; show the first element of the "filename"array (probably the scriptname)
    }

uArray := fArray[2]   ; name the "username"Array after the content of the second element of the "filename"Array
%uArray% := []   ; create the dynamic "username"array
%uArray%.Push(fArray[1],fArray[3])   ; push the content of the first and third element of the "filename"array to the "username"array

MsgBox % %uArray%[2]   ; show the content of the second element of the "username"array. 
Return

Proof of concept ... (see Xtra's more sophisticated outcome below!)

[divanebaba]

I showed you following example from help file.

Code: Select all

; Example #3: Retrieve file names sorted by name (see next example to sort by date):
FileList =  ; Initialize to be blank.
Loop, C:\*.*
    FileList = %FileList%%A_LoopFileName%`n
Sort, FileList, R  ; The R option sorts in reverse order. See Sort for other options.
Loop, parse, FileList, `n
{
    if A_LoopField =  ; Ignore the blank item at the end of the list.
        continue
    MsgBox, 4,, File number %A_Index% is %A_LoopField%.  Continue?
    IfMsgBox, No
        break
}

Instead of using suggested simple beginner friendly code, you choosed a difficult coded version with many of such rows: scrName := RegExReplace(A_LoopFileName, "^(.*)_.*_.*", "$1").
When you choose such difficult code, have in mind that even support will be difficult and you will need high professional supporter instead of normal advanced supporter.
I'm sorry. Your code is too much for me. I don't have any experience with RegEx.
Good luck

[Xtra]

Code: Select all

#NoEnv
#SingleInstance, force
SetBatchLines, -1

CreateTestFiles()
myObj := {}
NetworkFolder := A_ScriptDir  ; replace with your network folder name

loop, % NetworkFolder . "\*_*_*.txt"
{
    script := name := "" , count := 0
    Loop, Parse, A_LoopFileName, _
        (A_Index = 1) ? (script := A_LoopField) : (A_Index = 2) ? (name := A_LoopField) : (count := LTrim(SubStr(A_LoopField,1,-4),"0"))
    if myObj.HasKey(script)
        myObj[script] += count 
    else
        myObj[script] := count
    scrList .= InStr(scrList,script) ?  "" : (A_Index=1 ? script . "|" : "|" . script)
    AppendCSV(script,name,count)
}

Gui, Font, s10 Normal
Gui, Add, Text, x10 w50,Scripts
Gui, Add, DropDownList, yp-5 x70 gScr vScr, %scrList%
gui, font,s15
Gui, Add,text, x10 w600 h600 vTx
gosub, Scr
gui,Show
return

Scr:
    Gui, Submit, NoHide
    GuiControl,,Tx, % "The script: """ . Scr . """ has been run " . myObj[Scr] . " times!"
return

Esc::
GuiClose:
ExitApp

AppendCSV(script,name,count)
{
    FileAppend, % script . "`," . name . "`," . count . "`n", CSV_Output.csv
}

CreateTestFiles()
{
    ;test files:
    FileAppend,,%A_ScriptDir%\Script1_Johana_0027.txt
    FileAppend,,%A_ScriptDir%\Script2_Johana_0047.txt
    FileAppend,,%A_ScriptDir%\Script2_thatguy_0021.txt
    FileAppend,,%A_ScriptDir%\Script3_ahkrocks_0014.txt
    FileAppend,,%A_ScriptDir%\Script4_testuser_0187.txt
}

HTH

[BoBo]

Code: Select all

#NoEnv
#SingleInstance, force
SetBatchLines, -1

CreateTestFiles()
myObj := {}
NetworkFolder := A_ScriptDir  ; replace with your network folder name

loop, % NetworkFolder . "\*_*_*.txt"
{
    script := name := "" , count := 0
    Loop, Parse, A_LoopFileName, _
        (A_Index = 1) ? (script := A_LoopField) : (A_Index = 2) ? (name := A_LoopField) : (count := LTrim(SubStr(A_LoopField,1,-4),"0"))
    if myObj.HasKey(script)
        myObj[script] += count 
    else
        myObj[script] := count
    scrList .= InStr(scrList,script) ?  "" : (A_Index=1 ? script . "|" : "|" . script)
    AppendCSV(script,name,count)
}

Gui, Font, s10 Normal
Gui, Add, Text, x10 w50,Scripts
Gui, Add, DropDownList, yp-5 x70 gScr vScr, %scrList%
gui, font,s15
Gui, Add,text, x10 w600 h600 vTx
gosub, Scr
gui,Show
return

Scr:
    Gui, Submit, NoHide
    GuiControl,,Tx, % "The script: """ . Scr . """ has been run " . myObj[Scr] . " times!"
return

Esc::
GuiClose:
ExitApp

AppendCSV(script,name,count)
{
    FileAppend, % script . "`," . name . "`," . count . "`n", CSV_Output.csv
}

CreateTestFiles()
{
    ;test files:
    FileAppend,,%A_ScriptDir%\Script1_Johana_0027.txt
    FileAppend,,%A_ScriptDir%\Script2_Johana_0047.txt
    FileAppend,,%A_ScriptDir%\Script2_thatguy_0021.txt
    FileAppend,,%A_ScriptDir%\Script3_ahkrocks_0014.txt
    FileAppend,,%A_ScriptDir%\Script4_testuser_0187.txt
}

HTH

That's really great
... well, I've to admit that I've shrunk your Gui to death

Spoiler

Code: Select all

Gui, Font, s10 Normal
Gui, Add, DDL,  x14  y10                 vScr gScr, %scrList%
Gui, Add, Text, x164 yp4       w600 h600 vTx
GoSub, Scr
Gui, Show, w328 h44, SEC   ; script execution counter!
Return

Scr:
    Gui, Submit, NoHide
    GuiControl,,Tx, % " ... has been run " . myObj[Scr] . " times!"
    Return