Is is possible to use auto copy/paste? Topic is solved

Get help with using AutoHotkey and its commands and hotkeys
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Is is possible to use auto copy/paste?

20 Jul 2018, 03:36

Hello guys,

I'm a new member here and a newbie using hotkeys.

I have some work to do that involves a lot of copy/paste texts.
I'm looking for a faster way to do this, and I was thinking of using hotkeys, but I don't know if is possible.

Let me try to explain what I need:

I have a website where I need to put "domain" in field1 and "domain url" on field2.
My idea is when I copy a domain and paste into field1, the field2 will be filled automatically with that specific domain.

Please check this screenshot for better understanding: http://take.ms/ESazK

I have a long list in notepad with:
domain URL

And every time I need to copy a domain, I need to go back to the file and copy the URL too.
If someone helps me with this, is one less step that makes me save some time.

Thank you!

And sorry for my poor English, is not my native language.
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

21 Jul 2018, 08:53

Hello again guys,

Let's say I have a notepad file with the following list format:
#

21domain.com http://21domain.com

A

artdomain.com https://artdomain
animaldomain.com http://animaldomain.com

B

(...)
I want to put domain.com in field1 and url in field2.

Is it possible to just copy (Ctrl+C) the full line, example:
animaldomain.com http://animaldomain.com
And when I paste (Ctrl+V) in field1, the script put the domain in field1, give TAB and put the url in field2?

A guy from reddit gave me this code:

Code: Select all

; full path to file here:
filepath = C:\Users\User\Desktop\testlist.txt
; reading the file into vars
Loop, read, %filepath%
{
	StringSplit, TempArray, A_LoopReadLine , %A_Tab%
	Domain_%A_Index% := TempArray1
	Url_%A_Index% := TempArray2
	MaxIndex := A_Index
}
CurrIndex := 1

;hotkey to input the data, change to whatever you want
F9::
SendRaw, % Domain_%CurrIndex%
sleep, 10
Send, {Tab}
sleep, 10
SendRaw, % Url_%CurrIndex%
return

; hotkey to get next set, change to whatever you want
F10::
CurrIndex += 1
if (CurrIndex > MaxIndex)
{
	CurrIndex := 1
	MsgBox, End of List!
}
But is not working like I need. But maybe someone can help me in adjust the code to my needs.

Can someone please help me?

Or if you think in a better/faster solution for my case, I really appreciate it :)

Thank you!!
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

21 Jul 2018, 13:54

Try

Code: Select all

; Press F1 in Notepad to copy the line at the caret position:

#IfWinActive WinTitle of Notepad	
	
	$F1::
	domain := "" ; empty this variable (erase its content)
	URL := ""
	ClipSaved := ClipboardAll  ; save the entire clipboard to the variable ClipSaved
	clipboard := ""  ; empty the clipboard (start off empty to allow ClipWait to detect when the text has arrived)
	Send, {End}+{HOME} ; select the whole line at the caret position
	Sleep, 30
	Send, ^c ; copy the selected line
	ClipWait 1 ; wait for the clipboard to contain data
	If ErrorLevel  ; If  ErrorLevel clipwait found no data on the clipboard
	{
		 MsgBox, No text selected`n`tTry again!
		 clipboard := ClipSaved ; restore original clipboard
		 return
	}
	If !InStr(Clipboard, "://")
	{
		MsgBox, The selected text does not contain any URL`n`tTry again!
		clipboard := ClipSaved
		return
	}
	; otherwise:
	domain := StrSplit(Clipboard," ").1
	URL := StrSplit(Clipboard," ").2
	Sleep, 300
	clipboard := ClipSaved
	return

; Press F1 in your browser to paste the copied line:

#IfWinActive WinTitle of the web page
	
	$F1:: SendInput, %domain%%A_Tab%%URL%
 
#IfWinActive ; turn off context sensitivity
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

21 Jul 2018, 14:06

Hey GEV, thank you so much for helping me! :)

Unfortunately, the script is not working, nothing happens.
Btw, I changed F1 with F8 because the F1 was opening the Microsoft support page.

I tried:

1- cursor in line I wanted on notepad and clicked F8 (without select all line)
2- cursor in line I wanted on notepad, select all line and clicked F8.
3- In browser I clicked F8 again but nothing happens.

Any idea of what could be?

Thank you again for your time helping me.
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

21 Jul 2018, 14:12

Have you replaced "WinTitle of Notepad" and "WinTitle of the web page" with the right titles of the programs (as shown in Windows Spy)?
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

21 Jul 2018, 16:34

GEV wrote:Have you replaced "WinTitle of Notepad" and "WinTitle of the web page" with the right titles of the programs (as shown in Windows Spy)?
Ohhh, like I said, I'm a total newbie hehe.

Thanks, it was that. But the copy is not working, is always keep saying "No text selected. Try again!"

What could be? Did you test it?

Code: Select all

; Press F8 in Notepad to copy the line at the caret position:

#IfWinActive linkslist - Notepad	
	
	$F8::
	domain := "" ; empty this variable (erase its content)
	URL := ""
	ClipSaved := ClipboardAll  ; save the entire clipboard to the variable ClipSaved
	clipboard := ""  ; empty the clipboard (start off empty to allow ClipWait to detect when the text has arrived)
	Send, {End}+{Pos1} ; select the whole line at the caret position
	Sleep, 30
	Send, ^c ; copy the selected line
	ClipWait 1 ; wait for the clipboard to contain data
	If ErrorLevel  ; If  ErrorLevel clipwait found no data on the clipboard
	{
		 MsgBox, No text selected`n`tTry again!
		 clipboard := ClipSaved ; restore original clipboard
		 return
	}
	If !InStr(Clipboard, "://")
	{
		MsgBox, The selected text does not contain any URL`n`tTry again!
		clipboard := ClipSaved
		return
	}
	; otherwise:
	domain := StrSplit(Clipboard," ").1
	URL := StrSplit(Clipboard," ").2
	Sleep, 300
	clipboard := ClipSaved
	return

; Press F8 in your browser to paste the copied line:

#IfWinActive Edit Model ‹ Agency — WordPress - Google Chrome:
	
	$F8:: SendInput, %domain%%A_Tab%%URL%
 
#IfWinActive ; turn off context sensitivity
Thanks once again!
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

21 Jul 2018, 17:12

First of all you have to activate the window to which you want send the commands, and second, the keyboard caret has to be positioned (e,g. by clicking) on the line you will copy, before pressing F8 in Notepad and
in the field1, before pressing F8 in Chrome.
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

21 Jul 2018, 18:33

GEV wrote:First of all you have to activate the window to which you want send the commands, and second, the keyboard caret has to be positioned (e,g. by clicking) on the line you will copy, before pressing F8 in Notepad and
in the field1, before pressing F8 in Chrome.
I already did that as you can see in the code above, I added the correct window titles:

Code: Select all

#IfWinActive WinTitle of Notepad	
#IfWinActive Edit Model ‹ Agency — WordPress - Google Chrome
And I also did what you said too, I click on the line on notepad and only after I press F8. The error appears when I do that.
Can you try the code in your computer, please? :)

Thank you!
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 03:27

Works for me.

Another (more practical) way is to use a GUI for sending the text:

Code: Select all

WinTitle := "Edit Model ‹ Agency — WordPress - Google Chrome:"

Gui, Add, ListView, r10 w400 gMyListView, domain|URL
; Loop, Read, Fullpath of the file linkslist.txt
; or:
Loop, Read, linkslist.txt ; if linkslist.txt is located in the script's (working ) directory
{
	If !InStr(A_LoopReadLine, "://")
		continue
	domain := StrSplit(A_LoopReadLine," ").1
	URL := StrSplit(A_LoopReadLine," ").2
	LV_Add("", domain, URL)
}
LV_ModifyCol()  ; auto-size each column to fit its contents.
Gui, Add, Button, Default, Send
Gui, Show,, Send domain+URL
return

MyListView:
	If (A_GuiEvent = "DoubleClick")
	{
		LV_GetText(domain, A_EventInfo, 1)
		LV_GetText(URL, A_EventInfo, 2)
		; MsgBox, domain = "%domain%"`nURL = "%URL%"
		WinActivate, %WinTitle%
		WinWaitActive, %WinTitle%
		SendInput, %domain%%A_Tab%%URL%
	}
return

; https://autohotkey.com/docs/commands/ListView.htm#LV_GetNext
ButtonSend:
	RowNumber  = 0
	Loop
	{
		RowNumber := LV_GetNext(RowNumber)  
		If (!RowNumber)
			Break
		LV_GetText(domain, RowNumber, 1)
		LV_GetText(URL, RowNumber, 2)
		; MsgBox, domain = "%domain%"`nURL = "%URL%"
		WinActivate, %WinTitle%
		WinWaitActive, %WinTitle%
		SendInput, %domain%%A_Tab%%URL%
	}
Return

Esc::
GuiClose:
ExitApp
Last edited by GEV on 22 Jul 2018, 03:56, edited 1 time in total.
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 03:52

That's weird, the 1st code is not working for me and I think I'm doing everything correctly.

The 2nd option is a much better option, thank you so much my friend!

But when I press send, is not sending the domain name.

I need:

field1: domain.com (selected)
field2: http://domain.com (selected)

And is sending as:

field1: http://domain.com (selected)
field2: http://domain5.com (last domain in list)

Screenshot: http://take.ms/WZGOTm

Any idea how to fix this? :)

Thank you so much for your time helping me with this.

We are very close!!
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 04:19

I made a typing mistake. Try my edited answer.
Instead of clicking Send, you can also doubleclick the desired item or press Enter after selecting it.
To select an item you can also use the Up/down buttons on your keyboard.
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 04:34

Working perfectly now, thank you so much!! :D

Just two "little" things:

1- In my list, I have subsites listed in this format:

domain.com http://domain.com
- subdomain1.com http://subdomain1.com
- subdomain2.com http://subdomain2.com
- subdomain3.com http://subdomain3.com

Is it possible to ignore the "-"?
But I need to identify in the window that is a subdomain somehow.
Maybe show as "- subdomain.com" but paste as "subdomain.com"

2- Is it possible to show notes for each link in the 3rd column of the window? Example:

domain.com http://domain.com
- subdomain1.com http://subdomain1.com
- subdomain2.com http://subdomain2.com (this is a note)
- subdomain3.com http://subdomain3.com

Your code is already working great, but if you can do this, would be perfect!! :)

Thank you once again!!
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?  Topic is solved

22 Jul 2018, 10:31

Code: Select all

WinTitle := "Edit Model ‹ Agency — WordPress - Google Chrome:"

Gui, Add, ListView, r10 w400 gMyListView, domain|URL|notes

; Loop, Read, Fullpath of the file linkslist.txt
; or:
Loop, Read, linkslist.txt ; if linkslist.txt is in the script's (working ) directory
{
	If !InStr(A_LoopReadLine, "://")
		continue
	If (SubStr(A_LoopReadLine, 1, 2) = "- ")
	{
		domain := "- " . StrSplit(A_LoopReadLine," ").2
		URL := StrSplit(A_LoopReadLine," ").3
	}
	else
	{
		domain := StrSplit(A_LoopReadLine," ").1
		URL := StrSplit(A_LoopReadLine," ").2
	}
	If InStr(A_LoopReadLine, "(")
	{
		note := "(" . StrSplit(A_LoopReadLine,"(").2
		LV_Add("", domain, URL, note)
	}
	else
		LV_Add("", domain, URL)
}
LV_ModifyCol()  ; auto-size each column to fit its contents.
Gui, Add, Button, Default, Send
Gui, Show,, Send domain+URL
return

MyListView:
	If (A_GuiEvent = "DoubleClick")
	{
		LV_GetText(domain, A_EventInfo, 1)
		If SubStr(domain, 1, 2) = "- "
			domain := SubStr(domain, 3)
		else
			domain := domain
		LV_GetText(URL, A_EventInfo, 2)
		; MsgBox, domain = "%domain%"`nURL = "%URL%"
		WinActivate, %WinTitle%
		WinWaitActive, %WinTitle%
		SendInput, %domain%%A_Tab%%URL%
	}
return

; https://autohotkey.com/docs/commands/ListView.htm#LV_GetNext
ButtonSend:
	RowNumber = 0
	Loop
	{
		RowNumber := LV_GetNext(RowNumber)  
		If (!RowNumber)
			Break
		LV_GetText(domain, RowNumber, 1)
		If SubStr(domain, 1, 2) = "- "
			domain := SubStr(domain, 3)
		else
			domain := domain
		LV_GetText(URL, RowNumber, 2)
		; MsgBox, domain = "%domain%"`nURL = "%URL%"
		WinActivate, %WinTitle%
		WinWaitActive, %WinTitle%
		SendInput, %domain%%A_Tab%%URL%
	}
Return

Esc::
GuiClose:
ExitApp
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 10:49

OMG is working perfectly !!!

Thank you so much, mate!! You're a lifesaver :D
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 12:09

I was thinking since I have a big list of domains, do you have any idea how to show domains per selected letter instead of loading full list?

For example, my list format:
#

21domain.com http://21domain.com

A

artdomain.com http://artdomain
- subdomainart.com http://artsubdomain.com
animaldomain.com http://animaldomain.com

B

(...)
Maybe a drop-down with the letters to choose, such as:
ALL
#
A
B
(...)
If I choose for example letter A, will only show:
artdomain.com http://artdomain
- subdomainart.com http://artsubdomain.com
animaldomain.com http://animaldomain.com
I hope you got the idea... is it difficult to create? :)

Thank you so much for your time!!
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 15:41

Press Alt+Shift+letter to show the corresponding domain in the GUI:

Code: Select all

#NoEnv
#SingleInstance Force
SetWorkingDir %A_ScriptDir%

WinTitle := "Edit Model ‹ Agency — WordPress - Google Chrome:"

Keys := ["#","1","2","3","4","5","6","7","8","9","0"]
for each, key in Keys
	Hotkey, !+%key%, Create_LV_Key, On

Loop, 26
	Hotkey, % "!+" Chr(A_Index + 64), Create_LV_Key, On
return

Create_LV_Key:
key := SubStr(A_ThisHotkey, 0)
Gui, destroy
Index := ""
text := ""
Loop, Read, linkslist.txt
{
	If ((StrLen(A_LoopReadLine) = 1) && (A_LoopReadLine == key))
	{
		Index := A_Index
			break
	}
}
Loop, Read, linkslist.txt
{
	If (A_Index <= Index)
		continue
	If (A_LoopReadLine = "")
		continue
	If (StrLen(A_LoopReadLine) = 1) && (A_Index > Index)
		break
	text .= A_LoopReadLine "`r`n"
}

Gui, Add, ListView, r10 w400 gMyListView, domain|URL|notes

Loop, parse, text, `r`n
{
	If (A_LoopField = "")
		continue
	If !InStr(A_LoopField, "://")
		continue
	If (SubStr(A_LoopField, 1, 2) = "- ")
	{
		domain := "- " . StrSplit(A_LoopField," ").2
		URL := StrSplit(A_LoopField," ").3
	}
	else
	{
		domain := StrSplit(A_LoopField," ").1
		URL := StrSplit(A_LoopField," ").2
	}
	If InStr(A_LoopField, "(")
	{
		note := "(" . StrSplit(A_LoopField,"(").2
		LV_Add("", domain, URL, note)
	}
	else
		LV_Add("", domain, URL)
}
LV_ModifyCol()  ; auto-size each column to fit its contents.
Gui, Add, Button, Default, Send
Gui, Show,, Send domain+URL  %key%
return

MyListView:
	If (A_GuiEvent = "DoubleClick")
	{
		LV_GetText(domain, A_EventInfo, 1)
		If SubStr(domain, 1, 2) = "- "
			domain := SubStr(domain, 3)
		else
			domain := domain
		LV_GetText(URL, A_EventInfo, 2)
		; MsgBox, domain = "%domain%"`nURL = "%URL%"
		WinActivate, %WinTitle%
		WinWaitActive, %WinTitle%
		SendInput, %domain%%A_Tab%%URL%
	}
return

; https://autohotkey.com/docs/commands/ListView.htm#LV_GetNext
ButtonSend:
	RowNumber  = 0
	Loop
	{
		RowNumber  := LV_GetNext(RowNumber)  
		If (!RowNumber )
			Break
		LV_GetText(domain, RowNumber, 1)
		If SubStr(domain, 1, 2) = "- "
			domain := SubStr(domain, 3)
		else
			domain := domain
		LV_GetText(URL, RowNumber, 2)
		; MsgBox, domain = "%domain%"`nURL = "%URL%"
		WinActivate, %WinTitle%
		WinWaitActive, %WinTitle%
		SendInput, %domain%%A_Tab%%URL%
	}
Return

Esc::
GuiClose:
ExitApp
Last edited by GEV on 22 Jul 2018, 17:03, edited 1 time in total.
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 16:31

Thank you so much :)

But is giving me an error when I run it:
Script lines most recently executed (oldest first). Press [F5] to refresh. The seconds elapsed between a line and the one after it is in parentheses to the right (if not 0). The bottommost line's elapsed time is the number of seconds since it executed.

---- C:\Users\bestl\Desktop\test.ahk
001: WinTitle := "Edit Model ‹ Agency — WordPress - Google Chrome:"
003: Hotkey,!+#,Create_LV_Key,On
004: Loop,26
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
005: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
006: Return (5.22)

Press [F5] to refresh.
Any idea how to solve it? :)

Thanks!!

P.S. Is the Alt+Shift works for numbers too?
Last edited by Divvy on 22 Jul 2018, 17:14, edited 1 time in total.
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 17:05

Try my last edided answer.
Divvy
Posts: 25
Joined: 20 Jul 2018, 03:18

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 17:14

Same error, but this time have more error lines:
Script lines most recently executed (oldest first). Press [F5] to refresh. The seconds elapsed between a line and the one after it is in parentheses to the right (if not 0). The bottommost line's elapsed time is the number of seconds since it executed.

---- C:\Users\bestl\Desktop\test.ahk
003: SetWorkingDir,%A_ScriptDir%
005: WinTitle := "Edit Model ‹ Agency — WordPress - Google Chrome:"
007: Keys := ["#","1","2","3","4","5","6","7","8","9","0"]
008: For each,key in Keys
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On (0.03)
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
009: Hotkey,!+%key%,Create_LV_Key,On
011: Loop,26
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
012: Hotkey,"!+" Chr(A_Index + 64),Create_LV_Key,On
013: Return (2.28)

Press [F5] to refresh.
GEV
Posts: 689
Joined: 25 Feb 2014, 00:50

Re: Is is possible to use auto copy/paste?

22 Jul 2018, 17:35

On my system it°s working:
Win10 Build 17134.167 EN 64Bit
AutoHotkey_1.1.29.01 64Bit

Maybe someone else knows of a better way.

Return to “Ask For Help”

Who is online

Users browsing this forum: andremarasca, Bing [Bot], Google [Bot], Scr1pter and 27 guests