how to determine if variable is gui var or hwnd?

[smarq8]

i want to write function where as param i can pass control var or hwnd. So can I somehow determine when I pass hwnd or control var?

Code: Select all

LB_GetCount(Byref control){
	GuiControlGet,hLB,Hwnd,control
	return DllCall("SendMessage", "uint", hLB, "uint", 0x18B) ; LB_GETCOUNT
}

[wolf_II]

You could include an indicator with your calls, since at the time of calling, it should be known.

example:

Code: Select all

LB_GetCount(Byref control, indicator := ""){
    if (indicator = "HANDLE")
        hLB := control
    else
        GuiControlGet,hLB,Hwnd,control
	return DllCall("SendMessage", "uint", hLB, "uint", 0x18B) ; LB_GETCOUNT
}


Gui, Add, ListBox, vLB hwndhLB, A|B|C|D
Gui, Add, Button,, Test
Gui, Show
Return

GuiClose:
GuiEscape:
ExitApp

ButtonTest:
    MsgBox, % LB_GetCount(LB)
    MsgBox, % LB_GetCount(hLB, "HANDLE")
Return

[wolf_II]

Alternative way without added indicator:

Code: Select all

LB_GetCount(Byref control){
    if control is number
        hLB := control
    else
        GuiControlGet,hLB,Hwnd,control
	return DllCall("SendMessage", "uint", hLB, "uint", 0x18B) ; LB_GETCOUNT
}

[imustbeamoron]

returns true if its a hwnd, false if not.

Code: Select all

isHwnd(hwnd){
	return DllCall("IsWindow", "Ptr", hwnd)
}