One handed keyboard

[ikcosyw]

I want to be able to type with my left hand on the right side of the key board, and my thumb controlling all the modifier keys.

I would like to use the AppsKey as a modifier when held with any key to give me the keys on the left side of the keyboard and a space when pressed by itself. Also, I want to disable AppsKey from acting like AppsKey.

i.e.
::AppsKey::Space
::AppsKey+j::a
::AppsKey+j+shift::A

[gregster]

Welcome to the forum!
Please look at the tutorial to learn the basics. It seems you are confusing hotkeys (you want these) and hotstrings (you used their syntax).
Try:

Code: Select all

Appskey::Space	; Appskey alone sends Space - normal function is disabled	
AppsKey & j::a	; for a and A: press additional Shift to get A

[ikcosyw]

;I figured it out, based on a capslock script...

#singleinstance force
;Autohotkey Script AppsKey_Space.akh
F12::reload

AppsKey::
KeyWait, AppsKey ; wait for AppsKey to be released

If (A_PriorKey="AppsKey")
Send, {Space}

*AppsKey:: return ; This forces AppsKey into a modifying key.

#If, GetKeyState("AppsKey", "P") ;Your AppsKey hotkeys go below
;For my left hand I use jiop as my home row with my keyboard tilted. jiop=asdf
j::a
i::s
o::d
p::f
[::g
]::h
u::q
8::w
9::e
0::r
-::t
=::y
m::z
k::x
l::c
`;::v
'::b
#If
;end AppsKey_Space.akh

[Guest]

Perhaps useful: half-qwerty and thumbscript here https://github.com/ahkscript/awesome-AutoHotkey#typing

[evilC]

I dunno what the point of all that extra code is, what you want is very simple to do.

Code: Select all

hotkeys_on := 0

*AppsKey:: hotkeys_on := 1
*AppsKey up:: hotkeys_on := 0

#if hotkeys_on
j::a
i::s
o::d
p::f
[::g
]::h
u::q
8::w
9::e
0::r
-::t
=::y
m::z
k::x
l::c
`;::v
'::b
#if