aria2 rpc

[tmplinshi]

What is aria2?

aria2 is a lightweight multi-protocol & multi-source command-line download utility. It supports HTTP/HTTPS, FTP, BitTorrent and Metalink. aria2 can be manipulated via built-in JSON-RPC and XML-RPC interfaces.

How the aria2 RPC works?

Spoiler

--------------- First, run aria2c.exe: ---------------

aria2c --enable-rpc --rpc-listen-all -c

It will look like this:


--------------- Start download ---------------

For example, to download http://test.gorillaservers.com/100mb.bin, just post data to "http://127.0.0.1:6800/jsonrpc":

Code: Select all

url := "http://127.0.0.1:6800/jsonrpc"
data := "{""jsonrpc"":""2.0"",""id"":""1"",""method"":""aria2.addUri"",""params"":[[""http://test.gorillaservers.com/100mb.bin""]]}"
httpPost( url, data)
MsgBox, % data ; {"id":"1","jsonrpc":"2.0","result":"73d571fb7a4fc47d"}

httpPost(URL, ByRef In_POST__Out_Data) {
	static nothing := ComObjError(0)
	static oHTTP   := ComObjCreate("WinHttp.WinHttpRequest.5.1")

	oHTTP.Open("POST", URL, True)
	oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
	oHTTP.Send(In_POST__Out_Data)
	oHTTP.WaitForResponse(-1)

	In_POST__Out_Data := oHTTP.ResponseText
}

Screenshot - downloading...

You can continue add more urls to download them at the same time.

--------------- Pause a download ---------------

Code: Select all

url := "http://127.0.0.1:6800/jsonrpc"
data := "{""jsonrpc"":""2.0"",""id"":""1"",""method"":""aria2.pause"",""params"":[""73d571fb7a4fc47d""]}"
httpPost( url, data)

Screenshot - paused

sample.ahk

Code: Select all

; Make sure you have started aria2c with: aria2c --enable-rpc --rpc-listen-all -c

#Include, <aria2>

; =================================
;		addUri
; =================================
; uris is an array of HTTP/FTP/BitTorrent URIs (strings) pointing to the same resource.
obj_uris := ["http://test.gorillaservers.com/100mb.bin"]

; more details about Options: http://aria2.sourceforge.net/manual/en/html/aria2c.html#id3
obj_options := {dir: "c:\test", max-connection-per-server: 5}

ret := aria2.addUri( obj_uris, obj_options )
gid := ret.result

MsgBox, Download started.

; =================================
;		pause
; =================================
MsgBox, Now pause %gid%
aria2.pause(gid)

; =================================
;		unpause
; =================================
MsgBox, Now unpause %gid%
aria2.unpause(gid)

And here is a simple GUI:

(If you start aria2c with aria2c --enable-rpc --rpc-listen-all -c --rpc-secret=ahk123, you need set the --rpc-secret with ahk123 in the GUI.)



Github Page

Some aria2 web frontend:

• webui-aria2
• yaaw

[huyaowen]

ding!

[hed0nist]

Thanks!

I am a real beginner with AHK , with no programming skill at all.
I started this afternoon with the same idea : have an interaction with aria2 using AHK script ...

Here is my code :

Code: Select all

#NoEnv
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#Persistent
#SingleInstance

If !FileExist("ahk-aria2.ini") 
{
  MsgBox, 64, ahk-aria2, Settings file ahk-aria2.ini not found , creating a new one.`nThen do not forget to enter Options in the tray menu to set them properly.
  IniWrite, 0, ahk-aria2.ini, Paths, aria2
  IniWrite, 0, ahk-aria2.ini, Paths, webui
}

IniRead, Aria2Path, ahk-aria2.ini, Paths, aria2
IniRead, WebUIPath, ahk-aria2.ini, Paths, webui

IfNotExist, %Aria2Path%
{
  MsgBox, 65, ahk-aria2, aria2c.exe not found , download available there : http://sourceforge.net/projects/aria2/files/stable/aria2-1.18.7/`n`nDo you want to get the latest stable build right now ?
  IfMsgBox OK
    MsgBox, 36, ahk-aria2, Get the x64 build ? ( answer No will let you get the x32 build )`nZip file containing the executable will be available in ahk-aria2 directory.
      IfMsgBox Yes
        UrlDownloadToFile, http://sourceforge.net/projects/aria2/files/stable/aria2-1.18.7/aria2-1.18.7-win-64bit-build1.zip/download, aria2c_win64.zip  
      IfMsgBox No
        UrlDownloadToFile, http://sourceforge.net/projects/aria2/files/stable/aria2-1.18.7/aria2-1.18.7-win-32bit-build1.zip/download, aria2c_win32.zip
}

IfNotExist, %WebUIPath%
{
  MsgBox, 36, ahk-aria2, ziahamza/webui-aria2 not found , download available there : https://github.com/ziahamza/webui-aria2`n`nDo you want to get the latest stable release right now ?`nZip file containing the webUI will be available in ahk-aria2 directory.
  IfMsgBox Yes
    UrlDownloadToFile, https://github.com/ziahamza/webui-aria2/archive/master.zip, webui.zip
}

Destination = %A_MyDocuments%
Threads = 2

Menu, Tray, NoStandard
Menu, Tray, add, Add URL, ShowMainGui
Menu, Tray, add
Menu, Tray, add, Settings, ShowSettingsGui
Menu, Tray, add, Launch Aria2, LaunchAria2
Menu, Tray, add, Close Aria2, CloseAria2
Menu, Tray, add, Launch Web-UI, LaunchWebUI
Menu, Tray, add
Menu, Tray, add, Exit, AhkAria2Close

UpdateTray_Aria2_ON()
{
  Menu, Tray, disable, Launch Aria2
  Menu, Tray, enable, Close Aria2
  Menu, Tray, enable, Launch Web-UI
}

UpdateTray_Aria2_OFF()
{
  Menu, Tray, enable, Launch Aria2
  Menu, Tray, disable, Close Aria2
  Menu, Tray, disable, Launch Web-UI
}

Process, Exist, aria2c.exe
Aria2PID = %ErrorLevel%
  
If (%Aria2PID% = 0)
{
  UpdateTray_Aria2_OFF()
}
else
{
  UpdateTray_Aria2_ON()
}

return

ShowMainGui:
{
  Gui, New
  Gui, Add, Edit, x16 y34 w410 h20 vDownloadLink gDownloadLink, Paste URL here !
  Gui, Add, DropDownList, x176 y74 w40 h10 R5 vThreads gThreads, 1|2||3|4|5|6|7|8|9|10|11|12
  Gui, Add, Radio, x26 y114 w120 h30 Group Checked gDefaultDestination, My Documents
  Gui, Add, Radio, x26 y154 w120 h30 gDestination, Open folder
  Gui, Add, DropDownList, x176 y114 w150 h10 R5 vCategory gCategory, Archives|Video|Audio|Programs|Misc
  Gui, Add, Button, x310 y150 w100 h30 gDownload, DOWNLOAD
  Gui, Add, ListBox, x6 y184 w430 h90 ReadOnly +HScroll vListBox
  Gui -Resize -MaximizeBox +MinimizeBox
  ; Generated using SmartGUI Creator for SciTE
  Gui, Show, w445 h280 , ahk-aria2
  return
}

ShowSettingsGui:
{
  Gui, New
  Gui, Add, Button, x16 y14 w400 h30 gAria2PathConfig, Aria2c
  Gui, Add, Button, x16 y94 w400 h30 gWebUIPathConfig, WebUI
  Gui, Add, Edit, x16 y54 w400 h20 ReadOnly vAria2Path
  Gui, Add, Edit, x16 y134 w400 h20 ReadOnly vWebUIPath
  ; Generated using SmartGUI Creator for SciTE
  Gui, Show, w434 h186, ahk-aria2 Settings
  IniRead, Aria2Path, ahk-aria2.ini, Paths, aria2
  IniRead, WebUIPath, ahk-aria2.ini, Paths, webui
  GuiControl,, Aria2Path, %Aria2Path%
  GuiControl,, WebUIPath, %WebUIPath%
  return
}

Aria2PathConfig:
{
  FileSelectFile, Aria2Path, 1, aria2c.exe, Select aria2c executable, (*.exe)
  GuiControl,, Aria2Path, %Aria2Path%
  IniWrite, %Aria2Path%, ahk-aria2.ini, Paths, aria2
  return
}

WebUIPathConfig:
{
  FileSelectFile, WebUIPath, 1, index.html, Select webUI startpage file, (*.html)
  GuiControl,, WebUIPath, %WebUIPath%
  IniWrite, %WebUIPath%, ahk-aria2.ini, Paths, webui
  return
}

LaunchAria2:
{
  IniRead, Aria2Path, ahk-aria2.ini, Paths, aria2
  IfNotExist, %Aria2Path% 
    { 
      MsgBox, 16, ahk-aria2, Please specify aria2 directory path `in the settings.`n 
    }
  IfExist, %Aria2Path% 
    { 
      Run, %Aria2Path% --enable-rpc --rpc-listen-all,, Min, Aria2PID
      UpdateTray_Aria2_ON()
    }
  return
}

CloseAria2:
{
  Process, Close, %Aria2PID%
  UpdateTray_Aria2_OFF()
  return
}

LaunchWebUI:
{
  IniRead, WebUIPath, ahk-aria2.ini, Paths, webui
  IfNotExist, %WebUIPath% 
    {
      MsgBox, 16, ahk-aria2, Please specify webUI directory path `in the settings.`n 
    }
  IfExist, %WebUIPath% 
    { 
      Run, %WebUIPath%,, Max
    }
  return
}

DownloadLink:
{
  Gui, Submit, NoHide
  FormatTime, Time,, HH:mm:ss 
  GuiControl,, ListBox, %Time% - Download link set to %DownloadLink%||
  return
}

Threads:
{
  Gui, Submit, NoHide
  FormatTime, Time,, HH:mm:ss 
  GuiControl,, ListBox, %Time% - Number of threads set to %Threads%||
  return
}

Destination:
{
  Gui, Submit, NoHide
  FileSelectFolder, Destination,, 3
  GuiControl,, ListBox, %Time% - Destination folder set to %Destination%||
  return
}

DefaultDestination:
{
  Gui, Submit, NoHide
  Destination = %A_MyDocuments%
  GuiControl,, ListBox, %Time% - Destination folder set to %Destination%||
  return
}

Category: 
{
  Gui, Submit, NoHide
  FormatTime, Time,, HH:mm:ss
  GuiControl,, ListBox, %Time% - Download category changed : %Category%||
  return
}

Download:
{
  IniRead, Aria2Path, ahk-aria2.ini, Paths, aria2
  If !Destination 
  { 
    MsgBox, ERROR 
  }
  ; MsgBox, %Aria2Path% -x %Threads% -d %Destination% --file-allocation=none %DownloadLink%
  Run, %Aria2Path% -x %Threads% -d %Destination% --file-allocation=none %DownloadLink%
  return
}

AhkAria2Close:
ExitApp

As you can see it is ugly. And probably there are some bugs and bad use of a lot of things.
Basically :
- Check for INI and settings , proposing the download of aria and webui if not found.
- Run in system tray , menu reachable via right-click
- Start/Close aria2 RPC and webui
- Quick URL downloader with basic options ( threads and destination folder )

But of course with my knowledge , no JSON or other libs. And there was absolutely no "output" from aria2 inside the script as your code provide ( love the progress bar and all the timers info !! )
Thanks again for sharing ! I will try to understand ( and eventually learn ) the most i can.
Will add minor features from mine to your nice piece of art.

[hitman]

good!

[brutus_skywalker]

RAD!

[kczx3]

I can't tell but is the code for the GUI at the end included somewhere?

[tmplinshi]

@kczx3 click Download

[ginneylover]

Very good. Ding!