call AHK script from .BAT or .PS1 and capture errorcode?

[teknowledgist]

I would like to put a timer in my AHK script that exits the script if it takes too long. I need to know if the script has exited this way or the "correct" way so my PoSh (or CMD) script can continue in the correct direction. The ExitApp documentation indicates that this should possible, but I cannot seem to get it to work.

test.ahk:

Code: Select all

SetTimer, TooLong, 5000

msgbox, Testing!
ExitApp

TooLong:
ExitApp, 666

When I do this in a CMD window:

Code: Select all

autohotkey test.ahk
echo %errorlevel%

I inevitably get "0" no matter if I click the msgbox (which should give a "0") or I wait and the script exists (which should return "666").

I also tried with PowerShell:

Code: Select all

$Proc = start-process -filepath autohotkey -argumentlist .\test.ahk -passthru
$handle = $proc.handle  # See:  https://stackoverflow.com/a/23797762
Write-Host $proc.exitcode

which also always gives me an exitcode of "0".

These appear to be giving me the errorcode that indicates the script was *started* successfully. How can I capture the completion error code I am exiting with?

Thanks.

[Alguimist]

You can get %ERRORLEVEL% in the command prompt if you start the command line with "cmd /c".

The exit code can also be retrieved this way:

Code: Select all

RunWait, Temp.ahk,, UseErrorLevel
MsgBox % ErrorLevel

[tmplinshi]

Compile your script to console app using the new ahk2exe

Code: Select all

;@Ahk2Exe-ConsoleApp
FileAppend, Hello`n, *
ExitApp 1234

[teknowledgist]

You can get %ERRORLEVEL% in the command prompt if you start the command line with "cmd /c".

That doesn't work:

Code: Select all

c:>cmd /c autohotkey test.ahk && echo %errorlevel%
0

The "0" return is immediate before the AHK script times out. The %errorlevel% is for the success of AHK starting the script, not the results of the script.

The exit code can also be retrieved this way:

Code: Select all

RunWait, Temp.ahk,, UseErrorLevel
MsgBox % ErrorLevel

But that is getting the exitcode within another AHK script! I need to know the exitcode outside of AHK, and I don't want to show a dialog. I have other things that will happen (outside of AHK) based on the AHK exit code (assuming I can get it!).

Thanks for the reply though.

[teknowledgist]

Compile your script to console app using the new ahk2exe

Code: Select all

;@Ahk2Exe-ConsoleApp
FileAppend, Hello`n, *
ExitApp 1234

Thanks for the suggestion, but I must have a plain-text AHK script, not something compiled.

[tmplinshi]

Well then you can change AutoHotkey.exe to console program

Spoiler

Code: Select all

newFile := A_LineFile "\..\AutoHotkeyCon.exe"
FileCopy, %A_AhkPath%, %newFile%, 1
switch_subsystem(newFile, "C")
ExitApp

/*
	Modified from http://www.autohotkey.com/board/topic/21189-compile-ahk-ii-for-those-who-compile/?p=316030

	Args:
		filename  - bin/exe file to switch
		subsystem - "C" (console) or "G" (gui). if omitted, switches between the two.
*/
switch_subsystem(filename, subsystem := "") {
	static IMAGE_DOS_SIGNATURE := 0x5A4D
	     , IMAGE_NT_SIGNATURE := 0x4550
	     , IMAGE_SIZEOF_FILE_HEADER := 20
	     , IMAGE_SUBSYSTEM_WINDOWS_GUI := 2
	     , IMAGE_SUBSYSTEM_WINDOWS_CUI := 3

	; Open file for read/write.
	If !f := FileOpen(filename, "rw")
		Return "CreateFile failed"

	; Verify EXE signature.
	e_magic := f.ReadUShort()
	If (e_magic != IMAGE_DOS_SIGNATURE)
		Return "Bad exe file: no DOS sig", f.Close()

	; Get offset of IMAGE_NT_HEADERS.
	f.Pos := 60
	e_lfanew := f.ReadInt()

	; Verify NT signature.
	f.Pos := e_lfanew
	ntSignature := f.ReadUInt()
	If (ntSignature != IMAGE_NT_SIGNATURE)
		Return "Bad exe file: no NT sig", f.Close()

	; Calculate offset of IMAGE_OPTIONAL_HEADER and its Subsystem field.
	offset_optional_header := e_lfanew + 4 + IMAGE_SIZEOF_FILE_HEADER
	offset_Subsystem := offset_optional_header + 68

	; Read current subsystem.
	f.Pos := offset_Subsystem
	Cur_Subsystem := f.ReadUShort()

	; Write new subsystem.
	Subsystem := (Subsystem = "C")                             ? IMAGE_SUBSYSTEM_WINDOWS_CUI
	           : (Subsystem = "G")                             ? IMAGE_SUBSYSTEM_WINDOWS_GUI
	           : (Cur_Subsystem = IMAGE_SUBSYSTEM_WINDOWS_CUI) ? IMAGE_SUBSYSTEM_WINDOWS_GUI
	           : IMAGE_SUBSYSTEM_WINDOWS_CUI
	f.Pos := offset_Subsystem
	f.WriteUShort(Subsystem)

	f.Close()
}

Just run the above script, it will copy AutoHotkey.exe to AutoHotkeyCon.exe, and change AutoHotkeyCon.exe to a console program.
After that, run your ahk script using this AutoHotkeyCon.exe.

Code: Select all

@echo off
AutoHotkeyCon.exe test.ahk
echo %errorlevel%

Edit: Doesn't have to do that. See Alguimist's reply below.

[Alguimist]

That doesn't work:

Try again, this time with this batch file:

Code: Select all

@ECHO OFF
C:\Path\To\AutoHotkey.exe Test.ahk
ECHO %ERRORLEVEL%
PAUSE

But that is getting the exitcode within another AHK script! I need to know the exitcode outside of AHK

ErrorLevel can be passed as a command line parameter to a batch file:

Code: Select all

RunWait, Test.ahk,, UseErrorLevel
Run Outside.bat %ErrorLevel%

[teknowledgist]

Doh! I'm eating crow for desert tonight!

All my calls to AutoHotKey were not full path calls because it is in the path (or so I thought). It turns out, what is in the path is a "shim" that redirects AHK calls to the correct path (AHK is installed via Chocolatey.)

The shim is blocking the exitcode (or passing it at the expense of a big, ugly, cmd window if I use the a particular switch).

Once I used the full path to AutoHotKey.exe as you instructed, it is working as promised.

Sorry for the noise and thanks for leading me in the right direction.

[KuroiLight]

just an after thought, for powershell you can do (Start-Process -FilePath './cmdtest.ahk' -PassThru -Wait).ExitCode and call cmd /c "cmdtest.ahk" for cmdprompt