Pushing lines from Loop, Read into array?

[nompynuthead]

I'm relatively new to AHK, and I just haven't been able to find out what's going wrong here.
Essentially, I have a program that is meant to detect when the user physically clicks, take a pair of coordinates from a text file, and then virtually click the mouse at those coordinates. These coordinates are just two numbers in a text file, separated by a newline, e.g.:
100
200

My problem is, I can't seem to get this pair of coordinates to load into the mouseCoords array. They just aren't pushed to it at all. I don't know if this is a problem with my Loop statement or my mouseCoords.Push(A_LoopReadLine) statement, but I have tried for hours and I just can't seem to get it to work. Can anyone help to fix?

Code: Select all

CoordMode, Mouse

physClick = False
LButton::
    GetKeyState, State, LButton, P
    If State = D
        physClick = True

return

LButton Up::
    If physClick = True
        mouseCoords := []
        Loop, Read, mousepos.txt
        {
            mouseCoords.Push(A_LoopReadLine)
        }


        physClick = False
        Send {Click, mouseCoords[1], mouseCoords[2]}

return

!z::
    ExitApp
return

[boiler]

You can't use expressions or objects in a Click statement, so you have to use a pseudo-array and use % around the variables. Plus, all that stuff with the physClick, is that just so the virtual click doesn't trigger the LButton hotkey? That's what the $ option on hotkeys is for. I believe your script can be simplified to this:

Code: Select all

CoordMode, Mouse

$LButton::
	Loop, Read, mousepos.txt
		mouseCoords%A_Index% := A_LoopReadLine
	Click, %mouseCoords1%, %mouseCoords2%
return

!z::
    ExitApp
return

[nnnik]

You need brackets {} around pieces of code that you want to stick together:

Code: Select all

CoordMode, Mouse

physClick = False
LButton::
    GetKeyState, State, LButton, P
    If State = D
        physClick = True

return

LButton Up::
    If physClick = True {
        mouseCoords := []
        Loop, Read, mousepos.txt
        {
            mouseCoords.Push(A_LoopReadLine)
        }


        physClick = False
        Send % "{Click, " . mouseCoords[1] . "," .  mouseCoords[2] . "}" ; the . for string concenation
    }

return

!z::
    ExitApp
return

Also you need to force expression mode in the Send

[nnnik]

You can't use expressions or objects in a Click statement, so you have to use a pseudo-array and use % around the variables. Plus, all that stuff with the physClick, is that just so the virtual click doesn't trigger the LButton hotkey? That's what the $ option on hotkeys is for. I believe your script can be simplified to this:

Code: Select all

CoordMode, Mouse

$LButton::
	Loop, Read, mousepos.txt
		mouseCoords%A_Index% := A_LoopReadLine
	Click, %mouseCoords1%, %mouseCoords2%
return

!z::
    ExitApp
return

Quite wrong - you can always force expression mode.

[boiler]

Wow, you seem pretty sure of yourself, nnnik. Care to amend your statement when it comes to the Click command?

[Odlanir]

As nnnik says:

Code: Select all

$LButton::
	mouseCoords:= []
	Loop, Read, mousepos.txt
		mouseCoords.Push(A_LoopReadLine)
	Send % "{Click, " . mouseCoords[1] . "," .  mouseCoords[2] . "}" 
return

[boiler]

That is an expression of the Send command. His general statement that you can always force expression mode is not correct when it comes to the Click command.

[boiler]

I didn't say that what he did couldn't work. But in my code, I used Click, and that's why I used a pseudo array. His general statement was quite wrong.

[Helgef]

You can force an expression for click's one and only parameter, eg, click % x " " y. The documentation isn't very good in this case.

Cheers.