Problem passing list of window ids to function

[bobf32]

Hi,

Massive noob question: why does this work:

Code: Select all

WinGet, id, list,/cygdrive/h,, Program Manager
fSendDev1ToWindows(id)

fSendDev1ToWindows(id) {
    Loop, %id%
    {
        MsgBox %A_Index%
        this_id := id%A_Index%
        MsgBox %this_id%
        WinActivate, ahk_id %this_id%
;        Send, dev2{Enter}
    }

    RETURN
}

and this not?

Code: Select all

WinGet, id, list,/cygdrive/h,, Program Manager
fSendDev1ToWindows(id)

fSendDev1ToWindows(p_id) {
    Loop, %p_id%
    {
        MsgBox %A_Index%
        this_id := p_id%A_Index%
        MsgBox %this_id%
        WinActivate, ahk_id %this_id%
;        Send, dev2{Enter}
    }

    RETURN
}

Specifically, in the latter call the variable this_id does not appear to get populated.

[kanat]

Really weird behaviour. Somebody of the gurus should explain it.

[jmeneses]

Hello to you both look at this

Code: Select all

WinGet, id, list,,, Program Manager   
fSendDev1ToWindows1(id)
Msgbox 0x40000,, % "(ListVars of fSendDev1ToWindows1).......... " 
fSendDev1ToWindows2(id)
Msgbox 0x40000,, % "END!!!! "       
ExitApp

fSendDev1ToWindows1(id) {   
    Listvars
    RETURN
}

fSendDev1ToWindows2(p_id) {
    Listvars
    RETURN
}

See https://autohotkey.com/docs/Functions.htm#PseudoArrays

[bof32]

Thanks for this. Unfortunately I have no idea a) what it means or b) what I need to do to get my p_id version working!

[bobf32]

Thanks, but I have no idea how this helps!

[4GForce]

Specifically, in the latter call the variable this_id does not appear to get populated.

Because p_id1 doesn't exist ...

In the 1st one when using id%A_Index% you're accessing the global variable

The only thing that you pass to your function is id into p_id ... that is only the number of window found.

Pseudo arrays are imaginary arrays, they are actually just a bunch of variables, that's why he was pointing you at ListVars.

[bobf32]

Thanks, I see. Sort of. So given what I'm trying logically to do is pass an array to a function would it be best to just use the global or is there a better way to pass these pseudo arrays?

[4GForce]

Thanks, I see. Sort of. So given what I'm trying logically to do is pass an array to a function would it be best to just use the global or is there a better way to pass these pseudo arrays?

You can't really pass them to functions and they won't be global if created inside a function.
If you keep the code structure you have now, use the global.

If you want to avoid the globals, you could do something like this ...

Code: Select all

fSendDev1ToWindows(getWinIds())

getWinIds() {
   	 winIds := []
	WinGet, id, list,,, Program Manager
   	 loop % id
    	{
        	winIds[A_Index] := id%A_Index%
    	}
	return winIds
}

fSendDev1ToWindows(Ids) {
    	For i, id in Ids
    	{
        	MsgBox % A_Index . " -> " . id
        	WinActivate, ahk_id %id%
		;  Send, dev2{Enter}
   	 }
   	 return
}

[bobf32]

Many thanks for all the help.

[jmeneses]

Thaks 4GForce for helping out in explaining my english is very++ bad