Validating number in edit field

[shinymonky]

As a rookie, I was quite proud to have figured this out myself. This short code will check the text in the Edit control and make sure it's a number. Any other keypresses are ignored. It works by running a subroutine whenever any change is made to the Edit control text, checking the last character in that string, if it is not one of the accepted charactrs (numbers or decimal point) then a delete is sent. It's not perfect - the user can stil enter non-numerical characters by changing the insertion point with the arrow keys, but it's a start.

Gui, Add, Text,, Number
Gui, Add, Edit, r1 w150 gCheck vNumberentered
Gui, Add, Button, x30 y190 w60 h30 gOkay, Okay
Gui, Add, Button, x100 y190 w60 h30 gCancel, Cancel
Gui, Show,,
Return

Okay:
Gui, Submit, Hide
MsgBox, % Numberentered
Return
Cancel:
Gui, Submit, Hide
Return

Check:
GuiControlGet, var, , vNumberentered
EnsureNumber(var)
Return

EnsureNumber(var)
{
StringLen, L, var
T := "1.234567890"
C := SubStr(var, L, 1)
StringGetPos, I, T, %C%
IfEqual, I, -1
Send, {BS}
Return
}

[guest3456]

you can simply use the Number option when adding the Edit control:
https://autohotkey.com/docs/commands/Gu ... s.htm#Edit

Code: Select all

Gui, Add, Text,, Numbers only
Gui, Add, Edit, r1 w150 Number
Gui, Show,,
Return

[shinymonky]

Number option doesn't allow decimal points.

[boiler]

FYI - Your script doesn't work as posted. You need to remove the "v" from "vNumberentered" in your Check: subroutine, then it works again.

[Helgef]

Good job! There are some problems though, you can add as many decimal points as you like, and if you move the input marker, you can type anything, also, you can paste in stuff.

I wrote this function:

Spoiler

Code: Select all

EnsureNum(var)
{
	containsSpaces:=RegExMatch(var,"[\s]")		; Check if contains spaces
	noNumVar:=RegExReplace(var,"[^0-9.]+")		; Remove all non numerics or .
	ControlGet,inPos, CurrentCol,, Edit1,A		; Get input position of the edit box.
	
	StringSplit,splitNum,noNumVar,.				; Allow only one ".", the leftmost is preserved.
	if (splitNum0>2)							; This can be higher than three if user pastes in something with more than one dot.
	{
		noNumVar:=splitNum1 . "."
		Loop, % splitNum0-1
		{
			ind:=A_Index+1
			noNumVar.=splitNum%ind%	 
		}	
	}
	if (var==noNumVar && !containsSpaces) 		; If nothing changed and no spaces present, return
		return
	GuiControl,,Numberentered,%noNumVar%		; Set text
	PostMessage,0x00B1,inPos-2,inPos-2,Edit1,A 	; Move input caret to correct position, EM_SETSEL:=0x00B1
}

If anyone can "break" it or knows a better/easier method, let me know.

[just me]

Code: Select all

#NoEnv
Gui, Add, Text, , Number
Gui, Add, Edit, r1 w150 gCheck vNumberentered
Gui, Add, Button, x30 y190 w60 h30 gOkay, Okay
Gui, Add, Button, x100 y190 w60 h30 gCancel, Cancel
Gui, Show, , Test
Return

Okay:
Gui, Submit, NoHide
MsgBox, 0, You entered:, % Numberentered
Return

GuiClose:
Cancel:
ExitApp

Check:
GuiControlGet, Var, , Numberentered
If Var Is Not Number
   Send, {BS}
Return

[Helgef]

Code: Select all

Check:
GuiControlGet, Var, , Numberentered
If Var Is Not Number
   Send, {BS}
Return

Perfect, should be marked as solved. Easy to add space block if needed.

[Helgef]

Code: Select all

Check:
GuiControlGet, Var, , Numberentered
If Var Is Not Number
   Send, {BS}
Return

Perfect, should be marked as solved. Easy to add space block if needed.

Edit: There wasn't a request to solve something.