What swagfag used is called a ?: statement or a "ternary operator". It is basically a shorthand way of writing a simple if else statement. It is formatted like this:
( conditional expression ? code to execute if true : code to execute if false)
For an example, try the following script:
Code: Select all
X := 5
Msgbox % ( X < 10 ? "X is less than ten." : "X is ten or greater.")
return
You will see that changing the value of X changes the messagebox that pops up.
The second thing swagfag used is the fairly advanced trick (which you actually accidentally included in your original code) of putting an assignment expression into an if statement. When you do that, the assignment is completed and THEN the if is evaluated. For example, in the following code:
Code: Select all
MyVar := false
if (MyVar := true)
MsgBox Hello!
You will notice that the messagebox DOES pop up, even though MyVar is initially set to false. This is because
MyVar := true sets the variable to true, and THEN the if statement is checked. This is very useful for making toggles, because putting an ! in front of a variable resolves to the opposite of that variable. So if MyVar is true, then !MyVar is false. So look at this example:
Code: Select all
MyVar := false
Rbutton::
if (MyVar := !MyVar)
MsgBox Hello
else
MsgBox World
Each time you right click, the if statement is evaluated, and
MyVar := !MyVar causes MyVar to set to true if it was false, and false if it was true. The result of that is then used to evaluate the if statement. So the first time you right click, the messagebox says "Hello", the second time it says "World", and it alternates between the two.
Putting it all together, then, this line:
Code: Select all
RButton::Send, % (shouldSendAlternate := !shouldSendAlternate) ? "n{b Down}" : "{b Up}"
Reads "When you click the right mouse button, invert the value of shouldSendAlternate. Then, if shouldSendAlternate is true, send "n{b down}. Otherwise, send "{b up}".
