RegExMatch AHK v1/v2: DotAll: normally, it does not match newlines

[SAbboushi]

Maybe I'm sleep deprived...

Documentation says that dot "normally, it does not match newlines".

With the following code:

Code: Select all

Pos := RegExMatch("xyz`nabc`n", "^.*$" , match)

In AHK v1, Pos = 1 and match = "xyz
abc"

In AHK v2, I get the results I expected: Pos = empty, match = empty

Am I missing something?

[SAbboushi]

Can anyone verify this?

[Helgef]

Pos will be 0 if there is no match in v2. In v2, outputvar is a match object if there is a match.

By default, a dot matches any single character which is not part of a newline (`r`n) sequence,

Note, `r`n, not single `n. v2 docs says the same, it is probably not updated,

RegEx newline matching defaults to (*ANYCRLF) and (*BSR_ANYCRLF); `r and `n are recognized in addition to `r`n.

Cheers.

[SAbboushi]

Thanks much.

[NorInd]

Pos will be 0 if there is no match in v2. In v2, outputvar is a match object if there is a match.

By default, a dot matches any single character which is not part of a newline (`r`n) sequence,

Note, `r`n, not single `n. v2 docs says the same, it is probably not updated,

RegEx newline matching defaults to (*ANYCRLF) and (*BSR_ANYCRLF); `r and `n are recognized in addition to `r`n.

Cheers.

Yes, in Ahk v1, better use `a flag option for your regex -- `a recognizes any type of newline

@ie,eg: see the following behavior:

Code: Select all

; >>>>>>>>> Run Code
stdout := FileOpen("*", "w")
; O) flag option is for getting match object

Pos := RegExMatch("xyz`nabc`n", "O)^.*$" , match)
stdout.WriteLine("-----")
stdout.WriteLine(". matches ``n")
stdout.WriteLine(Pos . ": " . match.Value)

Pos := RegExMatch("xyz`rabc`r", "O)^.*$" , match)
stdout.WriteLine("-----")
stdout.WriteLine(". matches ``r")
stdout.WriteLine(Pos . ": " . match.Value)

Pos := RegExMatch("xyz`r`nabc`r`n", "O)^.*$" , match)
stdout.WriteLine("-----")
stdout.WriteLine(". do not matches ``r``n")
stdout.WriteLine(Pos . ": " . match.Value)

Pos := RegExMatch("xyz`nabc`n", "`aO)^.*$" , match)
stdout.WriteLine("-----")
stdout.WriteLine(". do not matches ``n; cuz you use ``a) flag option -- ``a recognizes any type of newline => this is the desire behavior")
stdout.WriteLine(Pos . ": " . match.Value)

Pos := RegExMatch("xyz`nabc`n", "s`aO)^.*$" , match)
stdout.WriteLine("-----")
stdout.WriteLine(". do matches ``n; cuz you use s) flag option -- dotAll")
stdout.WriteLine(Pos . ": " . match.Value)

; >>>>>>>>> Output
; >"E:\AutoHotkey\AutoHotkey.exe" /ErrorStdOut "C:\Users\Zlgtx\Desktop\AHK scripts\Test\Test2.ahk"    
; -----
; . matches `n
; 1: xyz
; abc
; 
; -----
; . matches `r
; 1: xyz
; abc
; -----
; . do not matches `r`n
; 0: 
; -----
; . do not matches `n; cuz you use `a) flag option -- `a recognizes any type of newline => this is the desire behavior
; 0: 
; -----
; . do matches `n; cuz you use s) flag option -- dotAll
; 1: xyz
; abc
; 
; >Exit code: 0    Time: 0.2791