Seconds to String

[jNizM]

Seconds to String

This function will return the duration of the given time period in days, hours, minutes and seconds.
e.g. secsToStr(1234567) would return "14 days, 6 hours, 56 minutes, 7 seconds"

Code: Select all

secsToStr(s)
{
    if (s >= 86400)
    {
        d := floor(s / 86400), s := mod(s, 86400)
        r := d " day" ((d <> 1) ? "s" : "") ((s > 0) ? ", " : "")
    }
    if (s >= 3600)
    {
        h := floor(s / 3600), s := mod(s, 3600)
        r .= h " hour" ((h <> 1) ? "s" : "") ((s > 0) ? ", " : "")
    }
    if (s >= 60)
    {
        m := floor(s / 60), s := mod(s, 60)
        r .= m " minute" ((m <> 1) ? "s" : "") ((s > 0) ? ", " : "")
    }
    r .= s " second" ((s <> 1) ? "s" : "")

    return, % r
}

MsgBox, % secsToStr(1234567)

[tmplinshi]

Just another method. (Slower than yours.)

Code: Select all

FormatSecondsToStr(s)
{
	static Unit := ["day", "hour", "minute", "second"]

	time := 19990101
	time += %s%, seconds
	FormatTime, ms, %time%, m#s
	d_h_m_s := s//3600//24 "#" Mod(s//3600, 24) "#" ms

	for i, v in StrSplit(d_h_m_s, "#")
		str .= v ? ( v " " Unit[i] (v>1 ? "s, " : ", ") ) : ""

	Return RTrim(str, ", ")
}

[Guest10]

very "classy" with no classes!

[jNizM]

update:
- shorter code

[joedf]

very "classy" with no classes!

Haha yeah...

[jballi]

Beans of the cool variety.

[Guest10]

this pil·fered from the old forum ... however, why i always get today's date?

Code: Select all

msgbox % DateParse(Dec-31-13)

; http://www.autohotkey.com/board/topic/18760-date-parser-convert-any-date-format-to-yyyymmddhh24miss/page-5
DateParse(str, americanOrder=1) {
	static monthNames := "(?:Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec)\w*"
		, dayAndMonth := "(?:(\d{1,2}|" . monthNames . ")[\s\.\-\/,]+)?(\d{1,2}|" . monthNames . ")"
	If RegExMatch(str, "i)^\s*(?:(\d{4})([\s\-:\/])(\d{1,2})\2(\d{1,2}))?"
		. "(?:\s*[T\s](\d{1,2})([\s\-:\/])(\d{1,2})(?:\6(\d{1,2})\s*(?:(Z)|(\+|\-)?"
		. "(\d{1,2})\6(\d{1,2})(?:\6(\d{1,2}))?)?)?)?\s*$", i) ;ISO 8601 timestamps
		year := i1, month := i3, day := i4, t1 := i5, t2 := i7, t3 := i8
	Else If !RegExMatch(str, "^\W*(\d{1,2}+)(\d{2})\W*$", t){
		RegExMatch(str, "i)(\d{1,2})"					;hours
				. "\s*:\s*(\d{1,2})"				;minutes
				. "(?:\s*:\s*(\d{1,2}))?"			;seconds
				. "(?:\s*([ap]m))?", t)				;am/pm
		StringReplace, str, str, %t%
		If Regexmatch(str, "i)(\d{4})[\s\.\-\/,]+" . dayAndMonth, d) ;2004/22/03
			year := d1, month := d3, day := d2
		Else If Regexmatch(str, "i)" . dayAndMonth . "[\s\.\-\/,]+(\d{2,4})", d)  ;22/03/2004 or 22/03/04
			year := d3, month := d2, day := d1
		If (RegExMatch(day, monthNames) or americanOrder and !RegExMatch(month, monthNames)) ;try to infer 

day/month order
			tmp := month, month := day, day := tmp
	}
	f = %A_FormatFloat%
	SetFormat, Float, 02.0
	d := (StrLen(year) == 2 ? "20" . year : (year ? year : A_YYYY))
		. ((month := month + 0 ? month : InStr(monthNames, SubStr(month, 1, 3)) // 4 ) > 0 ? month + 0.0 : A_MM)
		. ((day += 0.0) ? day : A_DD) 
		. t1 + (t1 == 12 ? t4 = "am" ? -12.0 : 0.0 : t4 = "pm" ? 12.0 : 0.0)
		. t2 + 0.0 . t3 + 0.0
	SetFormat, Float, %f%
	return, d
}

[smorgasbord]

i am getting bored.
can it be done in 1 line?

[Coco]

@Guest10
msgbox % DateParse("Dec-31-13") surround with quotes

[AlphaBravo]

i am getting bored.
can it be done in 1 line?

Code: Select all

secsToStr(s){
	return (s>86400?(s//86400) " Days, ":"")(s>3600?(s:=mod(s,86400))//3600 " Hours, ":"")(s>60?(s:=mod(s,3600))//60 " Minutes, ":"") mod(s,60) " Seconds"
}

[smorgasbord]

i am getting bored.
can it be done in 1 line?

Code: Select all

secsToStr(s){
	return (s>86400?(s//86400) " Days, ":"")(s>3600?(s:=mod(s,86400))//3600 " Hours, ":"")(s>60?(s:=mod(s,3600))//60 " Minutes, ":"") mod(s,60) " Seconds"
}

[Guest10]

@Guest10
msgbox % DateParse("Dec-31-13") surround with quotes

thanks, tested and it was a hit!

[Guest10]

i am getting bored.
can it be done in 1 line?

Code: Select all

secsToStr(s){
	return (s>86400?(s//86400) " Days, ":"")(s>3600?(s:=mod(s,86400))//3600 " Hours, ":"")(s>60?(s:=mod(s,3600))//60 " Minutes, ":"") mod(s,60) " Seconds"
}

i'm sure this will be a hit! any examples to test?

[garry]

example, AlphaBravo, works fine , maybe days missing ( if exact or below 1 day )

Code: Select all

s:=86462    ;- ok = 1 days 0 hours 1 minutes 2 seconds
;s:=86400   ;- should be 1 day , missing message 1 day
;s:=86399   ;- ok maybe add 0 days
aaa:= % secsToStr(s)
msgbox,%aaa%
return

secsToStr(s){
    return (s>86400?(s//86400) " Days, ":"")(s>3600?(s:=mod(s,86400))//3600 " Hours, ":"")(s>60?(s:=mod(s,3600))//60 " Minutes, ":"") mod(s,60) " Seconds"
}

[AlphaBravo]

@garry, thanks for the examples, this should be easy to modify to show "0 days" if desired

Code: Select all

list =
(comment
86462	;- ok = 1 days 0 hours 1 minutes 2 seconds
86400	;- should be 1 day , missing message 1 day
86399	;- ok maybe add 0 days
)

loop, parse, list, `n
	res .= secsToStr(A_LoopField) "`n"
MsgBox % res
return

secsToStr(s){
    return (s>=86400?(s//86400)" Days, ":"")(s>=3600?(s:=mod(s,86400))//3600 :0)" Hours, "(s>=60?(s:=mod(s,3600))//60 : 0)" Minutes, "mod(s,60) " Seconds"
}

Edit: I merely shrunk the original post, credit goes to jNizM

[garry]

thank you AlphaBravo , jNizM , tmplinshi , Guest10 ... for help and scripts , works fine

[Guest10]

could you post a COMPREHENSIVE script of this kind that converts any date format in the following LIST to 2 string types: (1) YYYYMMDD and (2) YYYYMMDDhhmmss

YYMMDD
YYYYYMMDD
YY/MM/DD
YYYYY/MM/DD
MMDDYY
MMDDYYYYY
MM/DD/YY
MM/DD/YYYY
DDMMYY
DDMMYYYYY
DD/MM/YY
DD/MM/YYYY

[atnbueno]

Guest10, there are too many ambiguities if you want to autodetect the format. For example "101214" could be either DDMMYY, MMDDYY, or YYMMDD.

Or did you mean something else?

[joedf]

@AlphaBravo Nice there! But I know that it can be even shorter, and you can do it...

[Guest10]

Guest10, there are too many ambiguities if you want to autodetect the format. For example "101214" could be either DDMMYY, MMDDYY, or YYMMDD.

Or did you mean something else?

doh!!! thanks for mentioning the conflict. i have the following in my archives:

Code: Select all

; http://www.autohotkey.com/board/topic/18760-date-parser-convert-any-date-format-to-yyyymmddhh24miss/

; Date Parser: Converts any date format to YYYYMMDDHH24MISS

/*
	Function: DateParse
		Converts almost any date format to a YYYYMMDDHH24MISS value.

	Parameters:
		str - a date/time stamp as a string

	Returns:
		A valid YYYYMMDDHH24MISS value which can be used by FormatTime, EnvAdd and other time commands.

	Example:
		time := DateParse("2:35 PM, 27 November, 2007")

	License:
		- Version 1.05 <http://www.autohotkey.net/~polyethene/#dateparse>
		- Dedicated to the public domain (CC0 1.0) <http://creativecommons.org/publicdomain/zero/1.0/>
*/

; Function:

DateParse(str) {
	static e2 = "i)(?:(\d{1,2}+)[\s\.\-\/,]+)?(\d{1,2}|(?:Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec)\w*)[\s\.\-\/,]+(\d{2,4})"
	str := RegExReplace(str, "((?:" . SubStr(e2, 42, 47) . ")\w*)(\s*)(\d{1,2})\b", "$3$2$1", "", 1)
	If RegExMatch(str, "i)^\s*(?:(\d{4})([\s\-:\/])(\d{1,2})\2(\d{1,2}))?"
		. "(?:\s*[T\s](\d{1,2})([\s\-:\/])(\d{1,2})(?:\6(\d{1,2})\s*(?:(Z)|(\+|\-)?"
		. "(\d{1,2})\6(\d{1,2})(?:\6(\d{1,2}))?)?)?)?\s*$", i)
		d3 := i1, d2 := i3, d1 := i4, t1 := i5, t2 := i7, t3 := i8
	Else If !RegExMatch(str, "^\W*(\d{1,2}+)(\d{2})\W*$", t)
		RegExMatch(str, "i)(\d{1,2})\s*:\s*(\d{1,2})(?:\s*(\d{1,2}))?(?:\s*([ap]m))?", t)
			, RegExMatch(str, e2, d)
	f = %A_FormatFloat%
	SetFormat, Float, 02.0
	d := (d3 ? (StrLen(d3) = 2 ? 20 : "") . d3 : A_YYYY)
		. ((d2 := d2 + 0 ? d2 : (InStr(e2, SubStr(d2, 1, 3)) - 40) // 4 + 1.0) > 0
			? d2 + 0.0 : A_MM) . ((d1 += 0.0) ? d1 : A_DD) . t1
			+ (t1 = 12 ? t4 = "am" ? -12.0 : 0.0 : t4 = "am" ? 0.0 : 12.0) . t2 + 0.0 . t3 + 0.0
	SetFormat, Float, %f%
	Return, d
}