multiple copy/paste

[cynflux]

Hello,

I'd like to be able to copy 2 items and paste them in the following script (first copied item as %clipboard% and second copied item as another variable name like %clipboard2%)

Code: Select all

:OC:tpu::
SetKeyDelay, 0
Send Called
Send {Space}
SendInput %clipboard%
Send {Space}
Send and spoke with 
Send {Space}
SendInput %clipboard2% and advised that we have picked up their ticket.
Return

Is there a way to do this?
Thank you in advance.

[Qysh]

Alt+C to copy to the second Clipboard
Alt+V to paste the second Clipboard
F6 to send your formated Text

Code: Select all

Clipboard2 = %Clipboard%

!C::
Clipboardtemp = %Clipboard%
Send, ^{c}
Clipboard2 = %Clipboard%
Clipboard = %Clipboardtemp%
return

!V::
Clipboardtemp = %Clipboard%
Clipboard = %Clipboard2%
Send, ^{v}
Clipboard = %Clipboardtemp%
return

F6::
Clipboardtemp = %Clipboard%
Clipboard = Called %Clipboard% and spoke with %Clipboard2% and advised that we have picked up their ticket.
Send, ^{v}
Clipboard = %Clipboardtemp%
return

[burque505]

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
;**************************
; Just Ctrl-C for the first clip, Alt-C for the second clip
; Then your hotstring

!C::
first := Clipboard
Clipboard =
Send, ^{c}
ClipWait
second := Clipboard
Clipboard =
return

:O*C:tpu::
Clipboard = Called %first% and spoke with %second% and advised that we have picked up their ticket.
Send, ^{v}
return

Escape::ExitApp

EDIT: I overedited this without checking, now it isn't working, I'll post it when I undo my mistakes. Thanks.
Fixed.

2clips3.gif (23.98 KiB) Viewed 4077 times

Regards,
burque505

[aalim]

Hi there. how would the code go if there are 4 words to copy and paste? tried modifying the code, but only 3 words get pasted. cheers. thanks

[rommmcek]

Try:

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

Clp:= []
Return

+^c:: ; add marked text to custom "clipboard"
    Clipboard:= ""
    Send, ^c
    ClipWait, 1
    Clp.Push(Clipboard)
Return

^Del:: Clp.RemoveAt(Clp.Length()) ; delete last "clipboard"
+^Del:: Clp:= [] ; delete all "clipboards"

F6:: ; display all "clipboards"
    cl:= ""
    for i, j in Clp
        cl.= i ": " j "`n"
    MsgBox % cl
Return

+^v:: ; paste the "sentence" with "clipboards"
    Clipboard:= "aaa " Clp.1 " bbb " Clp.2 " ccc " Clp.3 " ddd " Clp.4 " eee " Clp.5 ; ....
    Send, ^v
Return

+^Esc:: ExitApp ; exit applicaton