List all open and visible window (Alt+Tab) in windwos 10 Topic is solved

[sobuj53]

Hi,
I'm trying to list all open and visible window (minimized one also count) using following code (this code is not mine),

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
SetTitleMatchMode, RegEx
DetectHiddenWindows, Off
WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle wt, ahk_id %id%
	r .= wt . "`n"
}
MsgBox %r%

Though it list all open window, it also list inactive non visible window (those were not running when I run this script) in windows 10 like Calculator, Microsoft Edge, Photos, Store... etc. From what I've come to know is windows 10 use ApplicationFrameHost to display or run those widow. Is there any way to list only visible (minimized one also count) window like Alt+Tab window?

Best Regards,
Sobuj

[AHKStudent]

check your system and you will see if it shows calculator you have calculator.exe running etc

[tidbit]

winget,,list... shows a lot of things that are not in the alt-tab window. it's not just him. It's an ahk/os thing. iirc, It's tricky to get what he wants.

[sobuj53]

check your system and you will see if it shows calculator you have calculator.exe running etc

Thanks for your replay. As I've mentioned, it was not running well at least not visible. My goal is to list only visible windows (Minimized in task bar also counts). I've also tried this code https://autohotkey.com/board/topic/9191 ... lose-them/. But it list inactive invisible window

[sobuj53]

winget,,list... shows a lot of things that are not in the alt-tab window. it's not just him. It's an ahk/os thing. iirc, It's tricky to get what he wants.

Windows 10 made life harder

[tidbit]

best way I can think of, get everything before "system \n system" and remove any blank lines.

for me, running your code, has 2 "system" items in a row, and all of my windows were above that.
Will it be 100% reliable? no idea. but it's worth a shot if you have the same results.

[GEV]

Try also

Code: Select all

WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{	
		; If title not contains ...  ; add exceptions
		continue
	}
	r .= title . "`n"
}
MsgBox %r%

[sobuj53]

Try also

Code: Select all

WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{	
		; If title not contains ...  ; add exceptions
		continue
	}
	r .= title . "`n"
}
MsgBox %r%

Thanks for your reply but as you can see marked item was not running (well atleast not visible in taskbar). But still they were listed.

[sobuj53]

best way I can think of, get everything before "system \n system" and remove any blank lines.

for me, running your code, has 2 "system" items in a row, and all of my windows were above that.
Will it be 100% reliable? no idea. but it's worth a shot if you have the same results.

Can you please provide the code. I didn't get the part "system \n system".

[GEV]

If you don’t want Windows 10 Apps running in the background, you can disable this feature:
https://www.howtogeek.com/241752/how-to ... ackground/

Try also:

Code: Select all

WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	WinGetClass class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	}
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	r .= title . "`n"
}
MsgBox %r%

[sobuj53]

If you don’t want Windows 10 Apps running in the background, you can disable this feature:
https://www.howtogeek.com/241752/how-to ... ackground/

Try also:

Code: Select all

WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	WinGetClass class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	}
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	r .= title . "`n"
}
MsgBox %r%

Thanks, stoping Windows 10 Apps running in the background is an option to consider. Above code how ever don't register Windows 10 Apps when they are actually open and visible!

I have a solution that works without stoping background apps,

Code: Select all

^F::
ignored := { "Microsoft.Photos.exe":0, "WinStore.App.exe":0, "Video.UI.exe":0, "ApplicationFrameHost.exe":0, "Calculator.exe":0
, "WinStore.exe":0, "Avro Keyboard.exe":0, "SystemSettings.exe":0, "MicrosoftEdgeCP.exe":0, "MicrosoftEdge.exe":0 }

WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	WinGet ProcsName, ProcessName, ahk_id %id%
	
	if ignored.HasKey(ProcsName)=1  ; if the window doesn't have a title bar
	{	
		; If title not contains ...  ; add exceptions
		continue
	}
	r .= title . "`n"
}
MsgBox %r%

reload
return

But this means I'm permanently blacklisting those. It's not possible to list windows apps when they are visible in taskbar via this script. Hope there will be a option to detect them somedays.

[GEV]

This works on my system Win10 Build 17134.137 (only windows apps visible in taskbar are shown on the menu):

Code: Select all

$F1::
Menu, Windows, Add
Menu, Windows, deleteAll
WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle, title, ahk_id %id%
	WinGetClass, class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	} 
	WinGet, style, style, ahk_id %id%
	If !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	WinGet, Path, ProcessPath, ahk_id %id%
	Menu, Windows, Add, %title%, Activate_Window
    If (class  = "ApplicationFrameWindow")
        Menu, Windows, Icon, %title%, %A_WinDir%\System32\SHELL32.dll, 3, 0
    else
        Menu, Windows, Icon, %title%, %Path%,, 0
}
Menu, Windows, Show
return

Activate_Window:
	SetTitleMatchMode, 3
	WinActivate, %A_ThisMenuItem%
return

[sobuj53]

This works on my system Win10 Build 17134.137 (only windows apps visible in taskbar are shown on the menu):

Code: Select all

$F1::
Menu, Windows, Add
Menu, Windows, deleteAll
WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle, title, ahk_id %id%
	WinGetClass, class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	} 
	WinGet, style, style, ahk_id %id%
	If !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	WinGet, Path, ProcessPath, ahk_id %id%
	Menu, Windows, Add, %title%, Activate_Window
    If (class  = "ApplicationFrameWindow")
        Menu, Windows, Icon, %title%, %A_WinDir%\System32\SHELL32.dll, 3, 0
    else
        Menu, Windows, Icon, %title%, %Path%,, 0
}
Menu, Windows, Show
return

Activate_Window:
	SetTitleMatchMode, 3
	WinActivate, %A_ThisMenuItem%
return

Thank you very much. But this throws an error Error: Parameter #3 must not be blank in this case. at line 027

Code: Select all

Menu, Windows, Icon, %title%, %Path%,, 0

[GEV]

In that case try to find out what program/window is the cause for the error (AHK cannot find the path of the process or the executable file doesn't contain any icons) and use the same icon as in ApplicationFrameWindow:

Code: Select all

$F1::
Menu, Windows, Add
Menu, Windows, deleteAll
WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	If (title = "")
		continue
	WinGetClass class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	} 
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	WinGet, Path, ProcessPath, ahk_id %id%
	Menu, Windows, Add, %title%, Activate_Window
	 ; If  the executable file doesn't contain any icons (replace "this_class" with the class of that window)
    If (class  = "ApplicationFrameWindow") || (class  = "this_class")
        Menu, Windows, Icon, %title%, %A_WinDir%\System32\SHELL32.dll, 3, 0
    else
        Menu, Windows, Icon, %title%, %Path%,, 0
}
Menu, Windows, Show
return

Activate_Window:
	SetTitleMatchMode, 3
	WinActivate, %A_ThisMenuItem%
return

[sobuj53]

In that case try to find out what program/window is the cause for the error (AHK cannot find the path of the process or the executable file doesn't contain any icons) and use the same icon as in ApplicationFrameWindow:

Code: Select all

$F1::
Menu, Windows, Add
Menu, Windows, deleteAll
WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	If (title = "")
		continue
	WinGetClass class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	} 
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	WinGet, Path, ProcessPath, ahk_id %id%
	Menu, Windows, Add, %title%, Activate_Window
	 ; If  the executable file doesn't contain any icons (replace "this_class" with the class of that window)
    If (class  = "ApplicationFrameWindow") || (class  = "this_class")
        Menu, Windows, Icon, %title%, %A_WinDir%\System32\SHELL32.dll, 3, 0
	 else
    If (class  = "this class")
        Menu, Windows, Icon, %title%, %A_WinDir%\System32\SHELL32.dll, 3, 0
    else
        Menu, Windows, Icon, %title%, %Path%,, 0
}
Menu, Windows, Show
return

Activate_Window:
	SetTitleMatchMode, 3
	WinActivate, %A_ThisMenuItem%
return

This throws another error . I must be missing something. Just can't figure out what that is!

[GEV]

taskhostw.exe isn't a visible process/window unless you have DetectHiddenWindows On. Try the above code as a stand alone script.
You can also add this to the code:

Code: Select all

	...
	WinGet, Path, ProcessPath, ahk_id %id%
	SplitPath, Path,,,,name_no_ext
	If (name_no_ext= "taskhostw")
		continue
	Menu, Windows, Add, %title%, Activate_Window
	...

[Nextron]

You're probably using a 32-bit AHK on a 64-bit Windows? Then some redirection occurs, which might cause issues: https://msdn.microsoft.com/en-us/librar ... 85%29.aspx

---

Instead of manually adding exceptions to a default icon, wouldn't it be more reliable to use a Try/Catch:

Code: Select all

$F1::
Menu, Windows, Add
Menu, Windows, deleteAll
WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	If (title = "")
		continue
	WinGetClass class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	} 
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	WinGet, Path, ProcessPath, ahk_id %id%
	Menu, Windows, Add, %title%, Activate_Window
	Try 
		Menu, Windows, Icon, %title%, %Path%,, 0
	Catch 
		Menu, Windows, Icon, %title%, %A_WinDir%\System32\SHELL32.dll, 3, 0
}
Menu, Windows, Show
return

Activate_Window:
	SetTitleMatchMode, 3
	WinActivate, %A_ThisMenuItem%
return

[sobuj53]

taskhostw.exe isn't a visible process/window unless you have DetectHiddenWindows On. Try the above code as a stand alone script.
You can also add this to the code:

Code: Select all

	...
	WinGet, Path, ProcessPath, ahk_id %id%
	SplitPath, Path,,,,name_no_ext
	If (name_no_ext= "taskhostw")
		continue
	Menu, Windows, Add, %title%, Activate_Window
	...

Thank you sir. This works great. I really appreciate your help and time on this.

[sobuj53]

You're probably using a 32-bit AHK on a 64-bit Windows? Then some redirection occurs, which might cause issues: https://msdn.microsoft.com/en-us/librar ... 85%29.aspx

---

Instead of manually adding exceptions to a default icon, wouldn't it be more reliable to use a Try/Catch:

Code: Select all

$F1::
Menu, Windows, Add
Menu, Windows, deleteAll
WinGet windows, List
Loop %windows%
{
	id := windows%A_Index%
	WinGetTitle title, ahk_id %id%
	If (title = "")
		continue
	WinGetClass class, ahk_id %id%	
	If (class = "ApplicationFrameWindow") 
	{
		WinGetText, text, ahk_id %id%
		If (text = "")
			continue
	} 
	WinGet, style, style, ahk_id %id%
	if !(style & 0xC00000) ; if the window doesn't have a title bar
	{
		; If title not contains ...  ; add exceptions
			continue
	}
	WinGet, Path, ProcessPath, ahk_id %id%
	Menu, Windows, Add, %title%, Activate_Window
	Try 
		Menu, Windows, Icon, %title%, %Path%,, 0
	Catch 
		Menu, Windows, Icon, %title%, %A_WinDir%\System32\SHELL32.dll, 3, 0
}
Menu, Windows, Show
return

Activate_Window:
	SetTitleMatchMode, 3
	WinActivate, %A_ThisMenuItem%
return

Thank your very much for help sir. This works neatly. Love this community never came back empty handed.

[GEV]

Instead of manually adding exceptions to a default icon, wouldn't it be more reliable to use a Try/Catch