How do I prevent a progress window from destroying another? Topic is solved

[daniel]

Hello, I got the following code from a fellow member of the board but I can't get it to work properly because I don't want one progress window to destroy another. If capslock is activated then I don't want the capslock progress window to disappear when I activate scroll lock or numlock. Is there any way to display three progress window running in the same script?

Thanks for any help!

Code: Select all

SetNumlockState, Off
SetCapsLockState, Off
SetScrollLockState, Off
cWidth := A_ScreenWidth - 202
cHeight := A_ScreenHeight - 35
nWidth := A_ScreenWidth - 202
nHeight := A_ScreenHeight - 80
sWidth := A_ScreenWidth - 202
sHeight := A_ScreenHeight - 125
 
~*CapsLock::
 
Sleep, 100
if GetKeyState("CapsLock", "T")
{
	Progress, B1 W200 H28 ZH0 FS11 WS900 x%cWidth% y%cHeight% CTFFFFFF CW0000FF, Capslock On
}
else
{
	Progress, off
}
return

~*NumLock::
 
Sleep, 100
if GetKeyState("Numlock", "T")
{
	Progress, B1 W200 H28 ZH0 FS11 WS900 x%nWidth% y%nHeight% CT000000 CW00FF00, Numlock On
}
else
{
	Progress, off
}
 
return

~*ScrollLock::
 
Sleep, 100
if GetKeyState("ScrollLock", "T")
{
	Progress, B1 W200 H28 ZH0 FS11 WS900 x%sWidth% y%sHeight% CTFFFFFF CWFF0000, Scroll Lock On
}
else
{
	Progress, off
}
return

[Marrow]

Hi,
you could create one or three GUIs instead. You can place either the three GUIs like you want to place your three progress bars or you add a progress bar when a second (or third) LockState is also true via GuiControl or Gui, Submit, NoHide.

To make a GUI not appear as a window set this options: Gui, +ToolWindow -Disabled -SysMenu -Caption +E0x20 +AlwaysOnTop
To place a text above/in a progress bar, you can add a text element with this options, e.g.: Gui, Add, Text, cBlack x%cWidth% y%cHeight% w200 h28 +0x200 +Center +BackgroundTrans, Capslock On

[jeeswg]

You could get the states of all 3, and list them in one string e.g. C N S, or Caps Num Scroll.

Also, check this:
Progress/SplashImage
https://autohotkey.com/docs/commands/Progress.htm

Each script can display up to 10 Progress windows and 10 SplashImage windows.

[daniel]

thank, guys. Turns out I just needed to name each progress window.

Code: Select all

SetCapsLockState, off
cWidth := A_ScreenWidth - 202
cHeight := A_ScreenHeight - 35
SetNumlockState, off
nWidth := A_ScreenWidth - 202
nHeight := A_ScreenHeight - 80
SetScrollLockState, off
sWidth := A_ScreenWidth - 202
sHeight := A_ScreenHeight - 125
 
~*CapsLock::
 
Sleep, 100
if GetKeyState("CapsLock", "T")
{
	Progress, 1:B1 W200 H28 ZH0 FS11 WS900 x%cWidth% y%cHeight% CTFFFFFF CW0000FF, Capslock On
}
else
{
	Progress, 1:off
}
return

 
~*NumLock::
 
Sleep, 100
if GetKeyState("Numlock", "T")
{
	Progress, 2:B1 W200 H28 ZH0 FS11 WS900 x%nWidth% y%nHeight% CT000000 CW00FF00, Numlock On
}
else
{
	Progress, 2:off
}
return

~*ScrollLock::
 
Sleep, 100
if GetKeyState("ScrollLock", "T")
{
	Progress, 3:B1 W200 H28 ZH0 FS11 WS900 x%sWidth% y%sHeight% CTFFFFFF CWFF0000, Scroll Lock On
}
else
{
	Progress, 3:off
}
return