WinTitle - fine-tuning the target

[StefOnSteroids]

I managed to bring up my own right mouse menu in Thunderbird:

Code: Select all

#If WinActive ("ahk_exe thunderbird.exe")
RButton::Menu, MyTBird, Show

But I don't want this menu to come up when I am composing a mail. In certain dialogs - when WinTitle contains the words "Address Book" or "Write" I want to revert to the default Thunderbird context menu.

I have tried all kinds of WinActive and WinNotActive, with and without #-directives, in nested conditionals with parentheses and quotes and what not - but I just can't get it to work. Could someone help me out, please?

[Rohwedder]

Hallo,
try:

Code: Select all

SetTitleMatchMode, 2 ;A window's title can contain WinTitle anywhere inside
GroupAdd, Thunderbird2, Address Book ahk_exe thunderbird.exe
GroupAdd, Thunderbird2, Write ahk_exe thunderbird.exe
Return
#If WinActive("ahk_group Thunderbird2") ;(specific) before general
RButton::ToolTip, ahk_group Thunderbird2
#If WinActive("ahk_exe thunderbird.exe") ;(general)
RButton::ToolTip, ahk_exe thunderbird.exe
#If

[gregster]

Rohwedder should have you covered. But note that between a function name and its parentheses with the parameters, there is no space allowed (there is one in your original post).

[wolf_II]

Try this:

Code: Select all

#If WinActive("ahk_exe thunderbird.exe")
And Not WinActive("Address Book")
And Not WinActive("Write")
RButton::Menu, MyTBird, Show

I hope that helps.untested

[StefOnSteroids]

@Rohwedder and gregster
Whoa, your approach is totally different from anything I could have ever dreamed up.
And it works! Hurrah!
Many thanks, also to gregster for pointing out my syntax error.

@wolf_II
Your solution works nicely, too. And it's close to one of my attempted routes.
Could someone please spot my syntax error, I'd like to learn from my mistakes:

Code: Select all

#If WinActive("ahk_exe thunderbird.exe") and not WinActive("Write" or "Address")
#If WinActive("ahk_exe thunderbird.exe") and (!WinActive("Write" or "Address"))

May I ask what's wrong - in general logic or syntax-wise - using the ExcludeText parameter:

Code: Select all

WinActive(WinTitle , WinText, ExcludeTitle, ExcludeText)
WinActive("ahk_exe thunderbird.exe", , "Write")
WinActive("ahk_exe thunderbird.exe", , ("Write" or "Address"))

Using ExcludeText - is that the wrong track to start with, or is it just a matter of getting the syntax right?

[wolf_II]

"Write" or "Address" this results in a boolean (True). WinActive(True) is not what you want.

WinActive(x) or WinActive(y) is what you want instead.

Using ExcludeText - is that the wrong track to start with, or is it just a matter of getting the syntax right?

wrong track, given info in OP. OP talks about WinTitles.

And it's close to one of my attempted routes.

That's what I aimed for. If possible, use plain English to describe what we want. Translate to AHK. Your post was very inviting to do so.
I count this as self-documenting code.

[StefOnSteroids]

Thank you wolf_II,
I really appreciate your feedback, it's helping me tremendously.

"Write" or "Address" this results in a boolean (True). WinActive(True) is not what you want.

I see what you're saying. By adopting ahk-help snippets to my scenario I ended up with twisted logic. It's not so much the syntax, it's the resulting logic that's at fault.

ExcludeText was a misnomer, ExcludeTitle was what I wanted to say. Regardless, it also slips up because of the boolean logic you pointed out, I can see that now.

Many thanks.