How to check if Gui is empty before showing it?

[think]

I'm creating a dynamic gui and sometimes it does not contain any control. How can check if gui is empty before it is shown? Checking it's size? I would like to avoid a taskbar showing an empty gui.

Code: Select all

gui, 2:destroy
gui, 2:Show,, MyGui 

[mikeyww]

Hello,

This is simple because the script controls the GUI. Therefore, your script always knows exactly what controls have been added. You can track that with a variable, use GuiControlGet, etc.

[boiler]

An alternate approach is to use this function to which you pass the GUI's hwnd. It will work without showing the GUI if you have DetectHiddenWindows on.

Code: Select all

CtrlCount(id) {
	WinGet, list, ControlList, ahk_id %id%
	RegExReplace(list, "\w+",, count)
	return count
}

Demonstration:

Code: Select all

DetectHiddenWindows, On
Gui, +HwndGuiID
;Gui, Show
MsgBox, % "No. of controls: " CtrlCount(GuiID)

Gui, Add, Text,, Hello
MsgBox, % "No. of controls: " CtrlCount(GuiID)

Gui, Add, Button, xm, Button
MsgBox, % "No. of controls: " CtrlCount(GuiID)
ExitApp

CtrlCount(id) {
	WinGet, list, ControlList, ahk_id %id%
	RegExReplace(list, "\w+",, count)
	return count
}