DTSUB() : Calculates age from two DateTime stamps and returns yyyy/MM/dd HH:mm:ss

[SKAN]

DTSUB( T1, T2, F )

The function accepts two DateTime stamps, calculates the difference and returns result formatted as Years,Months,Days,Hours,Minutes,Seconds.

The acceptable range for DateTime stamps are from -9990101000000 to 99991231235959 ( 1000 BC + 1s to AD 10000 - 1s ). Please refer anno Domini before using negative years. (There is no year 0000)

Pass begin date as T1 and end date as T2. Make sure the order isn't reversed. To be clear, when TimeStamps are resolved to the their full form of 14 chars, the parameter T2 must be numerically greater than T1.

About F parameter: The default value is True and returns result formatted as yyyy/MM/dd HH:mm:ss for sorting purpose. (Refer help doc: Sort).
Pass false as 3rd parameter to return the result as an array or pass a string for custom formatting. Refer examples and help doc: Format

The function

Code: Select all

DTSUB( T1, T2, F:=1 ) { ; v2.03 By SKAN | CD:10-Oct-2018 | Topic: goo.gl/L7frVp
Static D := [31,31,0,31,30,31,30,31,31,30,31,30]
Static S := [[1,4],[5,2],[7,2],[9,2],[11,2],[13,2]]          
Static U := [0,12,0,24,60,60]
Local  R := [0,1,1,0,0,0,0],  M,Y,I,xT1,xT2, Adj:=0                

    M    := ( M:=SubStr(T2,5,2)+0 ) ? M : 1
  , Y    := ( M<>3 ? 0 : SubStr(T2,1,4)+0 ) 
  , U[3] := ( M<>3 ? D[M] : (!Mod(Y,4) && Mod(Y,100) || !Mod(Y,400)) ? 29 : 28 )
  
    While ( I := 7-A_Index )   
          xT1 := ( xT1:=SubStr(T1, S[I].1, S[I].2)+0 ) ? xT1 : R[I] 
       ,  xT2 := ( xT2:=SubStr(T2, S[I].1, S[I].2)+0 ) ? xT2 : R[I]
       , R[I] := ( (xT2+=Adj) >= xT1 ? xT2-xT1+(Adj:=0) : xT2+U[I]-xT1+(Adj:=-1)+1 ) 

    R[3] = -1 ? ( R[3]:=30, R[2]:=11, R[1]-=1 ) : 0

Return F ? Format( F=1 ? "{:04}/{:02}/{:02} {:02}:{:02}:{:02}" : F, R* ) : R 
}

DTSUB-Examples.ahk

Code: Select all

#NoEnv
#SingleInstance, Force

; Example 1
; Age of Bill Gates

DoB := 19551028220000 ; PST
DoB += 8, Hours       ; UTC
MsgBox,,Example 1, % "Age of Bill Gates`n`n" DTSUB( DoB, A_NowUTC )


; Example 2
; Time left for a future event
MsgBox,,Example 2, % "Time left till New Year`n`n" DTSUB( A_Now, A_YYYY+1 )


; Example 3
; Using custom format

MsgBox,,Example 3, % DTSUB( A_YYYY, A_Now, "{2:} months {3:} days completed in " A_YYYY )
MsgBox,,Example 3, % DTSUB( A_Now, 3000, "Next millenium occurs in`n`nYears`t{1:}`nMonths`t{2:}`nDays`t{3:}" )


; Example 4
; Age of your Windows installation

if (A_Is64bitOS)
    SetRegView, 64
    
RegRead, UnixTime, HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion, InstallDate
WID := 1970
WID += %UnixTime%, S
MsgBox,,Example 4, % DTSUB( WID, A_NowUTC, "Time since Windows install`n`n{1:} years, {2:} months & {3:} days" )


; Example 5
; Windows Uptime and Time left for reboot.

T1 := T2 := T3 := A_Now,  TC := A_TickCount
T1 += % 0-(TC/1000), S
T3 += % ((0xFFFFFFFF-TC)/1000), S

MsgBox,,Example 5, % DTSUB( T1, T3, "A_TickCount life`n`n{2:} month {3:} days {4:}h {5:}m {6:}s`n`n`n")
                   . DTSUB( T1, T2, "Windows Uptime`n`n{2:} month {3:} days {4:}h {5:}m {6:}s`n`n`n" )
                   . DTSUB( T2, T3, "Time left for reboot`n`n{2:} month {3:} days {4:}h {5:}m {6:}s" )


; Copy/Paste DTSUB() below

Simple GUI for testing DTSUB()

• CB-20181022-221209.jpg

  (20.32 KiB) Downloaded 131 times

  Code: Select all

  #NoEnv
  #SingleInstance, Force
  
  Gui, Font, s14, Lucida Console
  Gui, Add, Text,           w280  h24,                          yyyy/MM/dd HH:mm:ss 
  Gui, Add, DateTime, Y+04  W280  h36  1 vE Choose%A_Now%  gDT, yyyy/MM/dd HH:mm:ss
  Gui, Add, DateTime, y+08  wp    h36  1 vB Choose1601     gDT, yyyy/MM/dd HH:mm:ss
  Gui, Add, Edit,     y+16  wp    h24    vA ReadOnly 
  Gui, Show,, DTSUB | DateTime subtract 
  
  DT:
    Gui, Submit, NoHide
    If ( B > E )
      T := B, B := E, E := T
    GuiControl,, A, % DTSUB( B, E )
  Return
  
  GuiClose:
  ExitApp
  
  ; Copy/Paste DTSUB() below
  

Thanks

[TAC109]

Very interesting that your function allows for early years, even negative.

However I don’t see a Country parameter, which is needed to allow for the changeover from the Julian calendar in the 16th to 20th centuries, depending on country. Also, is there allowance for such things as the year of confusion (46 BC which had 15 months and 445 days)?