How to optimize this code Topic is solved

[Pettola]

Hi, I wrote this code few days ago, but I was not able to write it in a short way.
As you can see there are 9 code blocks which are mostly the same, the only difference is the sending of F2, F3, etc.
So I wonder if there is a way to shrink the 9 blocks in a single block, maybe using a for cycle where for every iteration the last Send command get different F2, F3, etc. key.

the full code

Code: Select all

Alt::
InputBox, UserInput, Quanti ?, , , 150, 100
i = %UserInput%

Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F2}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F3}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F4}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F5}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F6}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F7}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F8}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send {F9}
Sleep 1399

Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Return

idea for the solution

Code: Select all

for j from 1 to 9
{
Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send **component j of an array containing F2, F3, ..., F9**
Sleep 1399
}

is this possible?

[gregster]

Sure, these are very basic programming techniques that you can use in (almost) any programming language, you just have to use the right syntax. Look into loops, the built-in variable A_index - and probably if. If you are just counting up like in F1, F2... F8, you don't even need an array, just A_index - although you could use an array here, too.

[Renz]

Maybe this can help you? Im not a pro its untested but i think, in the theory, it should work...
I try allways too use Expressions for my Codes...

Code: Select all

Alt::
InputBox, UserInput, Quanti ?, , , 150, 100
MAX_STEPS := 8
While(A_Index <= MAX_STEPS)
{
	if(A_Index == MAX_STEPS)
	{
		Click
		Sleep 499
		SendInput % UserInput
		Sleep 50
		Send % "{Return}"
		break
	}
	else
	{
		Click
		Sleep 499
		SendInput % UserInput
		Sleep 50
		Send % "{Return}"
		Sleep 999
		Send % "{" (A_Index == 1 ? "F2" : "F" (A_Index+1)) "}"
		Sleep 1399
	}
}
Return

[Pettola]

Sure, these are very basic programming techniques that you can use in (almost) any programming language, you just have to use the right syntax. Look into loops, the built-in variable A_index - and probably if. If you are just counting up like in F1, F2... F8, you don't even need an array, just A_index - although you could use an array here, too.

Thank you very much for the hints!

Maybe this can help you? Im not a pro its untested but i think, in the theory, it should work...
I try allways too use Expressions for my Codes...
[/code]

Wow it works like a charm thank you very much!
I just had to put MAX_STEPS equal to 9 otherwise F9 key would not be sent.
Anyway, could you explain a bit the line

Code: Select all

Send % "{" (A_Index == 1 ? "F2" : "F" (A_Index+1)) "}"

?
It seems like you are "building" the object to send by composing it character by character: "{" + F2 (if A_Index == 1) or FA_Index+1 (otherwise) + "}"

[Renz]

A_Index is equal the times the loop is running...
Send % "{" (A_Index == 1 ? "F2" : "F" (A_Index+1)) "}"
in this part the ternary operator will check if loop runs the first time,
if the loop runs the first time, ternary operator will set "F2" cause the Expression A_Index == 1 is true!
and if the loop is running the 2,3,4,5 etc time the ternary operator will set F+LoopCount+1 means F2,F3,F4 etc
the +1 is required cause u cant change the Value of A_Index, so u need to add 1 via a + sign...
i hope this will help you, and you understand what i mean
its a pretty powerful operator... i cant much say about whats have a better performance, but i think the if() is faster in a ScriptRun...

ternary operator example in the spoiler down

Spoiler

Expression ? Expression_Its_True : Expression_Its_False
?: Called the "Ternary Operator" https://ahkde.github.io/docs/Variables.htm#ternary
a simple example with this operator is...

Code: Select all

x=1,y=2
ItsTrue := "Yes, its True! X is less then Y"
ItsFalse := "Nope, Sry Bro! X is greater then Y"
Msgbox % x < y ? ItsTrue : ItsTrue

;its a short style of if(), the msgbox above will show the same as the if() down here...
if(x < y) ; <-----
{
	Msgbox % ItsTrue
}
else
{
	Msgbox % ItsFalse
}

[FanaticGuru]

idea for the solution

Code: Select all

for j from 1 to 9
{
Click
Sleep 499
SendInput %i%
Sleep 50
Send {Return}
Sleep 999
Send **component j of an array containing F2, F3, ..., F9**
Sleep 1399
}

is this possible?

Implimentation of "idea" code:

Code: Select all

for Index, Key in ["{F2}", "{F3}", "{F4}", "{F5}", "{F6}", "{F7}", "{F8}", "{F9}"]
{
	Click
	Sleep 499
	SendInput %i%
	Sleep 50
	Send {Return}
	Sleep 999
	Send % Key
	Sleep 1399
}

This demonstrates how to use a for-loop to step through the elements of an array object.

FG

[Pettola]

A_Index is equal the times the loop is running...
Send % "{" (A_Index == 1 ? "F2" : "F" (A_Index+1)) "}"
in this part the ternary operator will check if...

thanks for the detailed explanation!

Implimentation of "idea" code:
...
This demonstrates how to use a for-loop to step through the elements of an array object.

FG

Thank you very much for the lesson!