Doubleclick On Selected Treeview Item Topic is solved

[NovaRanger]

Hello Guys,

I have a Non_AHK GUI with a treeview in it.
Inside the treeview, i have to navigate down thrice a branch and select an item, after selecting the item i need to open it so that i can change some values, (this has to be done for like 500 branches)

And {Enter} doesn't seem to activate it or do anything in this GUI.


I read about something similar in this post
https://autohotkey.com/board/topic/4462 ... ew32-item/
and
something really close in this post, this one gives me the coordinates of all the 500 items in the tree. (Would be nice if i could just have the selected one alone)
https://autohotkey.com/boards/viewtopic.php?t=35455

(Code under Spoiler)

Spoiler

Code: Select all

#singleinstance, force
#persistent
CoordMode, Mouse, Window
F12::
Loop, 100
{
	
	Sleep, 100
	Send, {DOWN}{DOWN}{DOWN}{RIGHT}{RIGHT}{RIGHT}b{RIGHT}{DOWN} ; move down the tree to open the branches
	Sleep, 100

	;<Double click on treeview selected item needed here>
	
	Sleep, 1000
	
	{ ; child window operations
		WinWait, Backup ; wait for the window
		Control, UnCheck, , Button3, Backup ; uncheck a checkbox
		sleep 500
		ControlClick, Button5, Backup  ; click on save button
		Winwaitclose, Backup ; wait for the window to close
	}
} ; repeat from top
return

^Escape::
ExitApp

Basically what i need is to doubleclick on the selected item in the treeview or else i could even settle for getting the coordinates of the selected item (i would mouseclick from here)

[NovaRanger]

Any suggestions guys ?

[jeeswg]

This worked for me to invoke the focused treeview item.

Code: Select all

;[Acc functions]
;Acc library (MSAA) and AccViewer download links - AutoHotkey Community
;https://autohotkey.com/boards/viewtopic.php?f=6&t=26201

q:: ;treeview - invoke focused item
ControlGet, hCtl, Hwnd,, SysTreeView321, A
oAcc := Acc_Get("Object", "4", 0, "ahk_id " hCtl)
;MsgBox, % oAcc.accChildCount
Loop, % oAcc.accChildCount
{
	;STATE_SYSTEM_FOCUSED := 0x4
	;if (oAcc.accState(A_Index) & 0x4)
	;	MsgBox, % oAcc.accName(A_Index)
	if (oAcc.accState(A_Index) & 0x4)
		try oAcc.accDoDefaultAction(A_Index)
}
oAcc := ""
return

[EDIT:] Here's a variant that uses the Click command to click the items, however I couldn't get ControlClick to work, and it seems that neither did HotKeyIt, in the example you posted.

Code: Select all

w:: ;treeview - double-click item
WinGet, hWnd, ID, A
ControlGet, hCtl, Hwnd,, SysTreeView321, A
oAcc := Acc_Get("Object", "4", 0, "ahk_id " hCtl)
;MsgBox, % oAcc.accChildCount
Loop, % oAcc.accChildCount
{
	;STATE_SYSTEM_FOCUSED := 0x4
	;if (oAcc.accState(A_Index) & 0x4)
	;	MsgBox, % oAcc.accName(A_Index)
	if (oAcc.accState(A_Index) & 0x4)
	{
		oRect := Acc_Location(oAcc, A_Index)
		CoordMode, Mouse, Screen
		vMouseX := oRect.x + oRect.w/2
		vMouseY := oRect.y + oRect.h/2
		MouseMove, % vMouseX, % vMouseY
		Click, 2

		;attempt to use ControlClick not working
		WinGetPos, vWinX, vWinY,,, % "ahk_id " hWnd
		vMouseX -= vWinX, vMouseY -= vWinY
		;MsgBox, % "X" Round(vMouseX) " Y" Round(vMouseY)
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd,,, 2
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd,,, 2, NA
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd
		;Sleep, 300
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd
	}
}
oAcc := ""
return

[jeeswg]

- I was trying to do this via more traditional methods, but it didn't work, in case someone can point out what's going on here. If I could get this to work on an internal control, I would then try and get this working on an external control using remote buffers.

Code: Select all

q:: ;treeview GUI
Gui, New, +HwndhGui, MyWinTitle
Gui, Add, TreeView, gMyTVSub
vTV1 := TV_Add("TV 1", "", "Select")
vTV2 := TV_Add("TV 2", vTV1)
vTV3 := TV_Add("TV 3", vTV2)
vTV4 := TV_Add("TV 4", vTV1)
vTV5 := TV_Add("TV 5")
Gui, Show, w300 h300
return

MyTVSub:
ToolTip, % A_GuiEvent
return

;Tree View Notifications (Windows)
;https://msdn.microsoft.com/en-us/library/windows/desktop/ff486107(v=vs.85).aspx

w:: ;treeview - attempt to double-click focused item
ControlGet, hCtl, Hwnd,, SysTreeView321, A
;TVGN_CARET := 0x9
;hItem := SendMessage(0x110A, 0x9, 0,, "ahk_id " hCtl) ;TVM_GETNEXTITEM := 0x110A
;GWL_ID := -12
vCtlID := DllCall("GetWindowLong" (A_PtrSize=8?"Ptr":""), Ptr,hCtl, Int,-12, Ptr)
VarSetCapacity(NMHDR, A_PtrSize=8?24:12, 0)
NumPut(hCtl, &NMHDR, 0, "Ptr") ;hwndFrom
NumPut(vCtlID, &NMHDR, A_PtrSize=8?8:4, "UPtr") ;idFrom
;NM_DBLCLK := -3 ;0xFFFFFFFD
NumPut(-3, &NMHDR, A_PtrSize=8?16:8, "UInt") ;code
;NM_CLICK := -2 ;0xFFFFFFFE
;NumPut(-2, &NMHDR, A_PtrSize=8?16:8, "UInt") ;code
hWndParent := DllCall("user32\GetAncestor", Ptr,hCtl, UInt,1, Ptr) ;GA_PARENT := 1
;MsgBox, % DllCall("user32\GetDoubleClickTime", UInt) ;500
PostMessage, 0x4E,, % &NMHDR,, % "ahk_id " hWndParent ;WM_NOTIFY := 0x4E
;Sleep, 400
;PostMessage, 0x4E,, % &NMHDR,, % "ahk_id " hWndParent ;WM_NOTIFY := 0x4E
return

- Anyhow, it would be probably better to use ControlClick. @kArThIcK hAcKeR 333: Were you not able to do this via ControlClick (or the 'WM_' messages as in HotKeyIt's example that you posted a link to), once you had the coordinates?

[NovaRanger]

Spoiler

This worked for me to invoke the focused treeview item.

Code: Select all

;[Acc functions]
;Acc library (MSAA) and AccViewer download links - AutoHotkey Community
;https://autohotkey.com/boards/viewtopic.php?f=6&t=26201

q:: ;treeview - invoke focused item
ControlGet, hCtl, Hwnd,, SysTreeView321, A
oAcc := Acc_Get("Object", "4", 0, "ahk_id " hCtl)
;MsgBox, % oAcc.accChildCount
Loop, % oAcc.accChildCount
{
	;STATE_SYSTEM_FOCUSED := 0x4
	;if (oAcc.accState(A_Index) & 0x4)
	;	MsgBox, % oAcc.accName(A_Index)
	if (oAcc.accState(A_Index) & 0x4)
		try oAcc.accDoDefaultAction(A_Index)
}
oAcc := ""
return

[EDIT:] Here's a variant that uses the Click command to click the items, however I couldn't get ControlClick to work, and it seems that neither did HotKeyIt, in the example you posted.

Code: Select all

w:: ;treeview - double-click item
WinGet, hWnd, ID, A
ControlGet, hCtl, Hwnd,, SysTreeView321, A
oAcc := Acc_Get("Object", "4", 0, "ahk_id " hCtl)
;MsgBox, % oAcc.accChildCount
Loop, % oAcc.accChildCount
{
	;STATE_SYSTEM_FOCUSED := 0x4
	;if (oAcc.accState(A_Index) & 0x4)
	;	MsgBox, % oAcc.accName(A_Index)
	if (oAcc.accState(A_Index) & 0x4)
	{
		oRect := Acc_Location(oAcc, A_Index)
		CoordMode, Mouse, Screen
		vMouseX := oRect.x + oRect.w/2
		vMouseY := oRect.y + oRect.h/2
		MouseMove, % vMouseX, % vMouseY
		Click, 2

		;attempt to use ControlClick not working
		WinGetPos, vWinX, vWinY,,, % "ahk_id " hWnd
		vMouseX -= vWinX, vMouseY -= vWinY
		;MsgBox, % "X" Round(vMouseX) " Y" Round(vMouseY)
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd,,, 2
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd,,, 2, NA
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd
		;Sleep, 300
		;ControlClick, % "X" Round(vMouseX) " Y" Round(vMouseY), % "ahk_id " hWnd
	}
}
oAcc := ""
return

Thanks for the reply "jeeswg".
The second code seems to find the co-ordinates correctly.
I can invoke a normal click itself now (something is better than nothing ).

As for the code in the third post, (controlclick type).. it didnot work (even in the AHK-GUI).

Thanks