RunWait for multiple programs

[azhata]

Hello,

I want to Loop through a folder containing shortcuts (*.lnk files) and then run each program (shortcut).
After all the launched programs have been closed, the user running the script should be logged off.

I figured I'd use RunWait for this, but then each program will only run after the program from the previous loop iteration has exited (obviously).

Is there a way to have RunWait start multiple programs at once, or a more suitable alternative for what I'm trying to do?

Here's my code:

Code: Select all

Loop, C:\Path\to\Shortcuts\*.lnk {
	RunWait, "%A_LoopFileLongPath%"
}

; logoff
Run, shutdown.exe /l /f, , Hide

; hotkeys
^!f::Send Foo
^!b::Send Bar

Any help would be much appreciated!

[jmeneses]

Hello azhata, welcome to the forum
Try to save the ID's and wait while there is one running, for example:

Code: Select all

pIDs := []
Loop % "C:\Temp\to\Shortcuts\*.lnk" {
	Run, % A_LoopFileLongPath , ,,ID
	pIDs.Push(ID)
}
While (pIDs.MaxIndex())
 For Index, pID in pIDs  {
     Process , Exist, % pID
 	   If (!ErrorLevel) {
 		     pIDs.RemoveAt(Index)
     }
 }
MsgBox 0x40000,, % "DONE!!"
; put your code here

[garry]

@jmeneses , thank you for the script

[azhata]

Hello jmeneses, thanks for the welcome and for the script you provided!

Correct me if I'm wrong, but I think your solution will introduce a slight performance penalty (I'm seeing quite a bit of CPU utilization for the script process).
I suppose adding a Sleep inside the While loop could mitigate this, but that doesn't seem very clean.

Is there maybe a more efficient way of doing this?

Thanks!

[jmeneses]

Hello jmeneses, thanks for the welcome and for the script you provided!

Correct me if I'm wrong, but I think your solution will introduce a slight performance penalty (I'm seeing quite a bit of CPU utilization for the script process).
I suppose adding a Sleep inside the While loop could mitigate this, but that doesn't seem very clean.

Is there maybe a more efficient way of doing this?

Thanks!

Yes, yes,of course, you're right, better to put a SLEEP according to your CPU processor

[jmeneses]

Is there maybe a more efficient way of doing this?
Thanks!

I can not think of another way, but surely if there is some way more elegant

[azhata]

Anyone else?

[A_AhkUser]

Is there maybe a more efficient way of doing this?

The code will be all the more efficient if the amount of time to sleep is appropriately chosen depending on your situation. The most efficient way is maybe to register a hook but would be at least overkill. Alternatively, you can use Process, WaitClose:

Code: Select all

a := []
Loop, parse, % "notepad,mspaint", CSV
{
	Run, % A_LoopField,,, PID
	a.push(PID)
}
while (PID:=a.pop())
    Process, WaitClose, % PID
; put your code here

Btw, use a timer to prevent runwait from postponing a loop iteration:

Code: Select all

#Persistent

Loop, parse, % "notepad,mspaint", CSV
{
	f := Func("RunWaitCloseAll").bind(A_LoopField)
	SetTimer % f, -1
}
return

RunWaitCloseAll(_target) {
static _n := 0
_n++
RunWait % _target
if not (--_n)
	MsgBox
}

[jeeswg]

You could create a window group, and repeatedly use WinGet's Count subcommand.
GroupAdd - Syntax & Usage | AutoHotkey
https://autohotkey.com/docs/commands/GroupAdd.htm
WinGet - Syntax & Usage | AutoHotkey
https://autohotkey.com/docs/commands/WinGet.htm