GuiDestroyAll? Topic is solved

[CyL0N]

I need a GuiDestroyAll() type functionality,tried it myself,but hit a dead end. Any other solutions & why isn't this working?

Code: Select all

Loop 99{
	Gui New
	Gui +AlwaysOnTop
	Gui Show, w100 h100
}

q::GuiDestroyAll()

GuiDestroyAll(){
	Loop 99
		Gui, %A_Index%:Destroy
}

x::
Loop 99
	Gui, %A_Index%:Destroy
Return

[MannyKSoSo]

I believe you need to set the name at the time of creation ie Gui %A_Index%:New and it should work with what you have.

[CyL0N]

Code: Select all

Loop 99
	GuiNew()

GuiNew(){
	Static i
	i := i ? (i+1) : 1
	Gui %i%:New
	Gui +AlwaysOnTop
	Gui Show, w100 h100
}

q::GuiDestroyAll()

GuiDestroyAll(){
	Loop 99
		Gui, %A_Index%:Destroy
}

Yup that works, Cheers.

[just me]

Code: Select all

GuiDestroyAll(){
   DHW := A_DetectHiddenWindows
   DetectHiddenWindows, On
   PID := DllCall("GetCurrentProcessId", "UInt")
   WinGet, GuiList, List, ahk_class AutoHotkeyGUI ahk_pid %PID%
   Loop, %GuiList%
      Gui, % GuiList%A_Index% . ":Destroy"
   DetectHiddenWindows, %DHW%
   Return GuiList
}

[CyL0N]

Exactly what I was looking for,THX DUDE.