Default Printer Viewer/Changer -- Feedback welcome

[kunkel321]

A simple tool I made from combining different commands that I found here on the forums.

Last version before adding context menu:

Spoiler

6-17-2023 updated with button to open Control Panel (see below posts).
6-18-2023 Esc now closes GUI, but keeps app in RAM.
6-18-2023 Added fourth button, for Print Queue. Opens print queue of selected item.

Code: Select all

#SingleInstance, Force
;===================
; https://www.autohotkey.com/boards/viewtopic.php?f=6&t=118596&p=526363#p526363
; For AHK v1
; A tool to allow user to check and/or change default printer.

!^+p::
menu, tray, icon, shell32.dll,107

guiColor =
fontColor =

; ===== Get default printer name. ======
RegRead, defaultPrinter, HKCU, Software\Microsoft\Windows NT\CurrentVersion\Windows, Device

; ==== Get list of installed printers ======
printerlist =
loop,HKCU,Software\Microsoft\Windows NT\CurrentVersion\devices
	printerlist = %printerlist%%A_loopRegName%`n
printerlist := SubStr(printerlist, 1, strlen(printerlist)-2)

;  ==== Put names in GUI ====
Gui, df:Destroy
Gui, df:color, %guiColor%
Gui, df:font, s12 bold c%FontColor%
Gui, df:Add, Text,, Set A Default Printer ...
Gui, df:font, s11 normal
Loop, parse, printerlist, `n
	If instr(defaultPrinter, A_LoopField)
		Gui, df:Add, Radio, checked vRadio%a_index%, %a_loopfield%
    Else
		Gui, df:Add, Radio, vRadio%a_index%, %a_loopfield%
Gui, df:Add, Button, default  gSet, Set Printer
Gui, df:Add, Button,  x+10 gQue, Print Queue
Gui, df:Add, Button,  x+10 gPanel, Control Panel
Gui, df:Add, Button,  x+10 , Cancel
Gui, df:Show, , Default Printer Changer
Return

Set:
	Gui, df:Submit
	Loop, parse, printerlist, `n
		If Radio%a_index% <> 0
			newDefault = %a_loopfield%
	; ==== Set new default printer =====
	RunWait, C:\Windows\System32\RUNDLL32.exe PRINTUI.DLL`, PrintUIEntry /y /n "%newDefault%" ; sets the printer
	Gui, df:Destroy
Return

Que:
	Gui, df:Submit
	Loop, parse, printerlist, `n
		If Radio%a_index% <> 0
			viewThis = %a_loopfield%
	; ==== View print queue for selected =====
	runwait, rundll32 printui.dll`, PrintUIEntry /o /n "%viewThis%"  ;- display printer queue view -User Garry
	;runwait,RUNDLL32 PRINTUI.DLL`,PrintUIEntry /f "%f1%" /Xg /n "%viewThis%"      ;- show printers specification in file F1
	;runwait,rundll32 printui.dll`,PrintUIEntry /?                                 ;- Help
	;runwait,rundll32 printui.dll`,PrintUIEntry /p /n "%viewThis%"                 ;-  printer properties
	Gui, df:Destroy
Return

Panel:
	; run,shell:PrintersFolder   ;- show printers and with rightclick change as default printer -User Garry
	run, control printers       ;- maybe rightclick for problem solution -User Garry
	Gui, df:Destroy
	printerlist =
Return

dfGuiEscape:
dfGuiClose:
dfButtonCancel:
	Gui, df:Destroy
	printerlist =
Return

/*
; Stuff from User: Garry
; https://www.autohotkey.com/boards/viewtopic.php?f=6&t=118596&p=526470#p526470
F1:=a_scriptdir . "\test.txt"
printerA:="SnagIt 2023"
;---------------
runwait,RUNDLL32 PRINTUI.DLL`,PrintUIEntry /f "%f1%" /Xg /n "%printerA%"      ;- show printers specification in file F1
runwait,rundll32 printui.dll`,PrintUIEntry /?                                 ;- Help
runwait,rundll32 printui.dll`,PrintUIEntry /o /n "%printerA%"                 ;- display printer queue view
runwait,rundll32 printui.dll`,PrintUIEntry /p /n "%printerA%"                 ;-  printer properties
try,
  run,%f1%    ;- show printers specification
run,shell:PrintersFolder
run,control printers
return
*/

6-19-2023 Version with right-click-on-item context menu

Spoiler

This version adds a context menu. The Switches variable has items pasted from the help window (see "Help this message" menu item). I removed all the ones that looked dangerous to me (delete this, disconnect that). Other people can add items back to the list if desired. Some commands won't work though, because the switch looks for a file name. I left the "View Print Queue" button on the bottom of the GUI. It is redundant now, but I like the button, because I check my print queue often.

Code: Select all

#SingleInstance, Force
;===================
; https://www.autohotkey.com/boards/viewtopic.php?f=6&t=118596&p=526363#p526363
; For AHK v1 ; By Kunkel321 with help from Garry.
; A tool to allow user to check and/or change default printer.

;!^+p::
menu, tray, icon, shell32.dll,107

guiColor =
fontColor =

Switches =
(
/e display printing preferences
/ge enum per machine printer connections
/k print test page to specified printer
/o display printer queue view
/p display printer properties
/s display server properties
/y set printer as the default
/Xg get printer settings
/? help this message
)


; ===== Get default printer name. ======
RegRead, defaultPrinter, HKCU, Software\Microsoft\Windows NT\CurrentVersion\Windows, Device

; ==== Get list of installed printers ======
printerlist =
loop,HKCU,Software\Microsoft\Windows NT\CurrentVersion\devices
	printerlist = %printerlist%%A_loopRegName%`n
printerlist := SubStr(printerlist, 1, strlen(printerlist)-2)
;StringSplit, printerlist, printerlist, `n ; Determines number of lines

;  ==== Put names in GUI ====
Gui, df:Destroy
Gui, df:color, %guiColor%
Gui, df:font, s12 bold c%FontColor%

; ---- put switches in menu ----
Loop, parse, Switches, `n
	Menu,df: Menu1, Add, %A_LoopField%, Label%A_Index%

Gui, df:Add, Text,, Set A Default Printer ...
Gui, df:font, s10 normal
Gui, df:Add, Text,y+-3, [Right-click printer name for more commands]
Gui, df:font, s11 normal
Loop, parse, printerlist, `n
	If instr(defaultPrinter, A_LoopField)
		Gui, df:Add, Radio, checked vRadio%a_index%, %a_loopfield%
    Else
		Gui, df:Add, Radio, vRadio%a_index%, %a_loopfield%
Gui, df:Add, Button, default  gSet, Set Printer
Gui, df:Add, Button,  x+10 gQue, Print Queue
Gui, df:Add, Button,  x+10 gPanel, Control Panel
Gui, df:Add, Button,  x+10 , Cancel
Gui, df:Show, , Default Printer Changer
Return

Label1:
Label2:
Label3:
Label4:
Label5:
Label6:
Label7:
Label8:
Label9:
Label10:
Label11:
Label12:
Label13:
Label14:
Label15:
Label16:
Label17:
Label18: ; If you have more than 18 'Switches' lines, above, add more labels.
MenuItem := StrReplace(A_ThisLabel, "Label", "")
StringSplit, Switches, Switches, `n
ThisSwitch := Switches%MenuItem%
StringSplit, ThisSwitch, ThisSwitch, " "
ThisSwitch := ThisSwitch1
return

dfGuiContextMenu:
If (A_GuiControl) {
	menu,df: Menu1, Show
	MouseGetPos,,,,Control1
	Loop, parse, printerlist, `n
		If (A_GuiControl = "Radio" A_Index) && (ThisSwitch <> "") {
			runwait, rundll32 printui.dll`, PrintUIEntry "%ThisSwitch%" /n "%A_LoopField%" ; Not sure why the /n has to be there....
			ThisSwitch =
		}
}
return

Set:
	Gui, df:Submit
	Loop, parse, printerlist, `n
		If Radio%a_index% <> 0
			newDefault = %a_loopfield%
	; ==== Set new default printer =====
	RunWait, C:\Windows\System32\RUNDLL32.exe PRINTUI.DLL`, PrintUIEntry /y /n "%newDefault%" ; sets the printer
	Gui, df:Destroy
Return

Que:
	Gui, df:Submit
	Loop, parse, printerlist, `n
		If Radio%a_index% <> 0
			viewThis = %a_loopfield%
	; ==== View print queue for selected =====
	runwait, rundll32 printui.dll`, PrintUIEntry /o /n "%viewThis%"  ;- display printer queue view -User Garry
	Gui, df:Destroy
Return

Panel:
	; run,shell:PrintersFolder   ;- show printers and with rightclick change as default printer -User Garry
	run, control printers       ;- maybe rightclick for problem solution -User Garry
	Gui, df:Destroy
	printerlist =
Return

dfGuiEscape:
dfGuiClose:
dfButtonCancel:
	Gui, df:Destroy
	printerlist =
Return

/*
; Stuff from User: Garry
; https://www.autohotkey.com/boards/viewtopic.php?f=6&t=118596&p=526470#p526470
F1:=a_scriptdir . "\test.txt"
printerA:="SnagIt 2023"
;---------------
runwait,RUNDLL32 PRINTUI.DLL`,PrintUIEntry /f "%f1%" /Xg /n "%printerA%"      ;- show printers specification in file F1
runwait,rundll32 printui.dll`,PrintUIEntry /?                                 ;- Help
runwait,rundll32 printui.dll`,PrintUIEntry /o /n "%printerA%"                 ;- display printer queue view
runwait,rundll32 printui.dll`,PrintUIEntry /p /n "%printerA%"                 ;-  printer properties
try,
  run,%f1%    ;- show printers specification
run,shell:PrintersFolder
run,control printers
return
*/

/=====================
5-14-2024 Update: A version for AHKv2 is here:
viewtopic.php?f=83&p=571743#p571743

[garry]

works fine , just added these commands after buttonset to see what happened :

Code: Select all

run,shell:PrintersFolder   ;- show printers and with rightclick change as default printer
run,control printers       ;- maybe rightclick for problem solution

EDIT : some other commands :

Code: Select all

F1:=a_scriptdir . "\test.txt"
printerA:="Pantum M6600NW Series"
;---------------
runwait,RUNDLL32 PRINTUI.DLL`,PrintUIEntry /f "%f1%" /Xg /n "%printerA%"      ;- show printers specification in file F1
runwait,rundll32 printui.dll`,PrintUIEntry /?                                 ;- Help
runwait,rundll32 printui.dll`,PrintUIEntry /o /n "%printerA%"                 ;- display printer queue view
runwait,rundll32 printui.dll`,PrintUIEntry /p /n "%printerA%"                 ;-  printer properties
try,
  run,%f1%    ;- show printers specification
;run,shell:PrintersFolder 
;run,control printers  
return

[kunkel321]

Yeah, accessing the already-existing system tools probably makes more sense.
But it's not as much fun.

Code: Select all

run,control printers       ;- maybe rightclick for problem solution

This gets its own button. LOL.

[garry]

@kunkel321 your script is optimal, easy see or set the default printer . Button 'control panel' is fine , maybe solve printer problems or other things with rightclick .

[kunkel321]

@kunkel321 your script is optimal, easy see or set the default printer . Button 'control panel' is fine , maybe solve printer problems or other things with rightclick .

Do you mean a popup menu upon right-clicking the radio items? I hand't thought of that. I'll see if I can figure out how to do it.

[garry]

sorry , nothing to change in your script . You have already the button > run,control printers , which I often used if I have a problem with the printer .

[kunkel321]

I see what you mean. Yes, just using the Control Panel for that probably makes more sense. Especially for troubleshooting. If you need to troubleshoot a printer, you'd likely go to the CP anyway... Though a fourth button to "open print que" might be nice...

On a related note: It doesn't appear that you can detect right-clicks on a radio item anyway... The docs for A_GuiControl indicate:

RightClick: Occurs only for GuiContextMenu, ListViews, and TreeViews.

EDIT: Upon experimentation... It looks like you can use an if GetKeyState("RButton") in the gLabel Label. That still doesn't detect a right-click though.... It only detects if the right button is being held down when you left click a radio item.

[garry]

example , rightclick on button ( if you don't want too many buttons ) or a GUI-menu
viewtopic.php?p=321750#p321750

[kunkel321]

Very cool. Thanks for all the info Garry!

Your right-click-on-button solution is very clever. It's always fun to see the different ways to solve different things. Alas, I think the technique might not be compatible with radio buttons... It requires that each command (button) have a unique vName and gName. With radio buttons though, the group members all share a vName.
Actually, the previous statement can't be accurate... I have experimented with a simple set of radio buttons and it only worked with a single variable. The above code makes multiple variables with vRadio%A_Index% though... [new edit at bottom of this post]


I suppose the above tool could be remade with dynamically-created buttons, rather than radio items.
I think I like the idea of a fourth button at the bottom, for "Show print queue," though. I'll use your above command line printer code for that.

EDIT: Wow... There certainly is a lot of information available via the /? one you posted....

Spoiler

Code: Select all

Usage: rundll32 printui.dll,PrintUIEntry [options] [@commandfile]
   /a[file] binary file name
   /b[name] base printer name
   /c[name] unc machine name if the action is on a remote machine
   /dl delete local printer
   /dn delete network printer connection
   /dd delete printer driver
   /e display printing preferences
   /f[file] either inf file or output file
   /F[file] location of an INF file that the INF file specified with /f may depend on
   /ga add per machine printer connections (the connection will be propagated to the user upon logon)
   /ge enum per machine printer connections
   /gd delete per machine printer connections (the connection will be deleted upon user logon)
   /h[arch] driver architecture one of the following, x86, x64 or Itanium
   /ia install printer driver using inf file
   /id install printer driver using add printer driver wizard
   /if install printer using inf file
   /ii install printer using add printer wizard with an inf file
   /il install printer using add printer wizard
   /im install printer using add printer wizard skiping network listed printers
   /in add network printer connection
   /ip install printer using network printer installation wizard
   /j[provider] print provider name
   /k print test page to specified printer, cannot be combined with command when installing a printer
   /l[path] printer driver source path
   /m[model] printer driver model name
   /n[name] printer name
   /o display printer queue view
   /p display printer properties
   /q quiet mode, do not display error messages
   /r[port] port name
   /s display server properties
   /Ss Store printer settings into a file
   /Sr Restore printer settings from a file
   Store or restore printer settings option flags that must be placed at the end of command:
	2	PRINTER_INFO_2
	7	PRINTER_INFO_7
	c	Color Profile
	d	PrinterData
	s	Security descriptor
	g	Global DevMode
	m	Minimal settings
	u	User DevMode
	r	Resolve name conflicts
	f	Force name
	p	Resolve port
	i	Driver name conflict
   /u use the existing printer driver if it's already installed
   /t[#] zero based index page to start on
   /v[version] driver version one of the following, "Type 2 - Kernel Mode" or "Type 3 - User Mode"
   /w prompt the user for a driver if specified driver is not found in the inf
   /y set printer as the default
   /Xg get printer settings
   /Xs set printer settings
   /z do not auto share this printer
   /Y do not auto generate a printer name
   /K changes the meaning of /h to accept 2, 3, 4 for x86, x64, or Itanium (respectively), and /v to accept 3 for "Type 3 - User Mode"
   /Z share this printer, can only be used with the /if option
   /? help this message
   @[file] command line argument file
   /Mw[message] show a warning message before committing the command
   /Mq[message] show a confirmation message before committing the command
   /W[flags] specifies flags and switches for the wizards (for APW & APDW)
	r	make the wizards to be restart-able from the last page
   /G[flags] specifies global flags and switches
	w	suppress setup driver warnings UI (super quiet mode)
   /R force selected driver to replace exisiting driver

Examples:
   Run server properties: 
rundll32 printui.dll,PrintUIEntry /s /t1 /c\\machine
   Run printer properties: 
rundll32 printui.dll,PrintUIEntry /p /n\\machine\printer
   Run add printer wizard locally: 
rundll32 printui.dll,PrintUIEntry /il 
   Run add printer wizard on \\machine: 
rundll32 printui.dll,PrintUIEntry /im /c\\machine
   Run queue view: 
rundll32 printui.dll,PrintUIEntry /o /n\\machine\printer
   Run inf install: 
rundll32 printui.dll,PrintUIEntry /if /b "Test Printer" /f c:\infpath\infFile.inf /r "lpt1:" /m "Brother DCP-128C"
   Run inf install (with inf dependency). In the example, prnbr002.inf depends on ntprint.inf
rundll32 printui.dll, PrintUIEntry /ia /m "Brother DCP-128C" /K /h x64 /v 3 /f "c:\infpath\prnbr002.inf" /F "c:\infpath\ntprint.inf"
   Run add printer wizard using inf: 
rundll32 printui.dll,PrintUIEntry /ii /f c:\infpath\infFile.inf
   Add printer using inbox printer driver: 
rundll32 printui.dll,PrintUIEntry /if /b "Test Printer" /r "lpt1:" /m "Brother DCP-128C"
   Add per machine printer connection (the connection will be propagated to the user upon logon): 
rundll32 printui.dll,PrintUIEntry /ga /c\\machine /n\\machine\printer /j"LanMan Print Services"
   Delete per machine printer connection (the connection will be deleted upon user logon): 
rundll32 printui.dll,PrintUIEntry /gd /c\\machine /n\\machine\printer
   Enumerate per machine printer connections: 
rundll32 printui.dll,PrintUIEntry /ge /c\\machine
   Add printer driver using inf: 
rundll32 printui.dll,PrintUIEntry /ia /c\\machine /m "Brother DCP-128C" /h "x86" /v "Type 3 - User Mode" /f c:\infpath\infFile.inf
   Add printer driver using inf: 
rundll32 printui.dll,PrintUIEntry /ia /K /c\\machine /m "Brother DCP-128C" /h "x86" /v 3
   Add inbox printer driver: 
rundll32 printui.dll,PrintUIEntry /ia /c\\machine /m "Brother DCP-128C" /h "Intel" /v "Type 3 - Kernel Mode"
   Remove printer driver: 
rundll32 printui.dll,PrintUIEntry /dd /c\\machine /m "Brother DCP-128C" /h "x86" /v "Type 3 - User Mode"
   Remove printer driver: 
rundll32 printui.dll,PrintUIEntry /dd /K /c\\machine /m "Brother DCP-128C" /h "x86" /v 3
   Set printer as default: 
rundll32 printui.dll,PrintUIEntry /y /n "printer"
   Set printer comment: 
rundll32 printui.dll,PrintUIEntry /Xs /n "printer" comment "My Cool Printer"
   Get printer settings: 
rundll32 printui.dll,PrintUIEntry /Xg /n "printer"
   Get printer settings saving results in a file: 
rundll32 printui.dll,PrintUIEntry /f "results.txt" /Xg /n "printer"
   Set printer settings command usage:
rundll32 printui.dll,PrintUIEntry /Xs /n "printer" ?
   Store all printer settings into a file: 
rundll32 printui.dll,PrintUIEntry /Ss /n "printer" /a "file.dat"
   Restore all printer settings from a file: 
rundll32 printui.dll,PrintUIEntry /Sr /n "printer" /a "file.dat"
   Store printer information on level 2 into a file : 
rundll32 printui.dll,PrintUIEntry /Ss /n "printer" /a "file.dat" 2
   Restore  from a file printer security descriptor: 
rundll32 printui.dll,PrintUIEntry /Sr /n "printer" /a "file.dat" s
   Restore  from a file printer global devmode and printer data: 
rundll32 printui.dll,PrintUIEntry /Sr /n "printer" /a "file.dat" g d
   Restore  from a file minimum settings and resolve port name: 
rundll32 printui.dll,PrintUIEntry /Sr /n "printer" /a "file.dat" m p
   Enable Client Side Rendering for a printer: 
rundll32 printui.dll,PrintUIEntry /Xs /n "printer" ClientSideRender enabled
   Disable Client Side Rendering for a printer: 
rundll32 printui.dll,PrintUIEntry /Xs /n "printer" ClientSideRender disabled

Just got an idea.... Rather than a "print queue" button, we can have a drop list that offers all of the above command line entries... The user selects one, then presses a button to do whatever command is selected. EDIT: Meh... Actually most of the commands are administrative things that I would never want to do.

EDIT 6-19-2023 It took a while to the the syntax right, but it turned out that I didn't even need to change the existing code to add r-click functionality... I just needed to add this subroutine:

Code: Select all

dfGuiContextMenu:
MouseGetPos,,,,Control1
Loop, parse, printerlist, `n
{
	If (A_GuiControl = "Radio" A_Index) {
		MsgBox % A_LoopField
	}
}
return

EDIT 6-19-2023: New version of code in first post.

[kunkel321]

A version of this printer tool, for AHKv2, is here:
viewtopic.php?f=83&p=571743#p571743