Changing Control Background/Text Color

[Masonjar13]

Perhaps there's a better way for doing so, but I stumbled across this post while trying to figure out how to change the bg of a readonly edit control. Seeing as it was written such a long time ago, I updated the syntax and upped the functionality of it.

Code: Select all

; callback for onMessage(0x0138,"WM_CTLCOLOR")
wm_ctlcolor(wParam,lParam,hwnd){
    if(!isObject(ctlColorObj[lParam]))
        return
    hBrush:=dllCall("Gdi32.dll\CreateSolidBrush","UInt",ctlColorObj[lParam].bg,"UPtr")

    if(ctlColorObj[lParam].text)
        dllCall("gdi32.dll\SetTextColor","Ptr",wParam,"UInt",ctlColorObj[lParam].text)
    dllCall("gdi32.dll\SetBkColor","Ptr",wParam,"UInt",ctlColorObj[lParam].bg)
    dllCall("gdi32.dll\SetBkMode","Ptr",wParam,"Int",2)
    return hBrush
}

It uses a global object to determine which controls should be changed in what way. Here's an example:

Code: Select all

global ctlColorObj:={}
onMessage(0x0138,"WM_CTLCOLOR")

gui,add,edit,+readonly +hwndchlhwnd r20 w300,Demo text.
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
gui,show,,Control Color
return

guiClose:
exitApp

F1::
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
winSet,redraw,,% "ahk_id " . chlhwnd
return

F2::
ctlColorObj[chlhwnd]:={bg:0x00ff00,text:0x000000}
winSet,redraw,,% "ahk_id " . chlhwnd
return

wm_ctlcolor(wParam,lParam,hwnd){
    if(!isObject(ctlColorObj[lParam]))
        return
    hBrush:=dllCall("Gdi32.dll\CreateSolidBrush","UInt",ctlColorObj[lParam].bg,"UPtr")

    if(ctlColorObj[lParam].text)
        dllCall("gdi32.dll\SetTextColor","Ptr",wParam,"UInt",ctlColorObj[lParam].text)
    dllCall("gdi32.dll\SetBkColor","Ptr",wParam,"UInt",ctlColorObj[lParam].bg)
    dllCall("gdi32.dll\SetBkMode","Ptr",wParam,"Int",2)
    return hBrush
}

The only problem I can't fix is the redraw (guiControl,moveDraw,Control doesn't seem to work), so changing the colors isn't instant (you'll have to click off the window and back onto it).
Hiding the GUI and showing it again will force a redraw. I suppose there may be a window message that could be sent to also force this kind of redraw?
Thanks to burque505 and guest3456

[burque505]

Hi Masonjar13, this flickers, and sometimes it misses a change, but you don't have to click off and on. Obviously not an ideal solution.

Code: Select all

global ctlColorObj:={}
global preference := {}
onMessage(0x0138,"WM_CTLCOLOR")

gui,add,edit,+readonly +hwndchlhwnd r20 w300,Demo text.
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
gui,show,,Control Color
return

guiClose:
exitApp

F1::
gui, destroy
preference:={bg:0xff00ff,text:0xffffff}
gosub, NewGui
return
F2::
gui, destroy
preference:={bg:0x00ff00,text:0x000000}
gosub, NewGui
return
return

wm_ctlcolor(wParam,lParam,hwnd){
    if(!isObject(ctlColorObj[lParam]))
        return
    hBrush:=dllCall("Gdi32.dll\CreateSolidBrush","UInt",ctlColorObj[lParam].bg,"UPtr")

    if(ctlColorObj[lParam].text)
        dllCall("gdi32.dll\SetTextColor","Ptr",wParam,"UInt",ctlColorObj[lParam].text)
    dllCall("gdi32.dll\SetBkColor","Ptr",wParam,"UInt",ctlColorObj[lParam].bg)
    dllCall("gdi32.dll\SetBkMode","Ptr",wParam,"Int",2)
    return hBrush
}

NewGui:
gui,add,edit,+readonly +hwndchlhwnd r20 w300,Demo text.
ctlColorObj[chlhwnd]:=preference
gui,show,,Control Color
return

Regards,
burque505

[Masonjar13]

Yeah, destroying a GUI and recreating it over is very inefficient, and significantly more so if it's a complicated GUI. But, you gave me an idea! I had tried gui,cancel,nohide, which didn't work. However, actually hiding it then showing it again does in fact work. Again, not a great solution, more of a workaround, but it does work. I've added it to the main example.

Thanks for the input

[burque505]

Cool! By chance I saw something somewhere earlier today - can't remember, in the forums somewhere - about needing a brief delay with color changes.
It doesn't seem to crash like this. What do you think? EDIT - took out one of the 10ms delays, still works.

Code: Select all

global ctlColorObj:={}
onMessage(0x0138,"WM_CTLCOLOR")

gui,add,edit,+readonly +hwndchlhwnd r20 w300,Demo text.
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
gui,show,,Control Color
return

guiClose:
exitApp

F1::
gui,cancel
;sleep, 10
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
sleep, 10
gui,show
return

F2::
gui,cancel
;sleep, 10
ctlColorObj[chlhwnd]:={bg:0x00ff00,text:0x000000}
sleep, 10
gui,show
return

wm_ctlcolor(wParam,lParam,hwnd){
    if(!isObject(ctlColorObj[lParam]))
        return
    hBrush:=dllCall("Gdi32.dll\CreateSolidBrush","UInt",ctlColorObj[lParam].bg,"UPtr")

    if(ctlColorObj[lParam].text)
        dllCall("gdi32.dll\SetTextColor","Ptr",wParam,"UInt",ctlColorObj[lParam].text)
    dllCall("gdi32.dll\SetBkColor","Ptr",wParam,"UInt",ctlColorObj[lParam].bg)
    dllCall("gdi32.dll\SetBkMode","Ptr",wParam,"Int",2)
    return hBrush
}

[guest3456]

Hiding the GUI and showing it again will force a redraw. I suppose there may be a window message that could be sent to also force this kind of redraw?

Code: Select all

F1::
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
WinSet, Redraw,, ahk_id %chlhwnd%
return

works for me

[burque505]

@guest3456, not only works but no flicker at all. Bravo.
Regards,
burque505

[Masonjar13]

Yep, there it is. I was just tired and didn't go looking for it Thanks guest3456, updated main example

[burque505]

:Bump
I ran across this again and it occurred to me that you might not want the user selecting that text, though I'm sure there are times when you would.

Spoiler

Code: Select all

global ctlColorObj:={}
onMessage(0x0138,"WM_CTLCOLOR")

gui, font, s14, Impact
gui, add, edit, +readonly x10 y10 r10 w300
gui,add,edit,+readonly +hwndchlhwnd +Transparent x10 y10 r10 w300,TRY TO SELECT ME. I dare you.`n`n(F1, F2: Change BG color)
gui, font
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
gui,show,,Control Color
return

guiClose:
exitApp

F1::
ctlColorObj[chlhwnd]:={bg:0xff00ff,text:0xffffff}
winSet,redraw,,% "ahk_id " . chlhwnd
return

F2::
ctlColorObj[chlhwnd]:={bg:0x00ff00,text:0x000000}
winSet,redraw,,% "ahk_id " . chlhwnd
return

wm_ctlcolor(wParam,lParam,hwnd){
    if(!isObject(ctlColorObj[lParam]))
        return
    hBrush:=dllCall("Gdi32.dll\CreateSolidBrush","UInt",ctlColorObj[lParam].bg,"UPtr")

    if(ctlColorObj[lParam].text)
        dllCall("gdi32.dll\SetTextColor","Ptr",wParam,"UInt",ctlColorObj[lParam].text)
    dllCall("gdi32.dll\SetBkColor","Ptr",wParam,"UInt",ctlColorObj[lParam].bg)
    dllCall("gdi32.dll\SetBkMode","Ptr",wParam,"Int",2)
    return hBrush
}

bg_no_edit.gif (26.47 KiB) Viewed 2710 times

[JnLlnd]

Thanks Masonjar13 and other for putting this together. It works perfectly with a read-only edit control. Is it possible to adapt this code to also support color change in non read-only edit control?

[just me]

Hi @JnLlnd,

you have to process the WM_CTLCOLOREDIT (0x0133) notification in this case.

[JnLlnd]

Thank you just me. I also found your class Class_CtlColors (viewtopic.php?f=6&t=2197). Very well done!

[junjunjon]

how can i change any random edit control color with this scpript, can it do that? many thanks.