Firefox: shortcuts for Bookmarks window

[freespacing]

Just threw this together to get rid of a persistent gripe: no shortcuts in the bookmarks window.
Ctrl + n creates a new folder
Ctrl + b creates a new bookmark

Some dupe code, no effort made at refactoring.

Code: Select all

; -------------- Hotkeys for Firefox -----------------
#IfWinActive ahk_exe firefox.exe 

; Shortcuts for Bookmarks window
^n:: ; New Folder
MouseGetPos,,,id,NN
ControlGetText, Text, %NN%, ahk_id %id%
if(Text != "Library") {   ; The title of the bookmark window is 'Library'
  Send ^n
  return
} 
; Tooltip Text=%Text%
Send !o
sleep 50
Send o
return

^b:: ; New Bookmark
MouseGetPos,,,id,NN
ControlGetText, Text, %NN%, ahk_id %id%
if(Text != "Library") {   ; The title of the bookmark window is 'Library'
  Send ^b
  return
} 
Send !o
sleep 50
Send b
return


#IfWinActive
	
; -------------- End hotkeys for Firefox -----------------

[TheDewd]

Code: Select all

; BEGIN >> HOTKEYS FOR FIREFOX
#IfWinActive Library ahk_class MozillaWindowClass ahk_exe firefox.exe
    ^n:: ; New Folder
        Send, {AppsKey}
        Sleep, 50
        Send, F

        WinWait, New Folder ahk_class MozillaDialogClass ahk_exe firefox.exe,, 3

        If (ErrorLevel) {
            MsgBox, WinWait timed out.
        }
    return

    ^b:: ; New Bookmark
        Send, {AppsKey}
        Sleep, 50
        Send, B

        WinWait, New Bookmark ahk_class MozillaDialogClass ahk_exe firefox.exe,, 3

        If (ErrorLevel) {
            MsgBox, WinWait timed out.
        }
    return
#IfWinActive
; END >> HOTKEYS FOR FIREFOX